PVE/VZDump/QemuServer.pm

   1 package PVE::VZDump::QemuServer;
   2
   3 use strict;
   4 use warnings;
   5
   6 use File::Basename;
   7 use File::Path;
   8 use IO::File;
   9 use IPC::Open3;
  10 use JSON;
  11
  12 use PVE::Cluster qw(cfs_read_file);
  13 use PVE::INotify;
  14 use PVE::IPCC;
  15 use PVE::JSONSchema;
  16 use PVE::QMPClient;
  17 use PVE::Storage::Plugin;
  18 use PVE::Storage::PBSPlugin;
  19 use PVE::Storage;
  20 use PVE::Tools;
  21 use PVE::VZDump;
  22
  23 use PVE::QemuConfig;
  24 use PVE::QemuServer;
  25 use PVE::QemuServer::Machine;
  26 use PVE::QemuServer::Monitor qw(mon_cmd);
  27
  28 use base qw (PVE::VZDump::Plugin);
  29
  30 sub new {
  31     my ($class, $vzdump) = @_;
  32
  33     PVE::VZDump::check_bin('qm');
  34
  35     my $self = bless { vzdump => $vzdump }, $class;
  36
  37     $self->{vmlist} = PVE::QemuServer::vzlist();
  38     $self->{storecfg} = PVE::Storage::config();
  39
  40     return $self;
  41 };
  42
  43 sub type {
  44     return 'qemu';
  45 }
  46
  47 sub vmlist {
  48     my ($self) = @_;
  49     return [ keys %{$self->{vmlist}} ];
  50 }
  51
  52 sub prepare {
  53     my ($self, $task, $vmid, $mode) = @_;
  54
  55     $task->{disks} = [];
  56
  57     my $conf = $self->{vmlist}->{$vmid} = PVE::QemuConfig->load_config($vmid);
  58
  59     $self->loginfo("VM Name: $conf->{name}")
  60         if defined($conf->{name});
  61
  62     $self->{vm_was_running} = 1;
  63     if (!PVE::QemuServer::check_running($vmid)) {
  64         $self->{vm_was_running} = 0;
  65     }
  66
  67     $task->{hostname} = $conf->{name};
  68
  69     my $hostname = PVE::INotify::nodename();
  70
  71     my $vollist = [];
  72     my $drivehash = {};
  73     my $backup_volumes = PVE::QemuConfig->get_backup_volumes($conf);
  74
  75     foreach my $volume (@{$backup_volumes}) {
  76         my $name = $volume->{key};
  77         my $volume_config = $volume->{volume_config};
  78         my $volid = $volume_config->{file};
  79
  80         if (!$volume->{included}) {
  81             $self->loginfo("exclude disk '$name' '$volid' ($volume->{reason})");
  82             next;
  83         } elsif ($self->{vm_was_running} && $volume_config->{iothread}) {
  84             if (!PVE::QemuServer::Machine::runs_at_least_qemu_version($vmid, 4, 0, 1)) {
  85                 die "disk '$name' '$volid' (iothread=on) can't use backup feature with running QEMU " .
  86                     "version < 4.0.1! Either set backup=no for this drive or upgrade QEMU and restart VM\n";
  87             }
  88         } else {
  89             my $log = "include disk '$name' '$volid'";
  90             if (defined(my $size = $volume_config->{size})) {
  91                 my $readable_size = PVE::JSONSchema::format_size($size);
  92                 $log .= " $readable_size";
  93             }
  94             $self->loginfo($log);
  95         }
  96
  97         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
  98         push @$vollist, $volid if $storeid;
  99         $drivehash->{$name} = $volume->{volume_config};
 100     }
 101
 102     PVE::Storage::activate_volumes($self->{storecfg}, $vollist);
 103
 104     foreach my $ds (sort keys %$drivehash) {
 105         my $drive = $drivehash->{$ds};
 106
 107         my $volid = $drive->{file};
 108         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 109
 110         my $path = $volid;
 111         if ($storeid) {
 112             $path = PVE::Storage::path($self->{storecfg}, $volid);
 113         }
 114         next if !$path;
 115
 116         my ($size, $format) = eval { PVE::Storage::volume_size_info($self->{storecfg}, $volid, 5) };
 117         die "no such volume '$volid'\n" if $@;
 118
 119         my $diskinfo = {
 120             path => $path,
 121             volid => $volid,
 122             storeid => $storeid,
 123             format => $format,
 124             virtdev => $ds,
 125             qmdevice => "drive-$ds",
 126         };
 127
 128         if (-b $path) {
 129             $diskinfo->{type} = 'block';
 130         } else {
 131             $diskinfo->{type} = 'file';
 132         }
 133
 134         push @{$task->{disks}}, $diskinfo;
 135     }
 136 }
 137
 138 sub vm_status {
 139     my ($self, $vmid) = @_;
 140
 141     my $running = PVE::QemuServer::check_running($vmid) ? 1 : 0;
 142
 143     return wantarray ? ($running, $running ? 'running' : 'stopped') : $running;
 144 }
 145
 146 sub lock_vm {
 147     my ($self, $vmid) = @_;
 148
 149     PVE::QemuConfig->set_lock($vmid, 'backup');
 150 }
 151
 152 sub unlock_vm {
 153     my ($self, $vmid) = @_;
 154
 155     PVE::QemuConfig->remove_lock($vmid, 'backup');
 156 }
 157
 158 sub stop_vm {
 159     my ($self, $task, $vmid) = @_;
 160
 161     my $opts = $self->{vzdump}->{opts};
 162
 163     my $wait = $opts->{stopwait} * 60;
 164     # send shutdown and wait
 165     $self->cmd ("qm shutdown $vmid --skiplock --keepActive --timeout $wait");
 166 }
 167
 168 sub start_vm {
 169     my ($self, $task, $vmid) = @_;
 170
 171     $self->cmd ("qm start $vmid --skiplock");
 172 }
 173
 174 sub suspend_vm {
 175     my ($self, $task, $vmid) = @_;
 176
 177     $self->cmd ("qm suspend $vmid --skiplock");
 178 }
 179
 180 sub resume_vm {
 181     my ($self, $task, $vmid) = @_;
 182
 183     $self->cmd ("qm resume $vmid --skiplock");
 184 }
 185
 186 sub assemble {
 187     my ($self, $task, $vmid) = @_;
 188
 189     my $conffile = PVE::QemuConfig->config_file($vmid);
 190
 191     my $outfile = "$task->{tmpdir}/qemu-server.conf";
 192     my $firewall_src = "/etc/pve/firewall/$vmid.fw";
 193     my $firewall_dest = "$task->{tmpdir}/qemu-server.fw";
 194
 195     my $outfd = IO::File->new (">$outfile") ||
 196         die "unable to open '$outfile'";
 197     my $conffd = IO::File->new ($conffile, 'r') ||
 198         die "unable open '$conffile'";
 199
 200     my $found_snapshot;
 201     my $found_pending;
 202     while (defined (my $line = <$conffd>)) {
 203         next if $line =~ m/^\#vzdump\#/; # just to be sure
 204         next if $line =~ m/^\#qmdump\#/; # just to be sure
 205         if ($line =~ m/^\[(.*)\]\s*$/) {
 206             if ($1 =~ m/PENDING/i) {
 207                 $found_pending = 1;
 208             } else {
 209                 $found_snapshot = 1;
 210             }
 211         }
 212         next if $found_snapshot || $found_pending; # skip all snapshots and pending changes config data
 213
 214         if ($line =~ m/^unused\d+:\s*(\S+)\s*/) {
 215             $self->loginfo("skip unused drive '$1' (not included into backup)");
 216             next;
 217         }
 218         next if $line =~ m/^lock:/ || $line =~ m/^parent:/;
 219
 220         print $outfd $line;
 221     }
 222
 223     foreach my $di (@{$task->{disks}}) {
 224         if ($di->{type} eq 'block' || $di->{type} eq 'file') {
 225             my $storeid = $di->{storeid} || '';
 226             my $format = $di->{format} || '';
 227             print $outfd "#qmdump#map:$di->{virtdev}:$di->{qmdevice}:$storeid:$format:\n";
 228         } else {
 229             die "internal error";
 230         }
 231     }
 232
 233     if ($found_snapshot) {
 234         $self->loginfo("snapshots found (not included into backup)");
 235     }
 236     if ($found_pending) {
 237         $self->loginfo("pending configuration changes found (not included into backup)");
 238     }
 239
 240     PVE::Tools::file_copy($firewall_src, $firewall_dest) if -f $firewall_src;
 241 }
 242
 243 sub archive {
 244     my ($self, $task, $vmid, $filename, $comp) = @_;
 245
 246     my $opts = $self->{vzdump}->{opts};
 247     my $scfg = $opts->{scfg};
 248
 249     if ($self->{vzdump}->{opts}->{pbs}) {
 250         $self->archive_pbs($task, $vmid);
 251     } else {
 252         $self->archive_vma($task, $vmid, $filename, $comp);
 253     }
 254 }
 255
 256 # number, [precision=1]
 257 my $num2str = sub {
 258     return sprintf( "%." . ( $_[1] || 1 ) . "f", $_[0] );
 259 };
 260 sub bytes_to_human {
 261     my ($bytes, $precission) = @_;
 262
 263     return $num2str->($bytes, $precission) . ' B' if $bytes < 1024;
 264     my $kb = $bytes/1024;
 265
 266     return $num2str->($kb, $precission) . " KiB" if $kb < 1024;
 267     my $mb = $kb/1024;
 268
 269     return $num2str->($mb, $precission) . " MiB" if $mb < 1024;
 270     my $gb = $mb/1024;
 271
 272     return $num2str->($gb, $precission) . " GiB" if $gb < 1024;
 273     my $tb = $gb/1024;
 274
 275     return $num2str->($tb, $precission) . " TiB";
 276 };
 277
 278 my $query_backup_status_loop = sub {
 279     my ($self, $vmid, $job_uuid) = @_;
 280
 281     my $starttime = time ();
 282     my $last_time = $starttime;
 283     my ($last_percent, $last_total, $last_target,  $last_zero, $last_transferred) = (-1, 0, 0, 0, 0);
 284     my ($transferred, $reused);
 285     my $first_round = 1;
 286
 287     my $get_mbps = sub {
 288         my ($mb, $delta) = @_;
 289         return "0 B/s" if $mb <= 0;
 290         my $bw = int(($mb / $delta));
 291         return bytes_to_human($bw) . "/s";
 292     };
 293
 294     while(1) {
 295         my $status = mon_cmd($vmid, 'query-backup');
 296
 297         my $total = $status->{total} || 0;
 298         my $dirty = $status->{dirty};
 299         my $target = (defined($dirty) && $dirty < $total) ? $dirty : $total;
 300         $transferred = $status->{transferred} || 0;
 301         $reused = $status->{reused};
 302         my $percent = $target ? int(($transferred * 100)/$target) : 0;
 303         my $zero = $status->{'zero-bytes'} || 0;
 304
 305         die "got unexpected uuid\n" if !$status->{uuid} || ($status->{uuid} ne $job_uuid);
 306
 307         my $ctime = time();
 308         my $duration = $ctime - $starttime;
 309
 310         my $rbytes = $transferred - $last_transferred;
 311         my $wbytes = $rbytes - ($zero - $last_zero);
 312
 313         my $timediff = ($ctime - $last_time) || 1; # fixme
 314         my $mbps_read = $get_mbps->($rbytes, $timediff);
 315         my $mbps_write = $get_mbps->($wbytes, $timediff);
 316         my $target_h = bytes_to_human($target);
 317         my $transferred_h = bytes_to_human($transferred);
 318
 319         if ($first_round && $target != $total) {
 320             my $total_h = bytes_to_human($total);
 321             $self->loginfo("using fast incremental mode (dirty-bitmap), $target_h dirty of $total_h total");
 322         }
 323
 324         my $statusline = "status: $percent% ($transferred_h of $target_h), duration $duration"
 325             .", read: $mbps_read, write: $mbps_write";
 326
 327         my $res = $status->{status} || 'unknown';
 328         if ($res ne 'active') {
 329             $self->loginfo($statusline);
 330             if ($res ne 'done') {
 331                 die (($status->{errmsg} || "unknown error") . "\n") if $res eq 'error';
 332                 die "got unexpected status '$res'\n";
 333             }
 334             $last_target = $target if $target;
 335             $last_total = $total if $total;
 336             $last_zero = $zero if $zero;
 337             $last_transferred = $transferred if $transferred;
 338             last;
 339         }
 340         if ($percent != $last_percent && ($timediff > 2)) {
 341             $self->loginfo($statusline);
 342             $last_percent = $percent;
 343             $last_target = $target if $target;
 344             $last_total = $total if $total;
 345             $last_zero = $zero if $zero;
 346             $last_transferred = $transferred if $transferred;
 347             $last_time = $ctime;
 348         }
 349         sleep(1);
 350         $first_round = 0;
 351     }
 352
 353     my $duration = time() - $starttime;
 354     if ($transferred && $duration) {
 355         my $transferred_h = bytes_to_human($transferred, 2);
 356         my $mbps = $get_mbps->($transferred, $duration);
 357         if ($reused) {
 358             my $reused_h = bytes_to_human($reused, 2);
 359             my $reuse_per = int($reused * 100 / $last_total);
 360             $self->loginfo("backup was done incrementally, reused $reused_h (${reuse_per}%)");
 361         }
 362         $self->loginfo("transferred $transferred_h in $duration seconds ($mbps)");
 363     }
 364
 365     if ($last_zero) {
 366         my $zero_per = $last_target ? int(($last_zero * 100)/$last_target) : 0;
 367         my $zero_h = bytes_to_human($last_zero, 2);
 368         $self->loginfo("Backup is sparse: ${zero_per}% ($zero_h) zero data");
 369     }
 370
 371     return {
 372         total => $last_total,
 373         reused => $reused,
 374     };
 375 };
 376
 377 sub archive_pbs {
 378     my ($self, $task, $vmid) = @_;
 379
 380     my $conffile = "$task->{tmpdir}/qemu-server.conf";
 381     my $firewall = "$task->{tmpdir}/qemu-server.fw";
 382
 383     my $opts = $self->{vzdump}->{opts};
 384     my $scfg = $opts->{scfg};
 385
 386     my $starttime = time();
 387
 388     my $server = $scfg->{server};
 389     my $datastore = $scfg->{datastore};
 390     my $username = $scfg->{username} // 'root@pam';
 391     my $fingerprint = $scfg->{fingerprint};
 392
 393     my $repo = "$username\@$server:$datastore";
 394     my $password = PVE::Storage::PBSPlugin::pbs_get_password($scfg, $opts->{storage});
 395
 396     my $diskcount = scalar(@{$task->{disks}});
 397     if (PVE::QemuConfig->is_template($self->{vmlist}->{$vmid}) || !$diskcount) {
 398         my @pathlist;
 399         # FIXME: accumulate disk sizes to use for backup job (email) log
 400         foreach my $di (@{$task->{disks}}) {
 401             if ($di->{type} eq 'block' || $di->{type} eq 'file') {
 402                 push @pathlist, "$di->{qmdevice}.img:$di->{path}";
 403             } else {
 404                 die "implement me (type $di->{type})";
 405             }
 406         }
 407
 408         if (!$diskcount) {
 409             $self->loginfo("backup contains no disks");
 410         }
 411
 412         local $ENV{PBS_PASSWORD} = $password;
 413         local $ENV{PBS_FINGERPRINT} = $fingerprint if defined($fingerprint);
 414         my $cmd = [
 415             '/usr/bin/proxmox-backup-client',
 416             'backup',
 417             '--repository', $repo,
 418             '--backup-type', 'vm',
 419             '--backup-id', "$vmid",
 420             '--backup-time', $task->{backup_time},
 421         ];
 422
 423         push @$cmd, "qemu-server.conf:$conffile";
 424         push @$cmd, "fw.conf:$firewall" if -e $firewall;
 425         push @$cmd, @pathlist if scalar(@pathlist);
 426
 427         $self->loginfo("starting template backup");
 428         $self->loginfo(join(' ', @$cmd));
 429
 430         $self->cmd($cmd);
 431
 432         return;
 433     }
 434
 435     # get list early so we die on unkown drive types before doing anything
 436     my $devlist = _get_task_devlist($task);
 437
 438     $self->enforce_vm_running_for_backup($vmid);
 439
 440     my $backup_job_uuid;
 441     eval {
 442         $SIG{INT} = $SIG{TERM} = $SIG{QUIT} = $SIG{HUP} = $SIG{PIPE} = sub {
 443             die "interrupted by signal\n";
 444         };
 445
 446         my $qemu_support = eval { mon_cmd($vmid, "query-proxmox-support") };
 447         if (!$qemu_support) {
 448             die "PBS backups are not supported by the running QEMU version. Please make "
 449               . "sure you've installed the latest version and the VM has been restarted.\n";
 450         }
 451
 452         my $fs_frozen = $self->qga_fs_freeze($task, $vmid);
 453
 454         my $params = {
 455             format => "pbs",
 456             'backup-file' => $repo,
 457             'backup-id' => "$vmid",
 458             'backup-time' => $task->{backup_time},
 459             password => $password,
 460             devlist => $devlist,
 461             'config-file' => $conffile,
 462         };
 463         $params->{fingerprint} = $fingerprint if defined($fingerprint);
 464         $params->{'firewall-file'} = $firewall if -e $firewall;
 465
 466         $params->{'use-dirty-bitmap'} = JSON::true if $qemu_support->{'pbs-dirty-bitmap'};
 467
 468         $params->{timeout} = 60; # give some time to connect to the backup server
 469
 470         my $res = eval { mon_cmd($vmid, "backup", %$params) };
 471         my $qmperr = $@;
 472         $backup_job_uuid = $res->{UUID} if $res;
 473
 474         if ($fs_frozen) {
 475             $self->qga_fs_thaw($vmid);
 476         }
 477
 478         die $qmperr if $qmperr;
 479         die "got no uuid for backup task\n" if !defined($backup_job_uuid);
 480
 481         $self->loginfo("started backup task '$backup_job_uuid'");
 482
 483         $self->resume_vm_after_job_start($task, $vmid);
 484
 485         my $stat = $query_backup_status_loop->($self, $vmid, $backup_job_uuid);
 486         $task->{size} = $stat->{total};
 487     };
 488     my $err = $@;
 489     if ($err) {
 490         $self->logerr($err);
 491         $self->mon_backup_cancel($vmid) if defined($backup_job_uuid);
 492     }
 493     $self->restore_vm_power_state($vmid);
 494
 495     die $err if $err;
 496 }
 497
 498 my $fork_compressor_pipe = sub {
 499     my ($self, $comp, $outfileno) = @_;
 500
 501     my @pipefd = POSIX::pipe();
 502     my $cpid = fork();
 503     die "unable to fork worker - $!" if !defined($cpid) || $cpid < 0;
 504     if ($cpid == 0) {
 505         eval {
 506             POSIX::close($pipefd[1]);
 507             # redirect STDIN
 508             my $fd = fileno(STDIN);
 509             close STDIN;
 510             POSIX::close(0) if $fd != 0;
 511             die "unable to redirect STDIN - $!"
 512                 if !open(STDIN, "<&", $pipefd[0]);
 513
 514             # redirect STDOUT
 515             $fd = fileno(STDOUT);
 516             close STDOUT;
 517             POSIX::close (1) if $fd != 1;
 518
 519             die "unable to redirect STDOUT - $!"
 520                 if !open(STDOUT, ">&", $outfileno);
 521
 522             exec($comp);
 523             die "fork compressor '$comp' failed\n";
 524         };
 525         if (my $err = $@) {
 526             $self->logerr($err);
 527             POSIX::_exit(1);
 528         }
 529         POSIX::_exit(0);
 530         kill(-9, $$);
 531     } else {
 532         POSIX::close($pipefd[0]);
 533         $outfileno = $pipefd[1];
 534     }
 535
 536     return ($cpid, $outfileno);
 537 };
 538
 539 sub archive_vma {
 540     my ($self, $task, $vmid, $filename, $comp) = @_;
 541
 542     my $conffile = "$task->{tmpdir}/qemu-server.conf";
 543     my $firewall = "$task->{tmpdir}/qemu-server.fw";
 544
 545     my $opts = $self->{vzdump}->{opts};
 546
 547     my $starttime = time();
 548
 549     my $speed = 0;
 550     if ($opts->{bwlimit}) {
 551         $speed = $opts->{bwlimit}*1024;
 552     }
 553
 554     my $diskcount = scalar(@{$task->{disks}});
 555     if (PVE::QemuConfig->is_template($self->{vmlist}->{$vmid}) || !$diskcount) {
 556         my @pathlist;
 557         foreach my $di (@{$task->{disks}}) {
 558             if ($di->{type} eq 'block' || $di->{type} eq 'file') {
 559                 push @pathlist, "$di->{qmdevice}=$di->{path}";
 560             } else {
 561                 die "implement me";
 562             }
 563         }
 564
 565         if (!$diskcount) {
 566             $self->loginfo("backup contains no disks");
 567         }
 568
 569         my $outcmd;
 570         if ($comp) {
 571             $outcmd = "exec:$comp";
 572         } else {
 573             $outcmd = "exec:cat";
 574         }
 575
 576         $outcmd .= " > $filename" if !$opts->{stdout};
 577
 578         my $cmd = ['/usr/bin/vma', 'create', '-v', '-c', $conffile];
 579         push @$cmd, '-c', $firewall if -e $firewall;
 580         push @$cmd, $outcmd, @pathlist;
 581
 582         $self->loginfo("starting template backup");
 583         $self->loginfo(join(' ', @$cmd));
 584
 585         if ($opts->{stdout}) {
 586             $self->cmd($cmd, output => ">&" . fileno($opts->{stdout}));
 587         } else {
 588             $self->cmd($cmd);
 589         }
 590
 591         return;
 592     }
 593
 594     my $devlist = _get_task_devlist($task);
 595
 596     $self->enforce_vm_running_for_backup($vmid);
 597
 598     my $cpid;
 599     my $backup_job_uuid;
 600
 601     eval {
 602         $SIG{INT} = $SIG{TERM} = $SIG{QUIT} = $SIG{HUP} = $SIG{PIPE} = sub {
 603             die "interrupted by signal\n";
 604         };
 605
 606         my $outfh;
 607         if ($opts->{stdout}) {
 608             $outfh = $opts->{stdout};
 609         } else {
 610             $outfh = IO::File->new($filename, "w") ||
 611                 die "unable to open file '$filename' - $!\n";
 612         }
 613         my $outfileno = fileno($outfh);
 614
 615         if ($comp) {
 616             ($cpid, $outfileno) = $fork_compressor_pipe->($self, $comp, $outfileno);
 617         }
 618
 619         my $qmpclient = PVE::QMPClient->new();
 620         my $backup_cb = sub {
 621             my ($vmid, $resp) = @_;
 622             $backup_job_uuid = $resp->{return}->{UUID};
 623         };
 624         my $add_fd_cb = sub {
 625             my ($vmid, $resp) = @_;
 626
 627             my $params = {
 628                 'backup-file' => "/dev/fdname/backup",
 629                 speed => $speed,
 630                 'config-file' => $conffile,
 631                 devlist => $devlist
 632             };
 633             $params->{'firewall-file'} = $firewall if -e $firewall;
 634
 635             $qmpclient->queue_cmd($vmid, $backup_cb, 'backup', %$params);
 636         };
 637
 638         $qmpclient->queue_cmd($vmid, $add_fd_cb, 'getfd', fd => $outfileno, fdname => "backup");
 639
 640         my $fs_frozen = $self->qga_fs_freeze($task, $vmid);
 641
 642         eval { $qmpclient->queue_execute(30) };
 643         my $qmperr = $@;
 644
 645         if ($fs_frozen) {
 646             $self->qga_fs_thaw($vmid);
 647         }
 648
 649         die $qmperr if $qmperr;
 650         die $qmpclient->{errors}->{$vmid} if $qmpclient->{errors}->{$vmid};
 651
 652         if ($cpid) {
 653             POSIX::close($outfileno) == 0 ||
 654                 die "close output file handle failed\n";
 655         }
 656
 657         die "got no uuid for backup task\n" if !defined($backup_job_uuid);
 658
 659         $self->loginfo("started backup task '$backup_job_uuid'");
 660
 661         $self->resume_vm_after_job_start($task, $vmid);
 662
 663         $query_backup_status_loop->($self, $vmid, $backup_job_uuid);
 664     };
 665     my $err = $@;
 666     if ($err) {
 667         $self->logerr($err);
 668         $self->mon_backup_cancel($vmid) if defined($backup_job_uuid);
 669     }
 670
 671     $self->restore_vm_power_state($vmid);
 672
 673     if ($err) {
 674         if ($cpid) {
 675             kill(9, $cpid);
 676             waitpid($cpid, 0);
 677         }
 678         die $err;
 679     }
 680
 681     if ($cpid && (waitpid($cpid, 0) > 0)) {
 682         my $stat = $?;
 683         my $ec = $stat >> 8;
 684         my $signal = $stat & 127;
 685         if ($ec || $signal) {
 686             die "$comp failed - wrong exit status $ec" .
 687                 ($signal ? " (signal $signal)\n" : "\n");
 688         }
 689     }
 690 }
 691
 692 sub _get_task_devlist {
 693     my ($task) = @_;
 694
 695     my $devlist = '';
 696     foreach my $di (@{$task->{disks}}) {
 697         if ($di->{type} eq 'block' || $di->{type} eq 'file') {
 698             $devlist .= ',' if $devlist;
 699             $devlist .= $di->{qmdevice};
 700         } else {
 701             die "implement me (type '$di->{type}')";
 702         }
 703     }
 704     return $devlist;
 705 }
 706
 707 sub qga_fs_freeze {
 708     my ($self, $task, $vmid) = @_;
 709     return if !$self->{vmlist}->{$vmid}->{agent} || $task->{mode} eq 'stop' || !$self->{vm_was_running};
 710
 711     if (!PVE::QemuServer::qga_check_running($vmid, 1)) {
 712         $self->loginfo("skipping guest-agent 'fs-freeze', agent configured but not running?");
 713         return;
 714     }
 715
 716     $self->loginfo("issuing guest-agent 'fs-freeze' command");
 717     eval { mon_cmd($vmid, "guest-fsfreeze-freeze") };
 718     $self->logerr($@) if $@;
 719
 720     return 1; # even on mon command error, ensure we always thaw again
 721 }
 722
 723 # only call if fs_freeze return 1
 724 sub qga_fs_thaw {
 725     my ($self, $vmid) = @_;
 726
 727     $self->loginfo("issuing guest-agent 'fs-thaw' command");
 728     eval { mon_cmd($vmid, "guest-fsfreeze-thaw") };
 729     $self->logerr($@) if $@;
 730 }
 731
 732 # we need a running QEMU/KVM process for backup, starts a paused (prelaunch)
 733 # one if VM isn't already running
 734 sub enforce_vm_running_for_backup {
 735     my ($self, $vmid) = @_;
 736
 737     if (PVE::QemuServer::check_running($vmid)) {
 738         $self->{vm_was_running} = 1;
 739         return;
 740     }
 741
 742     eval {
 743         $self->loginfo("starting kvm to execute backup task");
 744         # start with skiplock
 745         my $params = {
 746             skiplock => 1,
 747             paused => 1,
 748         };
 749         PVE::QemuServer::vm_start($self->{storecfg}, $vmid, $params);
 750     };
 751     die $@ if $@;
 752 }
 753
 754 # resume VM againe once we got in a clear state (stop mode backup of running VM)
 755 sub resume_vm_after_job_start {
 756     my ($self, $task, $vmid) = @_;
 757
 758     return if !$self->{vm_was_running};
 759
 760     if (my $stoptime = $task->{vmstoptime}) {
 761         my $delay = time() - $task->{vmstoptime};
 762         $task->{vmstoptime} = undef; # avoid printing 'online after ..' twice
 763         $self->loginfo("resuming VM again after $delay seconds");
 764     } else {
 765         $self->loginfo("resuming VM again");
 766     }
 767     mon_cmd($vmid, 'cont');
 768 }
 769
 770 # stop again if VM was not running before
 771 sub restore_vm_power_state {
 772     my ($self, $vmid) = @_;
 773
 774     # we always let VMs keep running
 775     return if $self->{vm_was_running};
 776
 777     eval {
 778         my $resp = mon_cmd($vmid, 'query-status');
 779         my $status = $resp && $resp->{status} ?  $resp->{status} : 'unknown';
 780         if ($status eq 'prelaunch') {
 781             $self->loginfo("stopping kvm after backup task");
 782             PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1);
 783         } else {
 784             $self->loginfo("kvm status changed after backup ('$status') - keep VM running");
 785         }
 786     };
 787     warn $@ if $@;
 788 }
 789
 790 sub mon_backup_cancel {
 791     my ($self, $vmid) = @_;
 792
 793     $self->loginfo("aborting backup job");
 794     eval { mon_cmd($vmid, 'backup-cancel') };
 795     $self->logerr($@) if $@;
 796 }
 797
 798 sub snapshot {
 799     my ($self, $task, $vmid) = @_;
 800
 801     # nothing to do
 802 }
 803
 804 sub cleanup {
 805     my ($self, $task, $vmid) = @_;
 806
 807     # nothing to do ?
 808 }
 809
 810 1;