qemu_memory_hotplug: remove unused $opt arg
[qemu-server.git] / PVE / QemuServer / Cloudinit.pm
1 package PVE::QemuServer::Cloudinit;
2
3 use strict;
4 use warnings;
5
6 use File::Path;
7 use Digest::SHA;
8 use URI::Escape;
9 use MIME::Base64 qw(encode_base64);
10
11 use PVE::Tools qw(run_command file_set_contents);
12 use PVE::Storage;
13 use PVE::QemuServer;
14
15 use constant CLOUDINIT_DISK_SIZE => 4 * 1024 * 1024; # 4MiB in bytes
16
17 sub commit_cloudinit_disk {
18 my ($conf, $vmid, $drive, $volname, $storeid, $files, $label) = @_;
19
20 my $path = "/run/pve/cloudinit/$vmid/";
21 mkpath $path;
22 foreach my $filepath (keys %$files) {
23 if ($filepath !~ m@^(.*)\/[^/]+$@) {
24 die "internal error: bad file name in cloud-init image: $filepath\n";
25 }
26 my $dirname = $1;
27 mkpath "$path/$dirname";
28
29 my $contents = $files->{$filepath};
30 file_set_contents("$path/$filepath", $contents);
31 }
32
33 my $storecfg = PVE::Storage::config();
34 my $iso_path = PVE::Storage::path($storecfg, $drive->{file});
35 my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
36 my $format = PVE::QemuServer::qemu_img_format($scfg, $volname);
37
38 my $size = eval { PVE::Storage::volume_size_info($storecfg, $drive->{file}) };
39 if (!defined($size) || $size <= 0) {
40 $volname =~ m/(vm-$vmid-cloudinit(.\Q$format\E)?)/;
41 my $name = $1;
42 $size = 4 * 1024;
43 PVE::Storage::vdisk_alloc($storecfg, $storeid, $vmid, $format, $name, $size);
44 $size *= 1024; # vdisk alloc takes KB, qemu-img dd's osize takes byte
45 }
46 my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
47 $plugin->activate_volume($storeid, $scfg, $volname);
48
49 print "generating cloud-init ISO\n";
50 eval {
51 run_command([
52 ['genisoimage', '-quiet', '-iso-level', '3', '-R', '-V', $label, $path],
53 ['qemu-img', 'dd', '-n', '-f', 'raw', '-O', $format, 'isize=0', "osize=$size", "of=$iso_path"]
54 ]);
55 };
56 my $err = $@;
57 rmtree($path);
58 die $err if $err;
59 }
60
61 sub get_cloudinit_format {
62 my ($conf) = @_;
63 if (defined(my $format = $conf->{citype})) {
64 return $format;
65 }
66
67 # No format specified, default based on ostype because windows'
68 # cloudbased-init only supports configdrivev2, whereas on linux we need
69 # to use mac addresses because regular cloudinit doesn't map 'ethX' to
70 # the new predicatble network device naming scheme.
71 if (defined(my $ostype = $conf->{ostype})) {
72 return 'configdrive2'
73 if PVE::QemuServer::windows_version($ostype);
74 }
75
76 return 'nocloud';
77 }
78
79 sub get_hostname_fqdn {
80 my ($conf, $vmid) = @_;
81 my $hostname = $conf->{name} // "VM$vmid";
82 my $fqdn;
83 if ($hostname =~ /\./) {
84 $fqdn = $hostname;
85 $hostname =~ s/\..*$//;
86 } elsif (my $search = $conf->{searchdomain}) {
87 $fqdn = "$hostname.$search";
88 }
89 return ($hostname, $fqdn);
90 }
91
92 sub get_dns_conf {
93 my ($conf) = @_;
94
95 # Same logic as in pve-container, but without the testcase special case
96 my $host_resolv_conf = PVE::INotify::read_file('resolvconf');
97
98 my $searchdomains = [
99 split(/\s+/, $conf->{searchdomain} // $host_resolv_conf->{search})
100 ];
101
102 my $nameserver = $conf->{nameserver};
103 if (!defined($nameserver)) {
104 $nameserver = [grep { $_ } $host_resolv_conf->@{qw(dns1 dns2 dns3)}];
105 } else {
106 $nameserver = [split(/\s+/, $nameserver)];
107 }
108
109 return ($searchdomains, $nameserver);
110 }
111
112 sub cloudinit_userdata {
113 my ($conf, $vmid) = @_;
114
115 my ($hostname, $fqdn) = get_hostname_fqdn($conf, $vmid);
116
117 my $content = "#cloud-config\n";
118
119 $content .= "hostname: $hostname\n";
120 $content .= "manage_etc_hosts: true\n";
121 $content .= "fqdn: $fqdn\n" if defined($fqdn);
122
123 my $username = $conf->{ciuser};
124 my $password = $conf->{cipassword};
125
126 $content .= "user: $username\n" if defined($username);
127 $content .= "disable_root: False\n" if defined($username) && $username eq 'root';
128 $content .= "password: $password\n" if defined($password);
129
130 if (defined(my $keys = $conf->{sshkeys})) {
131 $keys = URI::Escape::uri_unescape($keys);
132 $keys = [map { my $key = $_; chomp $key; $key } split(/\n/, $keys)];
133 $keys = [grep { /\S/ } @$keys];
134 $content .= "ssh_authorized_keys:\n";
135 foreach my $k (@$keys) {
136 $content .= " - $k\n";
137 }
138 }
139 $content .= "chpasswd:\n";
140 $content .= " expire: False\n";
141
142 if (!defined($username) || $username ne 'root') {
143 $content .= "users:\n";
144 $content .= " - default\n";
145 }
146
147 $content .= "package_upgrade: true\n";
148
149 return $content;
150 }
151
152 sub split_ip4 {
153 my ($ip) = @_;
154 my ($addr, $mask) = split('/', $ip);
155 die "not a CIDR: $ip\n" if !defined $mask;
156 return ($addr, $PVE::Network::ipv4_reverse_mask->[$mask]);
157 }
158
159 sub configdrive2_network {
160 my ($conf) = @_;
161
162 my $content = "auto lo\n";
163 $content .= "iface lo inet loopback\n\n";
164
165 my ($searchdomains, $nameservers) = get_dns_conf($conf);
166 if ($nameservers && @$nameservers) {
167 $nameservers = join(' ', @$nameservers);
168 $content .= " dns_nameservers $nameservers\n";
169 }
170 if ($searchdomains && @$searchdomains) {
171 $searchdomains = join(' ', @$searchdomains);
172 $content .= " dns_search $searchdomains\n";
173 }
174
175 my @ifaces = grep { /^net(\d+)$/ } keys %$conf;
176 foreach my $iface (sort @ifaces) {
177 (my $id = $iface) =~ s/^net//;
178 next if !$conf->{"ipconfig$id"};
179 my $net = PVE::QemuServer::parse_ipconfig($conf->{"ipconfig$id"});
180 $id = "eth$id";
181
182 $content .="auto $id\n";
183 if ($net->{ip}) {
184 if ($net->{ip} eq 'dhcp') {
185 $content .= "iface $id inet dhcp\n";
186 } else {
187 my ($addr, $mask) = split_ip4($net->{ip});
188 $content .= "iface $id inet static\n";
189 $content .= " address $addr\n";
190 $content .= " netmask $mask\n";
191 $content .= " gateway $net->{gw}\n" if $net->{gw};
192 }
193 }
194 if ($net->{ip6}) {
195 if ($net->{ip6} =~ /^(auto|dhcp)$/) {
196 $content .= "iface $id inet6 $1\n";
197 } else {
198 my ($addr, $mask) = split('/', $net->{ip6});
199 $content .= "iface $id inet6 static\n";
200 $content .= " address $addr\n";
201 $content .= " netmask $mask\n";
202 $content .= " gateway $net->{gw6}\n" if $net->{gw6};
203 }
204 }
205 }
206
207 return $content;
208 }
209
210 sub configdrive2_gen_metadata {
211 my ($user, $network) = @_;
212
213 my $uuid_str = Digest::SHA::sha1_hex($user.$network);
214 return configdrive2_metadata($uuid_str);
215 }
216
217 sub configdrive2_metadata {
218 my ($uuid) = @_;
219 return <<"EOF";
220 {
221 "uuid": "$uuid",
222 "network_config": { "content_path": "/content/0000" }
223 }
224 EOF
225 }
226
227 sub generate_configdrive2 {
228 my ($conf, $vmid, $drive, $volname, $storeid) = @_;
229
230 my ($user_data, $network_data, $meta_data) = get_custom_cloudinit_files($conf);
231 $user_data = cloudinit_userdata($conf, $vmid) if !defined($user_data);
232 $network_data = configdrive2_network($conf) if !defined($network_data);
233
234 if (!defined($meta_data)) {
235 $meta_data = configdrive2_gen_metadata($user_data, $network_data);
236 }
237 my $files = {
238 '/openstack/latest/user_data' => $user_data,
239 '/openstack/content/0000' => $network_data,
240 '/openstack/latest/meta_data.json' => $meta_data
241 };
242 commit_cloudinit_disk($conf, $vmid, $drive, $volname, $storeid, $files, 'config-2');
243 }
244
245 sub generate_opennebula {
246 my ($conf, $vmid, $drive, $volname, $storeid) = @_;
247
248 my ($hostname, $fqdn) = get_hostname_fqdn($conf, $vmid);
249
250 my $content = "";
251
252 my $username = $conf->{ciuser} || "root";
253 my $password = encode_base64($conf->{cipassword}) if defined($conf->{cipassword});
254
255 $content .= "USERNAME=$username\n" if defined($username);
256 $content .= "CRYPTED_PASSWORD_BASE64=$password\n" if defined($password);
257
258 if (defined(my $keys = $conf->{sshkeys})) {
259 $keys = URI::Escape::uri_unescape($keys);
260 $keys = [map { my $key = $_; chomp $key; $key } split(/\n/, $keys)];
261 $keys = [grep { /\S/ } @$keys];
262 $content .= "SSH_PUBLIC_KEY=\"";
263
264 foreach my $k (@$keys) {
265 $content .= "$k\n";
266 }
267 $content .= "\"\n";
268
269 }
270
271 my ($searchdomains, $nameservers) = get_dns_conf($conf);
272 if ($nameservers && @$nameservers) {
273 $nameservers = join(' ', @$nameservers);
274 $content .= "DNS=\"$nameservers\"\n";
275 }
276
277 $content .= "SET_HOSTNAME=$hostname\n";
278
279 if ($searchdomains && @$searchdomains) {
280 $searchdomains = join(' ', @$searchdomains);
281 $content .= "SEARCH_DOMAIN=\"$searchdomains\"\n";
282 }
283
284 my $networkenabled = undef;
285 my @ifaces = grep { /^net(\d+)$/ } keys %$conf;
286 foreach my $iface (sort @ifaces) {
287 (my $id = $iface) =~ s/^net//;
288 my $net = PVE::QemuServer::parse_net($conf->{$iface});
289 next if !$conf->{"ipconfig$id"};
290 my $ipconfig = PVE::QemuServer::parse_ipconfig($conf->{"ipconfig$id"});
291 my $ethid = "ETH$id";
292
293 my $mac = lc $net->{hwaddr};
294
295 if ($ipconfig->{ip}) {
296 $networkenabled = 1;
297
298 if ($ipconfig->{ip} eq 'dhcp') {
299 $content .= $ethid."_DHCP=YES\n";
300 } else {
301 my ($addr, $mask) = split_ip4($ipconfig->{ip});
302 $content .= $ethid."_IP=$addr\n";
303 $content .= $ethid."_MASK=$mask\n";
304 $content .= $ethid."_MAC=$mac\n";
305 $content .= $ethid."_GATEWAY=$ipconfig->{gw}\n" if $ipconfig->{gw};
306 }
307 $content .= $ethid."_MTU=$net->{mtu}\n" if $net->{mtu};
308 }
309
310 if ($ipconfig->{ip6}) {
311 $networkenabled = 1;
312 if ($ipconfig->{ip6} eq 'dhcp') {
313 $content .= $ethid."_DHCP6=YES\n";
314 } elsif ($ipconfig->{ip6} eq 'auto') {
315 $content .= $ethid."_AUTO6=YES\n";
316 } else {
317 my ($addr, $mask) = split('/', $ipconfig->{ip6});
318 $content .= $ethid."_IP6=$addr\n";
319 $content .= $ethid."_MASK6=$mask\n";
320 $content .= $ethid."_MAC6=$mac\n";
321 $content .= $ethid."_GATEWAY6=$ipconfig->{gw6}\n" if $ipconfig->{gw6};
322 }
323 $content .= $ethid."_MTU=$net->{mtu}\n" if $net->{mtu};
324 }
325 }
326
327 $content .= "NETWORK=YES\n" if $networkenabled;
328
329 my $files = {
330 '/context.sh' => $content,
331 };
332 commit_cloudinit_disk($conf, $vmid, $drive, $volname, $storeid, $files, 'CONTEXT');
333 }
334
335 sub nocloud_network_v2 {
336 my ($conf) = @_;
337
338 my $content = '';
339
340 my $head = "version: 2\n"
341 . "ethernets:\n";
342
343 my $dns_done;
344
345 my @ifaces = grep { /^net(\d+)$/ } keys %$conf;
346 foreach my $iface (sort @ifaces) {
347 (my $id = $iface) =~ s/^net//;
348 next if !$conf->{"ipconfig$id"};
349
350 # indentation - network interfaces are inside an 'ethernets' hash
351 my $i = ' ';
352
353 my $net = PVE::QemuServer::parse_net($conf->{$iface});
354 my $ipconfig = PVE::QemuServer::parse_ipconfig($conf->{"ipconfig$id"});
355
356 my $mac = $net->{macaddr}
357 or die "network interface '$iface' has no mac address\n";
358
359 $content .= "${i}$iface:\n";
360 $i .= ' ';
361 $content .= "${i}match:\n"
362 . "${i} macaddress: \"$mac\"\n"
363 . "${i}set-name: eth$id\n";
364 my @addresses;
365 if (defined(my $ip = $ipconfig->{ip})) {
366 if ($ip eq 'dhcp') {
367 $content .= "${i}dhcp4: true\n";
368 } else {
369 push @addresses, $ip;
370 }
371 }
372 if (defined(my $ip = $ipconfig->{ip6})) {
373 if ($ip eq 'dhcp') {
374 $content .= "${i}dhcp6: true\n";
375 } else {
376 push @addresses, $ip;
377 }
378 }
379 if (@addresses) {
380 $content .= "${i}addresses:\n";
381 $content .= "${i}- '$_'\n" foreach @addresses;
382 }
383 if (defined(my $gw = $ipconfig->{gw})) {
384 $content .= "${i}gateway4: '$gw'\n";
385 }
386 if (defined(my $gw = $ipconfig->{gw6})) {
387 $content .= "${i}gateway6: '$gw'\n";
388 }
389
390 next if $dns_done;
391 $dns_done = 1;
392
393 my ($searchdomains, $nameservers) = get_dns_conf($conf);
394 if ($searchdomains || $nameservers) {
395 $content .= "${i}nameservers:\n";
396 if (defined($nameservers) && @$nameservers) {
397 $content .= "${i} addresses:\n";
398 $content .= "${i} - '$_'\n" foreach @$nameservers;
399 }
400 if (defined($searchdomains) && @$searchdomains) {
401 $content .= "${i} search:\n";
402 $content .= "${i} - '$_'\n" foreach @$searchdomains;
403 }
404 }
405 }
406
407 return $head.$content;
408 }
409
410 sub nocloud_network {
411 my ($conf) = @_;
412
413 my $content = "version: 1\n"
414 . "config:\n";
415
416 my @ifaces = grep { /^net(\d+)$/ } keys %$conf;
417 foreach my $iface (sort @ifaces) {
418 (my $id = $iface) =~ s/^net//;
419 next if !$conf->{"ipconfig$id"};
420
421 # indentation - network interfaces are inside an 'ethernets' hash
422 my $i = ' ';
423
424 my $net = PVE::QemuServer::parse_net($conf->{$iface});
425 my $ipconfig = PVE::QemuServer::parse_ipconfig($conf->{"ipconfig$id"});
426
427 my $mac = lc($net->{macaddr})
428 or die "network interface '$iface' has no mac address\n";
429
430 $content .= "${i}- type: physical\n"
431 . "${i} name: eth$id\n"
432 . "${i} mac_address: '$mac'\n"
433 . "${i} subnets:\n";
434 $i .= ' ';
435 if (defined(my $ip = $ipconfig->{ip})) {
436 if ($ip eq 'dhcp') {
437 $content .= "${i}- type: dhcp4\n";
438 } else {
439 my ($addr, $mask) = split_ip4($ip);
440 $content .= "${i}- type: static\n"
441 . "${i} address: '$addr'\n"
442 . "${i} netmask: '$mask'\n";
443 if (defined(my $gw = $ipconfig->{gw})) {
444 $content .= "${i} gateway: '$gw'\n";
445 }
446 }
447 }
448 if (defined(my $ip = $ipconfig->{ip6})) {
449 if ($ip eq 'dhcp') {
450 $content .= "${i}- type: dhcp6\n";
451 } elsif ($ip eq 'auto') {
452 # SLAAC is only supported by cloud-init since 19.4
453 $content .= "${i}- type: ipv6_slaac\n";
454 } else {
455 $content .= "${i}- type: static6\n"
456 . "${i} address: '$ip'\n";
457 if (defined(my $gw = $ipconfig->{gw6})) {
458 $content .= "${i} gateway: '$gw'\n";
459 }
460 }
461 }
462 }
463
464 my $i = ' ';
465 my ($searchdomains, $nameservers) = get_dns_conf($conf);
466 if ($searchdomains || $nameservers) {
467 $content .= "${i}- type: nameserver\n";
468 if (defined($nameservers) && @$nameservers) {
469 $content .= "${i} address:\n";
470 $content .= "${i} - '$_'\n" foreach @$nameservers;
471 }
472 if (defined($searchdomains) && @$searchdomains) {
473 $content .= "${i} search:\n";
474 $content .= "${i} - '$_'\n" foreach @$searchdomains;
475 }
476 }
477
478 return $content;
479 }
480
481 sub nocloud_metadata {
482 my ($uuid) = @_;
483 return "instance-id: $uuid\n";
484 }
485
486 sub nocloud_gen_metadata {
487 my ($user, $network) = @_;
488
489 my $uuid_str = Digest::SHA::sha1_hex($user.$network);
490 return nocloud_metadata($uuid_str);
491 }
492
493 sub generate_nocloud {
494 my ($conf, $vmid, $drive, $volname, $storeid) = @_;
495
496 my ($user_data, $network_data, $meta_data) = get_custom_cloudinit_files($conf);
497 $user_data = cloudinit_userdata($conf, $vmid) if !defined($user_data);
498 $network_data = nocloud_network($conf) if !defined($network_data);
499
500 if (!defined($meta_data)) {
501 $meta_data = nocloud_gen_metadata($user_data, $network_data);
502 }
503
504 my $files = {
505 '/user-data' => $user_data,
506 '/network-config' => $network_data,
507 '/meta-data' => $meta_data
508 };
509 commit_cloudinit_disk($conf, $vmid, $drive, $volname, $storeid, $files, 'cidata');
510 }
511
512 sub get_custom_cloudinit_files {
513 my ($conf) = @_;
514
515 my $cicustom = $conf->{cicustom};
516 my $files = $cicustom ? PVE::JSONSchema::parse_property_string('pve-qm-cicustom', $cicustom) : {};
517
518 my $network_volid = $files->{network};
519 my $user_volid = $files->{user};
520 my $meta_volid = $files->{meta};
521
522 my $storage_conf = PVE::Storage::config();
523
524 my $network_data;
525 if ($network_volid) {
526 $network_data = read_cloudinit_snippets_file($storage_conf, $network_volid);
527 }
528
529 my $user_data;
530 if ($user_volid) {
531 $user_data = read_cloudinit_snippets_file($storage_conf, $user_volid);
532 }
533
534 my $meta_data;
535 if ($meta_volid) {
536 $meta_data = read_cloudinit_snippets_file($storage_conf, $meta_volid);
537 }
538
539 return ($user_data, $network_data, $meta_data);
540 }
541
542 sub read_cloudinit_snippets_file {
543 my ($storage_conf, $volid) = @_;
544
545 my ($full_path, undef, $type) = PVE::Storage::path($storage_conf, $volid);
546 die "$volid is not in the snippets directory\n" if $type ne 'snippets';
547 return PVE::Tools::file_get_contents($full_path, 1 * 1024 * 1024);
548 }
549
550 my $cloudinit_methods = {
551 configdrive2 => \&generate_configdrive2,
552 nocloud => \&generate_nocloud,
553 opennebula => \&generate_opennebula,
554 };
555
556 sub generate_cloudinitconfig {
557 my ($conf, $vmid) = @_;
558
559 my $format = get_cloudinit_format($conf);
560
561 PVE::QemuConfig->foreach_volume($conf, sub {
562 my ($ds, $drive) = @_;
563
564 my ($storeid, $volname) = PVE::Storage::parse_volume_id($drive->{file}, 1);
565
566 return if !$volname || $volname !~ m/vm-$vmid-cloudinit/;
567
568 my $generator = $cloudinit_methods->{$format}
569 or die "missing cloudinit methods for format '$format'\n";
570
571 $generator->($conf, $vmid, $drive, $volname, $storeid);
572 });
573 }
574
575 sub dump_cloudinit_config {
576 my ($conf, $vmid, $type) = @_;
577
578 my $format = get_cloudinit_format($conf);
579
580 if ($type eq 'user') {
581 return cloudinit_userdata($conf, $vmid);
582 } elsif ($type eq 'network') {
583 if ($format eq 'nocloud') {
584 return nocloud_network($conf);
585 } else {
586 return configdrive2_network($conf);
587 }
588 } else { # metadata config
589 my $user = cloudinit_userdata($conf, $vmid);
590 if ($format eq 'nocloud') {
591 my $network = nocloud_network($conf);
592 return nocloud_gen_metadata($user, $network);
593 } else {
594 my $network = configdrive2_network($conf);
595 return configdrive2_gen_metadata($user, $network);
596 }
597 }
598 }
599
600 1;