PVE/QemuServer/Cloudinit.pm

   1 package PVE::QemuServer::Cloudinit;
   2
   3 use strict;
   4 use warnings;
   5
   6 use File::Path;
   7 use Digest::SHA;
   8 use URI::Escape;
   9 use MIME::Base64 qw(encode_base64);
  10
  11 use PVE::Tools qw(run_command file_set_contents);
  12 use PVE::Storage;
  13 use PVE::QemuServer;
  14
  15 use constant CLOUDINIT_DISK_SIZE => 4 * 1024 * 1024; # 4MiB in bytes
  16
  17 sub commit_cloudinit_disk {
  18     my ($conf, $vmid, $drive, $volname, $storeid, $files, $label) = @_;
  19
  20     my $path = "/run/pve/cloudinit/$vmid/";
  21     mkpath $path;
  22     foreach my $filepath (keys %$files) {
  23         if ($filepath !~ m@^(.*)\/[^/]+$@) {
  24             die "internal error: bad file name in cloud-init image: $filepath\n";
  25         }
  26         my $dirname = $1;
  27         mkpath "$path/$dirname";
  28
  29         my $contents = $files->{$filepath};
  30         file_set_contents("$path/$filepath", $contents);
  31     }
  32
  33     my $storecfg = PVE::Storage::config();
  34     my $iso_path = PVE::Storage::path($storecfg, $drive->{file});
  35     my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
  36     my $format = PVE::QemuServer::qemu_img_format($scfg, $volname);
  37
  38     my $size = eval { PVE::Storage::volume_size_info($storecfg, $drive->{file}) };
  39     if (!defined($size) || $size <= 0) {
  40         $volname =~ m/(vm-$vmid-cloudinit(.\Q$format\E)?)/;
  41         my $name = $1;
  42         $size = 4 * 1024;
  43         PVE::Storage::vdisk_alloc($storecfg, $storeid, $vmid, $format, $name, $size);
  44         $size *= 1024; # vdisk alloc takes KB, qemu-img dd's osize takes byte
  45     }
  46     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
  47     $plugin->activate_volume($storeid, $scfg, $volname);
  48
  49     print "generating cloud-init ISO\n";
  50     eval {
  51         run_command([
  52             ['genisoimage', '-quiet', '-iso-level', '3', '-R', '-V', $label, $path],
  53             ['qemu-img', 'dd', '-n', '-f', 'raw', '-O', $format, 'isize=0', "osize=$size", "of=$iso_path"]
  54         ]);
  55     };
  56     my $err = $@;
  57     rmtree($path);
  58     die $err if $err;
  59 }
  60
  61 sub get_cloudinit_format {
  62     my ($conf) = @_;
  63     if (defined(my $format = $conf->{citype})) {
  64         return $format;
  65     }
  66
  67     # No format specified, default based on ostype because windows'
  68     # cloudbased-init only supports configdrivev2, whereas on linux we need
  69     # to use mac addresses because regular cloudinit doesn't map 'ethX' to
  70     # the new predicatble network device naming scheme.
  71     if (defined(my $ostype = $conf->{ostype})) {
  72         return 'configdrive2'
  73             if PVE::QemuServer::windows_version($ostype);
  74     }
  75
  76     return 'nocloud';
  77 }
  78
  79 sub get_hostname_fqdn {
  80     my ($conf, $vmid) = @_;
  81     my $hostname = $conf->{name} // "VM$vmid";
  82     my $fqdn;
  83     if ($hostname =~ /\./) {
  84         $fqdn = $hostname;
  85         $hostname =~ s/\..*$//;
  86     } elsif (my $search = $conf->{searchdomain}) {
  87         $fqdn = "$hostname.$search";
  88     }
  89     return ($hostname, $fqdn);
  90 }
  91
  92 sub get_dns_conf {
  93     my ($conf) = @_;
  94
  95     # Same logic as in pve-container, but without the testcase special case
  96     my $host_resolv_conf = PVE::INotify::read_file('resolvconf');
  97
  98     my $searchdomains = [
  99         split(/\s+/, $conf->{searchdomain} // $host_resolv_conf->{search})
 100     ];
 101
 102     my $nameserver = $conf->{nameserver};
 103     if (!defined($nameserver)) {
 104         $nameserver = [grep { $_ } $host_resolv_conf->@{qw(dns1 dns2 dns3)}];
 105     } else {
 106         $nameserver = [split(/\s+/, $nameserver)];
 107     }
 108
 109     return ($searchdomains, $nameserver);
 110 }
 111
 112 sub cloudinit_userdata {
 113     my ($conf, $vmid) = @_;
 114
 115     my ($hostname, $fqdn) = get_hostname_fqdn($conf, $vmid);
 116
 117     my $content = "#cloud-config\n";
 118
 119     $content .= "hostname: $hostname\n";
 120     $content .= "manage_etc_hosts: true\n";
 121     $content .= "fqdn: $fqdn\n" if defined($fqdn);
 122
 123     my $username = $conf->{ciuser};
 124     my $password = $conf->{cipassword};
 125
 126     $content .= "user: $username\n" if defined($username);
 127     $content .= "disable_root: False\n" if defined($username) && $username eq 'root';
 128     $content .= "password: $password\n" if defined($password);
 129
 130     if (defined(my $keys = $conf->{sshkeys})) {
 131         $keys = URI::Escape::uri_unescape($keys);
 132         $keys = [map { my $key = $_; chomp $key; $key } split(/\n/, $keys)];
 133         $keys = [grep { /\S/ } @$keys];
 134         $content .= "ssh_authorized_keys:\n";
 135         foreach my $k (@$keys) {
 136             $content .= "  - $k\n";
 137         }
 138     }
 139     $content .= "chpasswd:\n";
 140     $content .= "  expire: False\n";
 141
 142     if (!defined($username) || $username ne 'root') {
 143         $content .= "users:\n";
 144         $content .= "  - default\n";
 145     }
 146
 147     $content .= "package_upgrade: true\n";
 148
 149     return $content;
 150 }
 151
 152 sub split_ip4 {
 153     my ($ip) = @_;
 154     my ($addr, $mask) = split('/', $ip);
 155     die "not a CIDR: $ip\n" if !defined $mask;
 156     return ($addr, $PVE::Network::ipv4_reverse_mask->[$mask]);
 157 }
 158
 159 sub configdrive2_network {
 160     my ($conf) = @_;
 161
 162     my $content = "auto lo\n";
 163     $content .= "iface lo inet loopback\n\n";
 164
 165     my ($searchdomains, $nameservers) = get_dns_conf($conf);
 166     if ($nameservers && @$nameservers) {
 167         $nameservers = join(' ', @$nameservers);
 168         $content .= "        dns_nameservers $nameservers\n";
 169     }
 170     if ($searchdomains && @$searchdomains) {
 171         $searchdomains = join(' ', @$searchdomains);
 172         $content .= "        dns_search $searchdomains\n";
 173     }
 174
 175     my @ifaces = grep { /^net(\d+)$/ } keys %$conf;
 176     foreach my $iface (sort @ifaces) {
 177         (my $id = $iface) =~ s/^net//;
 178         next if !$conf->{"ipconfig$id"};
 179         my $net = PVE::QemuServer::parse_ipconfig($conf->{"ipconfig$id"});
 180         $id = "eth$id";
 181
 182         $content .="auto $id\n";
 183         if ($net->{ip}) {
 184             if ($net->{ip} eq 'dhcp') {
 185                 $content .= "iface $id inet dhcp\n";
 186             } else {
 187                 my ($addr, $mask) = split_ip4($net->{ip});
 188                 $content .= "iface $id inet static\n";
 189                 $content .= "        address $addr\n";
 190                 $content .= "        netmask $mask\n";
 191                 $content .= "        gateway $net->{gw}\n" if $net->{gw};
 192             }
 193         }
 194         if ($net->{ip6}) {
 195             if ($net->{ip6} =~ /^(auto|dhcp)$/) {
 196                 $content .= "iface $id inet6 $1\n";
 197             } else {
 198                 my ($addr, $mask) = split('/', $net->{ip6});
 199                 $content .= "iface $id inet6 static\n";
 200                 $content .= "        address $addr\n";
 201                 $content .= "        netmask $mask\n";
 202                 $content .= "        gateway $net->{gw6}\n" if $net->{gw6};
 203             }
 204         }
 205     }
 206
 207     return $content;
 208 }
 209
 210 sub configdrive2_gen_metadata {
 211     my ($user, $network) = @_;
 212
 213     my $uuid_str = Digest::SHA::sha1_hex($user.$network);
 214     return configdrive2_metadata($uuid_str);
 215 }
 216
 217 sub configdrive2_metadata {
 218     my ($uuid) = @_;
 219     return <<"EOF";
 220 {
 221      "uuid": "$uuid",
 222      "network_config": { "content_path": "/content/0000" }
 223 }
 224 EOF
 225 }
 226
 227 sub generate_configdrive2 {
 228     my ($conf, $vmid, $drive, $volname, $storeid) = @_;
 229
 230     my ($user_data, $network_data, $meta_data) = get_custom_cloudinit_files($conf);
 231     $user_data = cloudinit_userdata($conf, $vmid) if !defined($user_data);
 232     $network_data = configdrive2_network($conf) if !defined($network_data);
 233
 234     if (!defined($meta_data)) {
 235         $meta_data = configdrive2_gen_metadata($user_data, $network_data);
 236     }
 237     my $files = {
 238         '/openstack/latest/user_data' => $user_data,
 239         '/openstack/content/0000' => $network_data,
 240         '/openstack/latest/meta_data.json' => $meta_data
 241     };
 242     commit_cloudinit_disk($conf, $vmid, $drive, $volname, $storeid, $files, 'config-2');
 243 }
 244
 245 sub generate_opennebula {
 246     my ($conf, $vmid, $drive, $volname, $storeid) = @_;
 247
 248     my $content = "";
 249
 250     my $username = $conf->{ciuser} || "root";
 251     $content .= "USERNAME=$username\n" if defined($username);
 252
 253     if (defined(my $password = $conf->{cipassword})) {
 254         $content .= "CRYPTED_PASSWORD_BASE64=". encode_base64($password) ."\n";
 255     }
 256
 257     if (defined($conf->{sshkeys})) {
 258         my $keys = [ split(/\s*\n\s*/, URI::Escape::uri_unescape($conf->{sshkeys})) ];
 259         $content .= "SSH_PUBLIC_KEY=\"". join("\n", $keys->@*) ."\"\n";
 260     }
 261
 262     my ($hostname, $fqdn) = get_hostname_fqdn($conf, $vmid);
 263     $content .= "SET_HOSTNAME=$hostname\n";
 264
 265     my ($searchdomains, $nameservers) = get_dns_conf($conf);
 266     $content .= 'DNS="' . join(' ', @$nameservers) ."\"\n" if $nameservers && @$nameservers;
 267     $content .= 'SEARCH_DOMAIN="'. join(' ', @$searchdomains) ."\"\n" if $searchdomains && @$searchdomains;
 268
 269     my $networkenabled = undef;
 270     my @ifaces = grep { /^net(\d+)$/ } keys %$conf;
 271     foreach my $iface (sort @ifaces) {
 272         (my $id = $iface) =~ s/^net//;
 273         my $net = PVE::QemuServer::parse_net($conf->{$iface});
 274         next if !$conf->{"ipconfig$id"};
 275         my $ipconfig = PVE::QemuServer::parse_ipconfig($conf->{"ipconfig$id"});
 276         my $ethid = "ETH$id";
 277
 278         my $mac = lc $net->{hwaddr};
 279
 280         if ($ipconfig->{ip}) {
 281             $networkenabled = 1;
 282
 283             if ($ipconfig->{ip} eq 'dhcp') {
 284                 $content .= "${ethid}_DHCP=YES\n";
 285             } else {
 286                 my ($addr, $mask) = split_ip4($ipconfig->{ip});
 287                 $content .= "${ethid}_IP=$addr\n";
 288                 $content .= "${ethid}_MASK=$mask\n";
 289                 $content .= "${ethid}_MAC=$mac\n";
 290                 $content .= "${ethid}_GATEWAY=$ipconfig->{gw}\n" if $ipconfig->{gw};
 291             }
 292             $content .= "${ethid}_MTU=$net->{mtu}\n" if $net->{mtu};
 293         }
 294
 295         if ($ipconfig->{ip6}) {
 296             $networkenabled = 1;
 297             if ($ipconfig->{ip6} eq 'dhcp') {
 298                 $content .= "${ethid}_DHCP6=YES\n";
 299             } elsif ($ipconfig->{ip6} eq 'auto') {
 300                 $content .= "${ethid}_AUTO6=YES\n";
 301             } else {
 302                 my ($addr, $mask) = split('/', $ipconfig->{ip6});
 303                 $content .= "${ethid}_IP6=$addr\n";
 304                 $content .= "${ethid}_MASK6=$mask\n";
 305                 $content .= "${ethid}_MAC6=$mac\n";
 306                 $content .= "${ethid}_GATEWAY6=$ipconfig->{gw6}\n" if $ipconfig->{gw6};
 307             }
 308             $content .= "${ethid}_MTU=$net->{mtu}\n" if $net->{mtu};
 309         }
 310     }
 311
 312     $content .= "NETWORK=YES\n" if $networkenabled;
 313
 314     my $files = { '/context.sh' => $content };
 315     commit_cloudinit_disk($conf, $vmid, $drive, $volname, $storeid, $files, 'CONTEXT');
 316 }
 317
 318 sub nocloud_network_v2 {
 319     my ($conf) = @_;
 320
 321     my $content = '';
 322
 323     my $head = "version: 2\n"
 324              . "ethernets:\n";
 325
 326     my $dns_done;
 327
 328     my @ifaces = grep { /^net(\d+)$/ } keys %$conf;
 329     foreach my $iface (sort @ifaces) {
 330         (my $id = $iface) =~ s/^net//;
 331         next if !$conf->{"ipconfig$id"};
 332
 333         # indentation - network interfaces are inside an 'ethernets' hash
 334         my $i = '    ';
 335
 336         my $net = PVE::QemuServer::parse_net($conf->{$iface});
 337         my $ipconfig = PVE::QemuServer::parse_ipconfig($conf->{"ipconfig$id"});
 338
 339         my $mac = $net->{macaddr}
 340             or die "network interface '$iface' has no mac address\n";
 341
 342         $content .= "${i}$iface:\n";
 343         $i .= '    ';
 344         $content .= "${i}match:\n"
 345                  . "${i}    macaddress: \"$mac\"\n"
 346                  . "${i}set-name: eth$id\n";
 347         my @addresses;
 348         if (defined(my $ip = $ipconfig->{ip})) {
 349             if ($ip eq 'dhcp') {
 350                 $content .= "${i}dhcp4: true\n";
 351             } else {
 352                 push @addresses, $ip;
 353             }
 354         }
 355         if (defined(my $ip = $ipconfig->{ip6})) {
 356             if ($ip eq 'dhcp') {
 357                 $content .= "${i}dhcp6: true\n";
 358             } else {
 359                 push @addresses, $ip;
 360             }
 361         }
 362         if (@addresses) {
 363             $content .= "${i}addresses:\n";
 364             $content .= "${i}- '$_'\n" foreach @addresses;
 365         }
 366         if (defined(my $gw = $ipconfig->{gw})) {
 367             $content .= "${i}gateway4: '$gw'\n";
 368         }
 369         if (defined(my $gw = $ipconfig->{gw6})) {
 370             $content .= "${i}gateway6: '$gw'\n";
 371         }
 372
 373         next if $dns_done;
 374         $dns_done = 1;
 375
 376         my ($searchdomains, $nameservers) = get_dns_conf($conf);
 377         if ($searchdomains || $nameservers) {
 378             $content .= "${i}nameservers:\n";
 379             if (defined($nameservers) && @$nameservers) {
 380                 $content .= "${i}  addresses:\n";
 381                 $content .= "${i}  - '$_'\n" foreach @$nameservers;
 382             }
 383             if (defined($searchdomains) && @$searchdomains) {
 384                 $content .= "${i}  search:\n";
 385                 $content .= "${i}  - '$_'\n" foreach @$searchdomains;
 386             }
 387         }
 388     }
 389
 390     return $head.$content;
 391 }
 392
 393 sub nocloud_network {
 394     my ($conf) = @_;
 395
 396     my $content = "version: 1\n"
 397                 . "config:\n";
 398
 399     my @ifaces = grep { /^net(\d+)$/ } keys %$conf;
 400     foreach my $iface (sort @ifaces) {
 401         (my $id = $iface) =~ s/^net//;
 402         next if !$conf->{"ipconfig$id"};
 403
 404         # indentation - network interfaces are inside an 'ethernets' hash
 405         my $i = '    ';
 406
 407         my $net = PVE::QemuServer::parse_net($conf->{$iface});
 408         my $ipconfig = PVE::QemuServer::parse_ipconfig($conf->{"ipconfig$id"});
 409
 410         my $mac = lc($net->{macaddr})
 411             or die "network interface '$iface' has no mac address\n";
 412
 413         $content .= "${i}- type: physical\n"
 414                   . "${i}  name: eth$id\n"
 415                   . "${i}  mac_address: '$mac'\n"
 416                   . "${i}  subnets:\n";
 417         $i .= '  ';
 418         if (defined(my $ip = $ipconfig->{ip})) {
 419             if ($ip eq 'dhcp') {
 420                 $content .= "${i}- type: dhcp4\n";
 421             } else {
 422                 my ($addr, $mask) = split_ip4($ip);
 423                 $content .= "${i}- type: static\n"
 424                           . "${i}  address: '$addr'\n"
 425                           . "${i}  netmask: '$mask'\n";
 426                 if (defined(my $gw = $ipconfig->{gw})) {
 427                     $content .= "${i}  gateway: '$gw'\n";
 428                 }
 429             }
 430         }
 431         if (defined(my $ip = $ipconfig->{ip6})) {
 432             if ($ip eq 'dhcp') {
 433                 $content .= "${i}- type: dhcp6\n";
 434             } elsif ($ip eq 'auto') {
 435                 # SLAAC is only supported by cloud-init since 19.4
 436                 $content .= "${i}- type: ipv6_slaac\n";
 437             } else {
 438                 $content .= "${i}- type: static6\n"
 439                        . "${i}  address: '$ip'\n";
 440                 if (defined(my $gw = $ipconfig->{gw6})) {
 441                     $content .= "${i}  gateway: '$gw'\n";
 442                 }
 443             }
 444         }
 445     }
 446
 447     my $i = '    ';
 448     my ($searchdomains, $nameservers) = get_dns_conf($conf);
 449     if ($searchdomains || $nameservers) {
 450         $content .= "${i}- type: nameserver\n";
 451         if (defined($nameservers) && @$nameservers) {
 452             $content .= "${i}  address:\n";
 453             $content .= "${i}  - '$_'\n" foreach @$nameservers;
 454         }
 455         if (defined($searchdomains) && @$searchdomains) {
 456             $content .= "${i}  search:\n";
 457             $content .= "${i}  - '$_'\n" foreach @$searchdomains;
 458         }
 459     }
 460
 461     return $content;
 462 }
 463
 464 sub nocloud_metadata {
 465     my ($uuid) = @_;
 466     return "instance-id: $uuid\n";
 467 }
 468
 469 sub nocloud_gen_metadata {
 470     my ($user, $network) = @_;
 471
 472     my $uuid_str = Digest::SHA::sha1_hex($user.$network);
 473     return nocloud_metadata($uuid_str);
 474 }
 475
 476 sub generate_nocloud {
 477     my ($conf, $vmid, $drive, $volname, $storeid) = @_;
 478
 479     my ($user_data, $network_data, $meta_data) = get_custom_cloudinit_files($conf);
 480     $user_data = cloudinit_userdata($conf, $vmid) if !defined($user_data);
 481     $network_data = nocloud_network($conf) if !defined($network_data);
 482
 483     if (!defined($meta_data)) {
 484         $meta_data = nocloud_gen_metadata($user_data, $network_data);
 485     }
 486
 487     my $files = {
 488         '/user-data' => $user_data,
 489         '/network-config' => $network_data,
 490         '/meta-data' => $meta_data
 491     };
 492     commit_cloudinit_disk($conf, $vmid, $drive, $volname, $storeid, $files, 'cidata');
 493 }
 494
 495 sub get_custom_cloudinit_files {
 496     my ($conf) = @_;
 497
 498     my $cicustom = $conf->{cicustom};
 499     my $files = $cicustom ? PVE::JSONSchema::parse_property_string('pve-qm-cicustom', $cicustom) : {};
 500
 501     my $network_volid = $files->{network};
 502     my $user_volid = $files->{user};
 503     my $meta_volid = $files->{meta};
 504
 505     my $storage_conf = PVE::Storage::config();
 506
 507     my $network_data;
 508     if ($network_volid) {
 509         $network_data = read_cloudinit_snippets_file($storage_conf, $network_volid);
 510     }
 511
 512     my $user_data;
 513     if ($user_volid) {
 514         $user_data = read_cloudinit_snippets_file($storage_conf, $user_volid);
 515     }
 516
 517     my $meta_data;
 518     if ($meta_volid) {
 519         $meta_data = read_cloudinit_snippets_file($storage_conf, $meta_volid);
 520     }
 521
 522     return ($user_data, $network_data, $meta_data);
 523 }
 524
 525 sub read_cloudinit_snippets_file {
 526     my ($storage_conf, $volid) = @_;
 527
 528     my ($full_path, undef, $type) = PVE::Storage::path($storage_conf, $volid);
 529     die "$volid is not in the snippets directory\n" if $type ne 'snippets';
 530     return PVE::Tools::file_get_contents($full_path, 1 * 1024 * 1024);
 531 }
 532
 533 my $cloudinit_methods = {
 534     configdrive2 => \&generate_configdrive2,
 535     nocloud => \&generate_nocloud,
 536     opennebula => \&generate_opennebula,
 537 };
 538
 539 sub generate_cloudinitconfig {
 540     my ($conf, $vmid) = @_;
 541
 542     my $format = get_cloudinit_format($conf);
 543
 544     PVE::QemuConfig->foreach_volume($conf, sub {
 545         my ($ds, $drive) = @_;
 546
 547         my ($storeid, $volname) = PVE::Storage::parse_volume_id($drive->{file}, 1);
 548
 549         return if !$volname || $volname !~ m/vm-$vmid-cloudinit/;
 550
 551         my $generator = $cloudinit_methods->{$format}
 552             or die "missing cloudinit methods for format '$format'\n";
 553
 554         $generator->($conf, $vmid, $drive, $volname, $storeid);
 555     });
 556 }
 557
 558 sub dump_cloudinit_config {
 559     my ($conf, $vmid, $type) = @_;
 560
 561     my $format = get_cloudinit_format($conf);
 562
 563     if ($type eq 'user') {
 564         return cloudinit_userdata($conf, $vmid);
 565     } elsif ($type eq 'network') {
 566         if ($format eq 'nocloud') {
 567             return nocloud_network($conf);
 568         } else {
 569             return configdrive2_network($conf);
 570         }
 571     } else { # metadata config
 572         my $user = cloudinit_userdata($conf, $vmid);
 573         if ($format eq 'nocloud') {
 574             my $network = nocloud_network($conf);
 575             return nocloud_gen_metadata($user, $network);
 576         } else {
 577             my $network = configdrive2_network($conf);
 578             return configdrive2_gen_metadata($user, $network);
 579         }
 580     }
 581 }
 582
 583 1;