PVE/QemuServer/Memory.pm

   1 package PVE::QemuServer::Memory;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::Tools qw(run_command lock_file lock_file_full file_read_firstline dir_glob_foreach);
   7 use PVE::Exception qw(raise raise_param_exc);
   8
   9 use PVE::QemuServer;
  10 use PVE::QemuServer::Monitor qw(mon_cmd);
  11
  12 my $MAX_NUMA = 8;
  13 my $MAX_MEM = 4194304;
  14 my $STATICMEM = 1024;
  15
  16 sub get_numa_node_list {
  17     my ($conf) = @_;
  18     my @numa_map;
  19     for (my $i = 0; $i < $MAX_NUMA; $i++) {
  20         my $entry = $conf->{"numa$i"} or next;
  21         my $numa = PVE::QemuServer::parse_numa($entry) or next;
  22         push @numa_map, $i;
  23     }
  24     return @numa_map if @numa_map;
  25     my $sockets = $conf->{sockets} || 1;
  26     return (0..($sockets-1));
  27 }
  28
  29 # only valid when numa nodes map to a single host node
  30 sub get_numa_guest_to_host_map {
  31     my ($conf) = @_;
  32     my $map = {};
  33     for (my $i = 0; $i < $MAX_NUMA; $i++) {
  34         my $entry = $conf->{"numa$i"} or next;
  35         my $numa = PVE::QemuServer::parse_numa($entry) or next;
  36         $map->{$i} = print_numa_hostnodes($numa->{hostnodes});
  37     }
  38     return $map if %$map;
  39     my $sockets = $conf->{sockets} || 1;
  40     return {map { $_ => $_ } (0..($sockets-1))};
  41 }
  42
  43 sub foreach_dimm{
  44     my ($conf, $vmid, $memory, $sockets, $func) = @_;
  45
  46     my $dimm_id = 0;
  47     my $current_size = 0;
  48     my $dimm_size = 0;
  49
  50     if($conf->{hugepages} && $conf->{hugepages} == 1024) {
  51         $current_size = 1024 * $sockets;
  52         $dimm_size = 1024;
  53     } else {
  54         $current_size = 1024;
  55         $dimm_size = 512;
  56     }
  57
  58     return if $current_size == $memory;
  59
  60     my @numa_map = get_numa_node_list($conf);
  61
  62     for (my $j = 0; $j < 8; $j++) {
  63         for (my $i = 0; $i < 32; $i++) {
  64             my $name = "dimm${dimm_id}";
  65             $dimm_id++;
  66             my $numanode = $numa_map[$i % @numa_map];
  67             $current_size += $dimm_size;
  68             &$func($conf, $vmid, $name, $dimm_size, $numanode, $current_size, $memory);
  69             return  $current_size if $current_size >= $memory;
  70         }
  71         $dimm_size *= 2;
  72     }
  73 }
  74
  75 sub foreach_reverse_dimm {
  76     my ($conf, $vmid, $memory, $sockets, $func) = @_;
  77
  78     my $dimm_id = 253;
  79     my $current_size = 0;
  80     my $dimm_size = 0;
  81
  82     if($conf->{hugepages} && $conf->{hugepages} == 1024) {
  83         $current_size = 8355840;
  84         $dimm_size = 131072;
  85     } else {
  86         $current_size = 4177920;
  87         $dimm_size = 65536;
  88     }
  89
  90     return if $current_size == $memory;
  91
  92     my @numa_map = get_numa_node_list($conf);
  93
  94     for (my $j = 0; $j < 8; $j++) {
  95         for (my $i = 0; $i < 32; $i++) {
  96             my $name = "dimm${dimm_id}";
  97             $dimm_id--;
  98             my $numanode = $numa_map[(31-$i) % @numa_map];
  99             $current_size -= $dimm_size;
 100             &$func($conf, $vmid, $name, $dimm_size, $numanode, $current_size, $memory);
 101             return  $current_size if $current_size <= $memory;
 102         }
 103         $dimm_size /= 2;
 104     }
 105 }
 106
 107 sub qemu_memory_hotplug {
 108     my ($vmid, $conf, $defaults, $opt, $value) = @_;
 109
 110     return $value if !PVE::QemuServer::check_running($vmid);
 111
 112     my $sockets = 1;
 113     $sockets = $conf->{sockets} if $conf->{sockets};
 114
 115     my $memory = $conf->{memory} || $defaults->{memory};
 116     $value = $defaults->{memory} if !$value;
 117     return $value if $value == $memory;
 118
 119     my $static_memory = $STATICMEM;
 120     $static_memory = $static_memory * $sockets if ($conf->{hugepages} && $conf->{hugepages} == 1024);
 121
 122     die "memory can't be lower than $static_memory MB" if $value < $static_memory;
 123     die "you cannot add more memory than $MAX_MEM MB!\n" if $memory > $MAX_MEM;
 124
 125     if($value > $memory) {
 126
 127         my $numa_hostmap;
 128
 129         foreach_dimm($conf, $vmid, $value, $sockets, sub {
 130             my ($conf, $vmid, $name, $dimm_size, $numanode, $current_size, $memory) = @_;
 131
 132                 return if $current_size <= $conf->{memory};
 133
 134                 if ($conf->{hugepages}) {
 135                     $numa_hostmap = get_numa_guest_to_host_map($conf) if !$numa_hostmap;
 136
 137                     my $hugepages_size = hugepages_size($conf, $dimm_size);
 138                     my $path = hugepages_mount_path($hugepages_size);
 139                     my $host_numanode = $numa_hostmap->{$numanode};
 140                     my $hugepages_topology->{$hugepages_size}->{$host_numanode} = hugepages_nr($dimm_size, $hugepages_size);
 141
 142                     my $code = sub {
 143                         my $hugepages_host_topology = hugepages_host_topology();
 144                         hugepages_allocate($hugepages_topology, $hugepages_host_topology);
 145
 146                         eval { mon_cmd($vmid, "object-add", 'qom-type' => "memory-backend-file", id => "mem-$name", props => {
 147                                              size => int($dimm_size*1024*1024), 'mem-path' => $path, share => JSON::true, prealloc => JSON::true } ); };
 148                         if (my $err = $@) {
 149                             hugepages_reset($hugepages_host_topology);
 150                             die $err;
 151                         }
 152
 153                         hugepages_pre_deallocate($hugepages_topology);
 154                     };
 155                     eval { hugepages_update_locked($code); };
 156
 157                 } else {
 158                     eval { mon_cmd($vmid, "object-add", 'qom-type' => "memory-backend-ram", id => "mem-$name", props => { size => int($dimm_size*1024*1024) } ) };
 159                 }
 160
 161                 if (my $err = $@) {
 162                     eval { PVE::QemuServer::qemu_objectdel($vmid, "mem-$name"); };
 163                     die $err;
 164                 }
 165
 166                 eval { mon_cmd($vmid, "device_add", driver => "pc-dimm", id => "$name", memdev => "mem-$name", node => $numanode) };
 167                 if (my $err = $@) {
 168                     eval { PVE::QemuServer::qemu_objectdel($vmid, "mem-$name"); };
 169                     die $err;
 170                 }
 171                 #update conf after each succesful module hotplug
 172                 $conf->{memory} = $current_size;
 173                 PVE::QemuConfig->write_config($vmid, $conf);
 174         });
 175
 176     } else {
 177
 178         foreach_reverse_dimm($conf, $vmid, $value, $sockets, sub {
 179             my ($conf, $vmid, $name, $dimm_size, $numanode, $current_size, $memory) = @_;
 180
 181                 return if $current_size >= $conf->{memory};
 182                 print "try to unplug memory dimm $name\n";
 183
 184                 my $retry = 0;
 185                 while (1) {
 186                     eval { PVE::QemuServer::qemu_devicedel($vmid, $name) };
 187                     sleep 3;
 188                     my $dimm_list = qemu_dimm_list($vmid);
 189                     last if !$dimm_list->{$name};
 190                     raise_param_exc({ $name => "error unplug memory module" }) if $retry > 5;
 191                     $retry++;
 192                 }
 193
 194                 #update conf after each succesful module unplug
 195                 $conf->{memory} = $current_size;
 196
 197                 eval { PVE::QemuServer::qemu_objectdel($vmid, "mem-$name"); };
 198                 PVE::QemuConfig->write_config($vmid, $conf);
 199         });
 200     }
 201 }
 202
 203 sub qemu_dimm_list {
 204     my ($vmid) = @_;
 205
 206     my $dimmarray = mon_cmd($vmid, "query-memory-devices");
 207     my $dimms = {};
 208
 209     foreach my $dimm (@$dimmarray) {
 210
 211         $dimms->{$dimm->{data}->{id}}->{id} = $dimm->{data}->{id};
 212         $dimms->{$dimm->{data}->{id}}->{node} = $dimm->{data}->{node};
 213         $dimms->{$dimm->{data}->{id}}->{addr} = $dimm->{data}->{addr};
 214         $dimms->{$dimm->{data}->{id}}->{size} = $dimm->{data}->{size};
 215         $dimms->{$dimm->{data}->{id}}->{slot} = $dimm->{data}->{slot};
 216     }
 217     return $dimms;
 218 }
 219
 220 sub config {
 221     my ($conf, $vmid, $sockets, $cores, $defaults, $hotplug_features, $cmd) = @_;
 222
 223     my $memory = $conf->{memory} || $defaults->{memory};
 224     my $static_memory = 0;
 225
 226     if ($hotplug_features->{memory}) {
 227         die "NUMA needs to be enabled for memory hotplug\n" if !$conf->{numa};
 228         die "Total memory is bigger than ${MAX_MEM}MB\n" if $memory > $MAX_MEM;
 229
 230         for (my $i = 0; $i < $MAX_NUMA; $i++) {
 231             die "cannot enable memory hotplugging with custom NUMA topology\n"
 232                 if $conf->{"numa$i"};
 233         }
 234
 235         my $sockets = 1;
 236         $sockets = $conf->{sockets} if $conf->{sockets};
 237
 238         $static_memory = $STATICMEM;
 239         $static_memory = $static_memory * $sockets if ($conf->{hugepages} && $conf->{hugepages} == 1024);
 240
 241         die "minimum memory must be ${static_memory}MB\n" if($memory < $static_memory);
 242         push @$cmd, '-m', "size=${static_memory},slots=255,maxmem=${MAX_MEM}M";
 243
 244     } else {
 245
 246         $static_memory = $memory;
 247         push @$cmd, '-m', $static_memory;
 248     }
 249
 250     die "numa needs to be enabled to use hugepages" if $conf->{hugepages} && !$conf->{numa};
 251
 252     if ($conf->{numa}) {
 253
 254         my $numa_totalmemory = undef;
 255         for (my $i = 0; $i < $MAX_NUMA; $i++) {
 256             next if !$conf->{"numa$i"};
 257             my $numa = PVE::QemuServer::parse_numa($conf->{"numa$i"});
 258             next if !$numa;
 259             # memory
 260             die "missing NUMA node$i memory value\n" if !$numa->{memory};
 261             my $numa_memory = $numa->{memory};
 262             $numa_totalmemory += $numa_memory;
 263
 264             my $mem_object = print_mem_object($conf, "ram-node$i", $numa_memory);
 265
 266             # cpus
 267             my $cpulists = $numa->{cpus};
 268             die "missing NUMA node$i cpus\n" if !defined($cpulists);
 269             my $cpus = join(',cpus=', map {
 270                 my ($start, $end) = @$_;
 271                 defined($end) ? "$start-$end" : $start
 272             } @$cpulists);
 273
 274             # hostnodes
 275             my $hostnodelists = $numa->{hostnodes};
 276             if (defined($hostnodelists)) {
 277
 278                 my $hostnodes = print_numa_hostnodes($hostnodelists);
 279
 280                 # policy
 281                 my $policy = $numa->{policy};
 282                 die "you need to define a policy for hostnode $hostnodes\n" if !$policy;
 283                 $mem_object .= ",host-nodes=$hostnodes,policy=$policy";
 284             } else {
 285                 die "numa hostnodes need to be defined to use hugepages" if $conf->{hugepages};
 286             }
 287
 288             push @$cmd, '-object', $mem_object;
 289             push @$cmd, '-numa', "node,nodeid=$i,cpus=$cpus,memdev=ram-node$i";
 290         }
 291
 292         die "total memory for NUMA nodes must be equal to vm static memory\n"
 293             if $numa_totalmemory && $numa_totalmemory != $static_memory;
 294
 295         #if no custom tology, we split memory and cores across numa nodes
 296         if (!$numa_totalmemory) {
 297             my $numa_memory = ($static_memory / $sockets);
 298
 299             for (my $i = 0; $i < $sockets; $i++)  {
 300                 die "host NUMA node$i doesn't exist\n" if ! -d "/sys/devices/system/node/node$i/" && $conf->{hugepages};
 301
 302                 my $mem_object = print_mem_object($conf, "ram-node$i", $numa_memory);
 303                 push @$cmd, '-object', $mem_object;
 304
 305                 my $cpus = ($cores * $i);
 306                 $cpus .= "-" . ($cpus + $cores - 1) if $cores > 1;
 307
 308                 push @$cmd, '-numa', "node,nodeid=$i,cpus=$cpus,memdev=ram-node$i";
 309             }
 310         }
 311     }
 312
 313     if ($hotplug_features->{memory}) {
 314         foreach_dimm($conf, $vmid, $memory, $sockets, sub {
 315             my ($conf, $vmid, $name, $dimm_size, $numanode, $current_size, $memory) = @_;
 316
 317             my $mem_object = print_mem_object($conf, "mem-$name", $dimm_size);
 318
 319             push @$cmd, "-object" , $mem_object;
 320             push @$cmd, "-device", "pc-dimm,id=$name,memdev=mem-$name,node=$numanode";
 321
 322             die "memory size ($memory) must be aligned to $dimm_size for hotplugging\n"
 323                 if $current_size > $memory;
 324         });
 325     }
 326 }
 327
 328 sub print_mem_object {
 329     my ($conf, $id, $size) = @_;
 330
 331     if ($conf->{hugepages}) {
 332
 333         my $hugepages_size = hugepages_size($conf, $size);
 334         my $path = hugepages_mount_path($hugepages_size);
 335
 336         return "memory-backend-file,id=$id,size=${size}M,mem-path=$path,share=on,prealloc=yes";
 337     } else {
 338         return "memory-backend-ram,id=$id,size=${size}M";
 339     }
 340
 341 }
 342
 343 sub print_numa_hostnodes {
 344     my ($hostnodelists) = @_;
 345
 346     my $hostnodes;
 347     foreach my $hostnoderange (@$hostnodelists) {
 348         my ($start, $end) = @$hostnoderange;
 349         $hostnodes .= ',' if $hostnodes;
 350         $hostnodes .= $start;
 351         $hostnodes .= "-$end" if defined($end);
 352         $end //= $start;
 353         for (my $i = $start; $i <= $end; ++$i ) {
 354             die "host NUMA node$i doesn't exist\n" if ! -d "/sys/devices/system/node/node$i/";
 355         }
 356     }
 357     return $hostnodes;
 358 }
 359
 360 sub hugepages_mount {
 361
 362    my $mountdata = PVE::ProcFSTools::parse_proc_mounts();
 363
 364    foreach my $size (qw(2048 1048576)) {
 365         next if (! -d "/sys/kernel/mm/hugepages/hugepages-${size}kB");
 366
 367         my $path = "/run/hugepages/kvm/${size}kB";
 368
 369         my $found = grep {
 370             $_->[2] =~ /^hugetlbfs/ &&
 371             $_->[1] eq $path
 372         } @$mountdata;
 373
 374         if (!$found) {
 375
 376             File::Path::make_path($path) if (!-d $path);
 377             my $cmd = ['/bin/mount', '-t', 'hugetlbfs', '-o', "pagesize=${size}k", 'hugetlbfs', $path];
 378             run_command($cmd, errmsg => "hugepage mount error");
 379         }
 380    }
 381 }
 382
 383 sub hugepages_mount_path {
 384    my ($size) = @_;
 385
 386    $size = $size * 1024;
 387    return "/run/hugepages/kvm/${size}kB";
 388
 389 }
 390
 391 sub hugepages_nr {
 392   my ($size, $hugepages_size) = @_;
 393
 394   return $size / $hugepages_size;
 395 }
 396
 397 sub hugepages_size {
 398     my ($conf, $size) = @_;
 399     die "hugepages option is not enabled" if !$conf->{hugepages};
 400     die "memory size '$size' is not a positive even integer; cannot use for hugepages\n"
 401         if $size <= 0 || $size & 1;
 402
 403     my $page_chunk = sub { -d  "/sys/kernel/mm/hugepages/hugepages-". ($_[0] * 1024) ."kB" };
 404     die "your system doesn't support hugepages\n" if !$page_chunk->(2) && !$page_chunk->(1024);
 405
 406     if ($conf->{hugepages} eq 'any') {
 407
 408         # try to use 1GB if available && memory size is matching
 409         if ($page_chunk->(1024) && ($size & 1023) == 0) {
 410             return 1024;
 411         } elsif ($page_chunk->(2)) {
 412             return 2;
 413         } else {
 414             die "host only supports 1024 GB hugepages, but requested size '$size' is not a multiple of 1024 MB\n"
 415         }
 416     } else {
 417
 418         my $hugepagesize = $conf->{hugepages};
 419
 420         if (!$page_chunk->($hugepagesize)) {
 421             die "your system doesn't support hugepages of $hugepagesize MB\n";
 422         } elsif (($size % $hugepagesize) != 0) {
 423             die "Memory size $size is not a multiple of the requested hugepages size $hugepagesize\n";
 424         }
 425
 426         return $hugepagesize
 427     }
 428 }
 429
 430 sub hugepages_topology {
 431     my ($conf) = @_;
 432
 433     my $hugepages_topology = {};
 434
 435     return if !$conf->{numa};
 436
 437     my $defaults = PVE::QemuServer::load_defaults();
 438     my $memory = $conf->{memory} || $defaults->{memory};
 439     my $static_memory = 0;
 440     my $sockets = 1;
 441     $sockets = $conf->{smp} if $conf->{smp}; # old style - no longer iused
 442     $sockets = $conf->{sockets} if $conf->{sockets};
 443     my $numa_custom_topology = undef;
 444     my $hotplug_features = PVE::QemuServer::parse_hotplug_features(defined($conf->{hotplug}) ? $conf->{hotplug} : '1');
 445
 446     if ($hotplug_features->{memory}) {
 447         $static_memory = $STATICMEM;
 448         $static_memory = $static_memory * $sockets if ($conf->{hugepages} && $conf->{hugepages} == 1024);
 449     } else {
 450         $static_memory = $memory;
 451     }
 452
 453     #custom numa topology
 454     for (my $i = 0; $i < $MAX_NUMA; $i++) {
 455         next if !$conf->{"numa$i"};
 456         my $numa = PVE::QemuServer::parse_numa($conf->{"numa$i"});
 457         next if !$numa;
 458
 459         $numa_custom_topology = 1;
 460         my $numa_memory = $numa->{memory};
 461         my $hostnodelists = $numa->{hostnodes};
 462         my $hostnodes = print_numa_hostnodes($hostnodelists);
 463
 464         die "more than 1 hostnode value in numa node is not supported when hugepages are enabled" if $hostnodes !~ m/^(\d)$/;
 465         my $hugepages_size = hugepages_size($conf, $numa_memory);
 466         $hugepages_topology->{$hugepages_size}->{$hostnodes} += hugepages_nr($numa_memory, $hugepages_size);
 467
 468     }
 469
 470     #if no custom numa tology, we split memory and cores across numa nodes
 471     if(!$numa_custom_topology) {
 472
 473         my $numa_memory = ($static_memory / $sockets);
 474
 475         for (my $i = 0; $i < $sockets; $i++)  {
 476
 477             my $hugepages_size = hugepages_size($conf, $numa_memory);
 478             $hugepages_topology->{$hugepages_size}->{$i} += hugepages_nr($numa_memory, $hugepages_size);
 479         }
 480     }
 481
 482     if ($hotplug_features->{memory}) {
 483         my $numa_hostmap = get_numa_guest_to_host_map($conf);
 484
 485         foreach_dimm($conf, undef, $memory, $sockets, sub {
 486             my ($conf, undef, $name, $dimm_size, $numanode, $current_size, $memory) = @_;
 487
 488             $numanode = $numa_hostmap->{$numanode};
 489
 490             my $hugepages_size = hugepages_size($conf, $dimm_size);
 491             $hugepages_topology->{$hugepages_size}->{$numanode} += hugepages_nr($dimm_size, $hugepages_size);
 492         });
 493     }
 494
 495     return $hugepages_topology;
 496 }
 497
 498 sub hugepages_host_topology {
 499
 500     #read host hugepages
 501     my $hugepages_host_topology = {};
 502
 503     dir_glob_foreach("/sys/devices/system/node/", 'node(\d+)', sub {
 504         my ($nodepath, $numanode) = @_;
 505
 506         dir_glob_foreach("/sys/devices/system/node/$nodepath/hugepages/", 'hugepages\-(\d+)kB', sub {
 507             my ($hugepages_path, $hugepages_size) = @_;
 508
 509             $hugepages_size = $hugepages_size / 1024;
 510             my $hugepages_nr = PVE::Tools::file_read_firstline("/sys/devices/system/node/$nodepath/hugepages/$hugepages_path/nr_hugepages");
 511             $hugepages_host_topology->{$hugepages_size}->{$numanode} = $hugepages_nr;
 512         });
 513     });
 514
 515     return $hugepages_host_topology;
 516 }
 517
 518 sub hugepages_allocate {
 519     my ($hugepages_topology, $hugepages_host_topology) = @_;
 520
 521     #allocate new hupages if needed
 522     foreach my $size (sort keys %$hugepages_topology) {
 523
 524         my $nodes = $hugepages_topology->{$size};
 525
 526         foreach my $numanode (keys %$nodes) {
 527
 528             my $hugepages_size = $size * 1024;
 529             my $hugepages_requested = $hugepages_topology->{$size}->{$numanode};
 530             my $path = "/sys/devices/system/node/node${numanode}/hugepages/hugepages-${hugepages_size}kB/";
 531             my $hugepages_free = PVE::Tools::file_read_firstline($path."free_hugepages");
 532             my $hugepages_nr = PVE::Tools::file_read_firstline($path."nr_hugepages");
 533
 534             if ($hugepages_requested > $hugepages_free) {
 535                 my $hugepages_needed = $hugepages_requested - $hugepages_free;
 536                 PVE::ProcFSTools::write_proc_entry($path."nr_hugepages", $hugepages_nr + $hugepages_needed);
 537                 #verify that is correctly allocated
 538                 $hugepages_free = PVE::Tools::file_read_firstline($path."free_hugepages");
 539                 if ($hugepages_free < $hugepages_requested) {
 540                     #rollback to initial host config
 541                     hugepages_reset($hugepages_host_topology);
 542                     die "hugepage allocation failed";
 543                 }
 544             }
 545
 546         }
 547     }
 548
 549 }
 550
 551 sub hugepages_default_nr_hugepages {
 552     my ($size) = @_;
 553
 554     my $cmdline = PVE::Tools::file_read_firstline("/proc/cmdline");
 555     my $args = PVE::Tools::split_args($cmdline);
 556
 557     my $parsed_size = 2; # default is 2M
 558
 559     foreach my $arg (@$args) {
 560         if ($arg eq "hugepagesz=2M") {
 561             $parsed_size = 2;
 562         } elsif ($arg eq "hugepagesz=1G") {
 563             $parsed_size = 1024;
 564         } elsif ($arg =~ m/^hugepages=(\d+)?$/) {
 565             if ($parsed_size == $size) {
 566                 return $1;
 567             }
 568         }
 569     }
 570
 571     return 0;
 572 }
 573
 574 sub hugepages_pre_deallocate {
 575     my ($hugepages_topology) = @_;
 576
 577     foreach my $size (sort keys %$hugepages_topology) {
 578
 579         my $hugepages_size = $size * 1024;
 580         my $path = "/sys/kernel/mm/hugepages/hugepages-${hugepages_size}kB/";
 581         my $hugepages_nr = hugepages_default_nr_hugepages($size);
 582         PVE::ProcFSTools::write_proc_entry($path."nr_hugepages", $hugepages_nr);
 583     }
 584 }
 585
 586 sub hugepages_reset {
 587     my ($hugepages_topology) = @_;
 588
 589     foreach my $size (sort keys %$hugepages_topology) {
 590
 591         my $nodes = $hugepages_topology->{$size};
 592         foreach my $numanode (keys %$nodes) {
 593
 594             my $hugepages_nr = $hugepages_topology->{$size}->{$numanode};
 595             my $hugepages_size = $size * 1024;
 596             my $path = "/sys/devices/system/node/node${numanode}/hugepages/hugepages-${hugepages_size}kB/";
 597
 598             PVE::ProcFSTools::write_proc_entry($path."nr_hugepages", $hugepages_nr);
 599         }
 600     }
 601 }
 602
 603 sub hugepages_update_locked {
 604     my ($code, @param) = @_;
 605
 606     my $timeout = 60; #could be long if a lot of hugepages need to be alocated
 607
 608     my $lock_filename = "/var/lock/hugepages.lck";
 609
 610     my $res = lock_file($lock_filename, $timeout, $code, @param);
 611     die $@ if $@;
 612
 613     return $res;
 614 }
 615 1;
 616