PVE/VZDump/QemuServer.pm

   1 package PVE::VZDump::QemuServer;
   2
   3 use strict;
   4 use warnings;
   5
   6 use File::Basename;
   7 use File::Path;
   8 use IO::File;
   9 use IPC::Open3;
  10 use JSON;
  11
  12 use PVE::Cluster qw(cfs_read_file);
  13 use PVE::INotify;
  14 use PVE::IPCC;
  15 use PVE::JSONSchema;
  16 use PVE::QMPClient;
  17 use PVE::Storage::Plugin;
  18 use PVE::Storage::PBSPlugin;
  19 use PVE::Storage;
  20 use PVE::Tools;
  21 use PVE::VZDump;
  22
  23 use PVE::QemuConfig;
  24 use PVE::QemuServer;
  25 use PVE::QemuServer::Machine;
  26 use PVE::QemuServer::Monitor qw(mon_cmd);
  27
  28 use base qw (PVE::VZDump::Plugin);
  29
  30 sub new {
  31     my ($class, $vzdump) = @_;
  32
  33     PVE::VZDump::check_bin('qm');
  34
  35     my $self = bless { vzdump => $vzdump }, $class;
  36
  37     $self->{vmlist} = PVE::QemuServer::vzlist();
  38     $self->{storecfg} = PVE::Storage::config();
  39
  40     return $self;
  41 };
  42
  43 sub type {
  44     return 'qemu';
  45 }
  46
  47 sub vmlist {
  48     my ($self) = @_;
  49     return [ keys %{$self->{vmlist}} ];
  50 }
  51
  52 sub prepare {
  53     my ($self, $task, $vmid, $mode) = @_;
  54
  55     $task->{disks} = [];
  56
  57     my $conf = $self->{vmlist}->{$vmid} = PVE::QemuConfig->load_config($vmid);
  58
  59     $self->loginfo("VM Name: $conf->{name}")
  60         if defined($conf->{name});
  61
  62     $self->{vm_was_running} = 1;
  63     if (!PVE::QemuServer::check_running($vmid)) {
  64         $self->{vm_was_running} = 0;
  65     }
  66
  67     $task->{hostname} = $conf->{name};
  68
  69     my $hostname = PVE::INotify::nodename();
  70
  71     my $vollist = [];
  72     my $drivehash = {};
  73     my $backup_volumes = PVE::QemuConfig->get_backup_volumes($conf);
  74
  75     foreach my $volume (@{$backup_volumes}) {
  76         my $name = $volume->{key};
  77         my $volume_config = $volume->{volume_config};
  78         my $volid = $volume_config->{file};
  79
  80         if (!$volume->{included}) {
  81             $self->loginfo("exclude disk '$name' '$volid' ($volume->{reason})");
  82             next;
  83         } elsif ($self->{vm_was_running} && $volume_config->{iothread}) {
  84             if (!PVE::QemuServer::Machine::runs_at_least_qemu_version($vmid, 4, 0, 1)) {
  85                 die "disk '$name' '$volid' (iothread=on) can't use backup feature with running QEMU " .
  86                     "version < 4.0.1! Either set backup=no for this drive or upgrade QEMU and restart VM\n";
  87             }
  88         } else {
  89             my $log = "include disk '$name' '$volid'";
  90             if (defined(my $size = $volume_config->{size})) {
  91                 my $readable_size = PVE::JSONSchema::format_size($size);
  92                 $log .= " $readable_size";
  93             }
  94             $self->loginfo($log);
  95         }
  96
  97         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
  98         push @$vollist, $volid if $storeid;
  99         $drivehash->{$name} = $volume->{volume_config};
 100     }
 101
 102     PVE::Storage::activate_volumes($self->{storecfg}, $vollist);
 103
 104     foreach my $ds (sort keys %$drivehash) {
 105         my $drive = $drivehash->{$ds};
 106
 107         my $volid = $drive->{file};
 108         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 109
 110         my $path = $volid;
 111         if ($storeid) {
 112             $path = PVE::Storage::path($self->{storecfg}, $volid);
 113         }
 114         next if !$path;
 115
 116         my ($size, $format) = eval { PVE::Storage::volume_size_info($self->{storecfg}, $volid, 5) };
 117         die "no such volume '$volid'\n" if $@;
 118
 119         my $diskinfo = {
 120             path => $path,
 121             volid => $volid,
 122             storeid => $storeid,
 123             format => $format,
 124             virtdev => $ds,
 125             qmdevice => "drive-$ds",
 126         };
 127
 128         if (-b $path) {
 129             $diskinfo->{type} = 'block';
 130         } else {
 131             $diskinfo->{type} = 'file';
 132         }
 133
 134         push @{$task->{disks}}, $diskinfo;
 135     }
 136 }
 137
 138 sub vm_status {
 139     my ($self, $vmid) = @_;
 140
 141     my $running = PVE::QemuServer::check_running($vmid) ? 1 : 0;
 142
 143     return wantarray ? ($running, $running ? 'running' : 'stopped') : $running;
 144 }
 145
 146 sub lock_vm {
 147     my ($self, $vmid) = @_;
 148
 149     PVE::QemuConfig->set_lock($vmid, 'backup');
 150 }
 151
 152 sub unlock_vm {
 153     my ($self, $vmid) = @_;
 154
 155     PVE::QemuConfig->remove_lock($vmid, 'backup');
 156 }
 157
 158 sub stop_vm {
 159     my ($self, $task, $vmid) = @_;
 160
 161     my $opts = $self->{vzdump}->{opts};
 162
 163     my $wait = $opts->{stopwait} * 60;
 164     # send shutdown and wait
 165     $self->cmd ("qm shutdown $vmid --skiplock --keepActive --timeout $wait");
 166 }
 167
 168 sub start_vm {
 169     my ($self, $task, $vmid) = @_;
 170
 171     $self->cmd ("qm start $vmid --skiplock");
 172 }
 173
 174 sub suspend_vm {
 175     my ($self, $task, $vmid) = @_;
 176
 177     $self->cmd ("qm suspend $vmid --skiplock");
 178 }
 179
 180 sub resume_vm {
 181     my ($self, $task, $vmid) = @_;
 182
 183     $self->cmd ("qm resume $vmid --skiplock");
 184 }
 185
 186 sub assemble {
 187     my ($self, $task, $vmid) = @_;
 188
 189     my $conffile = PVE::QemuConfig->config_file($vmid);
 190
 191     my $outfile = "$task->{tmpdir}/qemu-server.conf";
 192     my $firewall_src = "/etc/pve/firewall/$vmid.fw";
 193     my $firewall_dest = "$task->{tmpdir}/qemu-server.fw";
 194
 195     my $outfd = IO::File->new (">$outfile") ||
 196         die "unable to open '$outfile'";
 197     my $conffd = IO::File->new ($conffile, 'r') ||
 198         die "unable open '$conffile'";
 199
 200     my $found_snapshot;
 201     my $found_pending;
 202     while (defined (my $line = <$conffd>)) {
 203         next if $line =~ m/^\#vzdump\#/; # just to be sure
 204         next if $line =~ m/^\#qmdump\#/; # just to be sure
 205         if ($line =~ m/^\[(.*)\]\s*$/) {
 206             if ($1 =~ m/PENDING/i) {
 207                 $found_pending = 1;
 208             } else {
 209                 $found_snapshot = 1;
 210             }
 211         }
 212         next if $found_snapshot || $found_pending; # skip all snapshots and pending changes config data
 213
 214         if ($line =~ m/^unused\d+:\s*(\S+)\s*/) {
 215             $self->loginfo("skip unused drive '$1' (not included into backup)");
 216             next;
 217         }
 218         next if $line =~ m/^lock:/ || $line =~ m/^parent:/;
 219
 220         print $outfd $line;
 221     }
 222
 223     foreach my $di (@{$task->{disks}}) {
 224         if ($di->{type} eq 'block' || $di->{type} eq 'file') {
 225             my $storeid = $di->{storeid} || '';
 226             my $format = $di->{format} || '';
 227             print $outfd "#qmdump#map:$di->{virtdev}:$di->{qmdevice}:$storeid:$format:\n";
 228         } else {
 229             die "internal error";
 230         }
 231     }
 232
 233     if ($found_snapshot) {
 234         $self->loginfo("snapshots found (not included into backup)");
 235     }
 236     if ($found_pending) {
 237         $self->loginfo("pending configuration changes found (not included into backup)");
 238     }
 239
 240     PVE::Tools::file_copy($firewall_src, $firewall_dest) if -f $firewall_src;
 241 }
 242
 243 sub archive {
 244     my ($self, $task, $vmid, $filename, $comp) = @_;
 245
 246     my $opts = $self->{vzdump}->{opts};
 247     my $scfg = $opts->{scfg};
 248
 249     if ($self->{vzdump}->{opts}->{pbs}) {
 250         $self->archive_pbs($task, $vmid);
 251     } else {
 252         $self->archive_vma($task, $vmid, $filename, $comp);
 253     }
 254 }
 255
 256 # number, [precision=1]
 257 my $num2str = sub {
 258     return sprintf( "%." . ( $_[1] || 1 ) . "f", $_[0] );
 259 };
 260 my sub bytes_to_human {
 261     my ($bytes, $precission) = @_;
 262
 263     return $num2str->($bytes, $precission) . ' B' if $bytes < 1024;
 264     my $kb = $bytes/1024;
 265
 266     return $num2str->($kb, $precission) . " KiB" if $kb < 1024;
 267     my $mb = $kb/1024;
 268
 269     return $num2str->($mb, $precission) . " MiB" if $mb < 1024;
 270     my $gb = $mb/1024;
 271
 272     return $num2str->($gb, $precission) . " GiB" if $gb < 1024;
 273     my $tb = $gb/1024;
 274
 275     return $num2str->($tb, $precission) . " TiB";
 276 }
 277 my sub duration_to_human {
 278     my ($seconds) = @_;
 279
 280     return sprintf('%2ds', $seconds) if $seconds < 60;
 281     my $minutes = $seconds / 60;
 282     $seconds = $seconds % 60;
 283
 284     return sprintf('%2dm %2ds', $minutes, $seconds) if $minutes < 60;
 285     my $hours = $minutes / 60;
 286     $minutes = $minutes % 60;
 287
 288     return sprintf('%2dh %2dm %2ds', $hours, $minutes, $seconds) if $hours < 24;
 289     my $days = $hours / 24;
 290     $hours = $hours % 24;
 291
 292     return sprintf('%2dd %2dh %2dm', $days, $hours, $minutes);
 293 }
 294
 295 my $bitmap_action_to_human = sub {
 296     my ($self, $info) = @_;
 297
 298     my $action = $info->{action};
 299
 300     if ($action eq "not-used") {
 301         return "disabled (no support)" if $self->{vm_was_running};
 302         return "disabled (VM not running)";
 303     } elsif ($action eq "not-used-removed") {
 304         return "disabled (old bitmap cleared)";
 305     } elsif ($action eq "new") {
 306         return "created new";
 307     } elsif ($action eq "used") {
 308         if ($info->{dirty} == 0) {
 309             return "OK (drive clean)";
 310         } else {
 311             my $size = bytes_to_human($info->{size});
 312             my $dirty = bytes_to_human($info->{dirty});
 313             return "OK ($dirty of $size dirty)";
 314         }
 315     } elsif ($action eq "invalid") {
 316         return "existing bitmap was invalid and has been cleared";
 317     } else {
 318         return "unknown";
 319     }
 320 };
 321
 322 my $query_backup_status_loop = sub {
 323     my ($self, $vmid, $job_uuid, $qemu_support) = @_;
 324
 325     my $starttime = time ();
 326     my $last_time = $starttime;
 327     my ($last_percent, $last_total, $last_target, $last_zero, $last_transferred) = (-1, 0, 0, 0, 0);
 328     my ($transferred, $reused);
 329
 330     my $get_mbps = sub {
 331         my ($mb, $delta) = @_;
 332         return "0 B/s" if $mb <= 0;
 333         my $bw = int(($mb / $delta));
 334         return bytes_to_human($bw) . "/s";
 335     };
 336
 337     my $target = 0;
 338     my $last_reused = 0;
 339     my $has_query_bitmap = $qemu_support && $qemu_support->{'query-bitmap-info'};
 340     if ($has_query_bitmap) {
 341         my $total = 0;
 342         my $bitmap_info = mon_cmd($vmid, 'query-pbs-bitmap-info');
 343         foreach my $info (sort { $a->{drive} cmp $b->{drive} } @$bitmap_info) {
 344             my $text = $bitmap_action_to_human->($self, $info);
 345             my $drive = $info->{drive};
 346             $drive =~ s/^drive-//; # for consistency
 347             $self->loginfo("$drive: dirty-bitmap status: $text");
 348             $target += $info->{dirty};
 349             $total += $info->{size};
 350             $last_reused += $info->{size} - $info->{dirty};
 351         }
 352         if ($target < $total) {
 353             my $total_h = bytes_to_human($total);
 354             my $target_h = bytes_to_human($target);
 355             $self->loginfo("using fast incremental mode (dirty-bitmap), $target_h dirty of $total_h total");
 356         }
 357     }
 358
 359     my $first_round = 1;
 360     while(1) {
 361         my $status = mon_cmd($vmid, 'query-backup');
 362
 363         my $total = $status->{total} || 0;
 364         my $dirty = $status->{dirty};
 365         $target = (defined($dirty) && $dirty < $total) ? $dirty : $total if !$has_query_bitmap;
 366         $transferred = $status->{transferred} || 0;
 367         $reused = $status->{reused};
 368         my $percent = $target ? int(($transferred * 100)/$target) : 100;
 369         my $zero = $status->{'zero-bytes'} || 0;
 370
 371         die "got unexpected uuid\n" if !$status->{uuid} || ($status->{uuid} ne $job_uuid);
 372
 373         my $ctime = time();
 374         my $duration = $ctime - $starttime;
 375
 376         my $rbytes = $transferred - $last_transferred;
 377         my $wbytes;
 378         if ($reused) {
 379             # reused includes zero bytes for PBS
 380             $wbytes = $rbytes - ($reused - $last_reused);
 381         } else {
 382             $wbytes = $rbytes - ($zero - $last_zero);
 383         }
 384
 385         my $timediff = ($ctime - $last_time) || 1; # fixme
 386         my $mbps_read = $get_mbps->($rbytes, $timediff);
 387         my $mbps_write = $get_mbps->($wbytes, $timediff);
 388         my $target_h = bytes_to_human($target);
 389         my $transferred_h = bytes_to_human($transferred);
 390
 391         if (!$has_query_bitmap && $first_round && $target != $total) { # FIXME: remove with PVE 7.0
 392             my $total_h = bytes_to_human($total);
 393             $self->loginfo("using fast incremental mode (dirty-bitmap), $target_h dirty of $total_h total");
 394         }
 395
 396         my $statusline = sprintf("%3d%% ($transferred_h of $target_h) in %s"
 397             .", read: $mbps_read, write: $mbps_write", $percent, duration_to_human($duration));
 398
 399         my $res = $status->{status} || 'unknown';
 400         if ($res ne 'active') {
 401             $self->loginfo($statusline);
 402             if ($res ne 'done') {
 403                 die (($status->{errmsg} || "unknown error") . "\n") if $res eq 'error';
 404                 die "got unexpected status '$res'\n";
 405             }
 406             $last_target = $target if $target;
 407             $last_total = $total if $total;
 408             $last_zero = $zero if $zero;
 409             $last_transferred = $transferred if $transferred;
 410             last;
 411         }
 412         if ($percent != $last_percent && ($timediff > 2)) {
 413             $self->loginfo($statusline);
 414             $last_percent = $percent;
 415             $last_target = $target if $target;
 416             $last_total = $total if $total;
 417             $last_zero = $zero if $zero;
 418             $last_transferred = $transferred if $transferred;
 419             $last_time = $ctime;
 420             $last_reused = $reused;
 421         }
 422         sleep(1);
 423         $first_round = 0 if $first_round;
 424     }
 425
 426     my $duration = time() - $starttime;
 427
 428     if ($last_zero) {
 429         my $zero_per = $last_target ? int(($last_zero * 100)/$last_target) : 0;
 430         my $zero_h = bytes_to_human($last_zero, 2);
 431         $self->loginfo("backup is sparse: $zero_h (${zero_per}%) total zero data");
 432     }
 433     if ($reused) {
 434         my $reused_h = bytes_to_human($reused, 2);
 435         my $reuse_per = int($reused * 100 / $last_total);
 436         $self->loginfo("backup was done incrementally, reused $reused_h (${reuse_per}%)");
 437     }
 438     if ($transferred) {
 439         my $transferred_h = bytes_to_human($transferred, 2);
 440         if ($duration) {
 441             my $mbps = $get_mbps->($transferred, $duration);
 442             $self->loginfo("transferred $transferred_h in $duration seconds ($mbps)");
 443         } else {
 444             $self->loginfo("transferred $transferred_h in <1 seconds");
 445         }
 446     }
 447
 448     return {
 449         total => $last_total,
 450         reused => $reused,
 451     };
 452 };
 453
 454 sub archive_pbs {
 455     my ($self, $task, $vmid) = @_;
 456
 457     my $conffile = "$task->{tmpdir}/qemu-server.conf";
 458     my $firewall = "$task->{tmpdir}/qemu-server.fw";
 459
 460     my $opts = $self->{vzdump}->{opts};
 461     my $scfg = $opts->{scfg};
 462
 463     my $starttime = time();
 464
 465     my $server = $scfg->{server};
 466     my $datastore = $scfg->{datastore};
 467     my $username = $scfg->{username} // 'root@pam';
 468     my $fingerprint = $scfg->{fingerprint};
 469
 470     my $repo = "$username\@$server:$datastore";
 471     my $password = PVE::Storage::PBSPlugin::pbs_get_password($scfg, $opts->{storage});
 472     my $keyfile = PVE::Storage::PBSPlugin::pbs_encryption_key_file_name($scfg, $opts->{storage});
 473
 474     my $diskcount = scalar(@{$task->{disks}});
 475     # proxmox-backup-client can only handle raw files and block devs
 476     # only use it (directly) for disk-less VMs
 477     if (!$diskcount) {
 478         my @pathlist;
 479         $self->loginfo("backup contains no disks");
 480
 481         local $ENV{PBS_PASSWORD} = $password;
 482         local $ENV{PBS_FINGERPRINT} = $fingerprint if defined($fingerprint);
 483         my $cmd = [
 484             '/usr/bin/proxmox-backup-client',
 485             'backup',
 486             '--repository', $repo,
 487             '--backup-type', 'vm',
 488             '--backup-id', "$vmid",
 489             '--backup-time', $task->{backup_time},
 490         ];
 491
 492         push @$cmd, "qemu-server.conf:$conffile";
 493         push @$cmd, "fw.conf:$firewall" if -e $firewall;
 494
 495         $self->loginfo("starting template backup");
 496         $self->loginfo(join(' ', @$cmd));
 497
 498         $self->cmd($cmd);
 499
 500         return;
 501     }
 502
 503     # get list early so we die on unkown drive types before doing anything
 504     my $devlist = _get_task_devlist($task);
 505
 506     $self->enforce_vm_running_for_backup($vmid);
 507
 508     my $backup_job_uuid;
 509     eval {
 510         $SIG{INT} = $SIG{TERM} = $SIG{QUIT} = $SIG{HUP} = $SIG{PIPE} = sub {
 511             die "interrupted by signal\n";
 512         };
 513
 514         my $qemu_support = eval { mon_cmd($vmid, "query-proxmox-support") };
 515         if (!$qemu_support) {
 516             die "PBS backups are not supported by the running QEMU version. Please make "
 517               . "sure you've installed the latest version and the VM has been restarted.\n";
 518         }
 519
 520         my $fs_frozen = $self->qga_fs_freeze($task, $vmid);
 521
 522         my $params = {
 523             format => "pbs",
 524             'backup-file' => $repo,
 525             'backup-id' => "$vmid",
 526             'backup-time' => $task->{backup_time},
 527             password => $password,
 528             devlist => $devlist,
 529             'config-file' => $conffile,
 530         };
 531         $params->{speed} = $opts->{bwlimit}*1024 if $opts->{bwlimit};
 532         $params->{fingerprint} = $fingerprint if defined($fingerprint);
 533         $params->{'firewall-file'} = $firewall if -e $firewall;
 534         if (-e $keyfile) {
 535             $self->loginfo("enabling encryption");
 536             $params->{keyfile} = $keyfile;
 537             $params->{encrypt} = JSON::true;
 538         } else {
 539             $params->{encrypt} = JSON::false;
 540         }
 541
 542         my $is_template = PVE::QemuConfig->is_template($self->{vmlist}->{$vmid});
 543         $params->{'use-dirty-bitmap'} = JSON::true
 544             if $qemu_support->{'pbs-dirty-bitmap'} && $self->{vm_was_running} && !$is_template;
 545
 546         $params->{timeout} = 60; # give some time to connect to the backup server
 547
 548         my $res = eval { mon_cmd($vmid, "backup", %$params) };
 549         my $qmperr = $@;
 550         $backup_job_uuid = $res->{UUID} if $res;
 551
 552         if ($fs_frozen) {
 553             $self->qga_fs_thaw($vmid);
 554         }
 555
 556         die $qmperr if $qmperr;
 557         die "got no uuid for backup task\n" if !defined($backup_job_uuid);
 558
 559         $self->loginfo("started backup task '$backup_job_uuid'");
 560
 561         $self->resume_vm_after_job_start($task, $vmid);
 562
 563         my $stat = $query_backup_status_loop->($self, $vmid, $backup_job_uuid, $qemu_support);
 564         $task->{size} = $stat->{total};
 565     };
 566     my $err = $@;
 567     if ($err) {
 568         $self->logerr($err);
 569         $self->mon_backup_cancel($vmid) if defined($backup_job_uuid);
 570     }
 571     $self->restore_vm_power_state($vmid);
 572
 573     die $err if $err;
 574 }
 575
 576 my $fork_compressor_pipe = sub {
 577     my ($self, $comp, $outfileno) = @_;
 578
 579     my @pipefd = POSIX::pipe();
 580     my $cpid = fork();
 581     die "unable to fork worker - $!" if !defined($cpid) || $cpid < 0;
 582     if ($cpid == 0) {
 583         eval {
 584             POSIX::close($pipefd[1]);
 585             # redirect STDIN
 586             my $fd = fileno(STDIN);
 587             close STDIN;
 588             POSIX::close(0) if $fd != 0;
 589             die "unable to redirect STDIN - $!"
 590                 if !open(STDIN, "<&", $pipefd[0]);
 591
 592             # redirect STDOUT
 593             $fd = fileno(STDOUT);
 594             close STDOUT;
 595             POSIX::close (1) if $fd != 1;
 596
 597             die "unable to redirect STDOUT - $!"
 598                 if !open(STDOUT, ">&", $outfileno);
 599
 600             exec($comp);
 601             die "fork compressor '$comp' failed\n";
 602         };
 603         if (my $err = $@) {
 604             $self->logerr($err);
 605             POSIX::_exit(1);
 606         }
 607         POSIX::_exit(0);
 608         kill(-9, $$);
 609     } else {
 610         POSIX::close($pipefd[0]);
 611         $outfileno = $pipefd[1];
 612     }
 613
 614     return ($cpid, $outfileno);
 615 };
 616
 617 sub archive_vma {
 618     my ($self, $task, $vmid, $filename, $comp) = @_;
 619
 620     my $conffile = "$task->{tmpdir}/qemu-server.conf";
 621     my $firewall = "$task->{tmpdir}/qemu-server.fw";
 622
 623     my $opts = $self->{vzdump}->{opts};
 624
 625     my $starttime = time();
 626
 627     my $speed = 0;
 628     if ($opts->{bwlimit}) {
 629         $speed = $opts->{bwlimit}*1024;
 630     }
 631
 632     my $diskcount = scalar(@{$task->{disks}});
 633     if (PVE::QemuConfig->is_template($self->{vmlist}->{$vmid}) || !$diskcount) {
 634         my @pathlist;
 635         foreach my $di (@{$task->{disks}}) {
 636             if ($di->{type} eq 'block' || $di->{type} eq 'file') {
 637                 push @pathlist, "$di->{qmdevice}=$di->{path}";
 638             } else {
 639                 die "implement me";
 640             }
 641         }
 642
 643         if (!$diskcount) {
 644             $self->loginfo("backup contains no disks");
 645         }
 646
 647         my $outcmd;
 648         if ($comp) {
 649             $outcmd = "exec:$comp";
 650         } else {
 651             $outcmd = "exec:cat";
 652         }
 653
 654         $outcmd .= " > $filename" if !$opts->{stdout};
 655
 656         my $cmd = ['/usr/bin/vma', 'create', '-v', '-c', $conffile];
 657         push @$cmd, '-c', $firewall if -e $firewall;
 658         push @$cmd, $outcmd, @pathlist;
 659
 660         $self->loginfo("starting template backup");
 661         $self->loginfo(join(' ', @$cmd));
 662
 663         if ($opts->{stdout}) {
 664             $self->cmd($cmd, output => ">&" . fileno($opts->{stdout}));
 665         } else {
 666             $self->cmd($cmd);
 667         }
 668
 669         return;
 670     }
 671
 672     my $devlist = _get_task_devlist($task);
 673
 674     $self->enforce_vm_running_for_backup($vmid);
 675
 676     my $cpid;
 677     my $backup_job_uuid;
 678
 679     eval {
 680         $SIG{INT} = $SIG{TERM} = $SIG{QUIT} = $SIG{HUP} = $SIG{PIPE} = sub {
 681             die "interrupted by signal\n";
 682         };
 683
 684         my $outfh;
 685         if ($opts->{stdout}) {
 686             $outfh = $opts->{stdout};
 687         } else {
 688             $outfh = IO::File->new($filename, "w") ||
 689                 die "unable to open file '$filename' - $!\n";
 690         }
 691         my $outfileno = fileno($outfh);
 692
 693         if ($comp) {
 694             ($cpid, $outfileno) = $fork_compressor_pipe->($self, $comp, $outfileno);
 695         }
 696
 697         my $qmpclient = PVE::QMPClient->new();
 698         my $backup_cb = sub {
 699             my ($vmid, $resp) = @_;
 700             $backup_job_uuid = $resp->{return}->{UUID};
 701         };
 702         my $add_fd_cb = sub {
 703             my ($vmid, $resp) = @_;
 704
 705             my $params = {
 706                 'backup-file' => "/dev/fdname/backup",
 707                 speed => $speed,
 708                 'config-file' => $conffile,
 709                 devlist => $devlist
 710             };
 711             $params->{'firewall-file'} = $firewall if -e $firewall;
 712
 713             $qmpclient->queue_cmd($vmid, $backup_cb, 'backup', %$params);
 714         };
 715
 716         $qmpclient->queue_cmd($vmid, $add_fd_cb, 'getfd', fd => $outfileno, fdname => "backup");
 717
 718         my $fs_frozen = $self->qga_fs_freeze($task, $vmid);
 719
 720         eval { $qmpclient->queue_execute(30) };
 721         my $qmperr = $@;
 722
 723         if ($fs_frozen) {
 724             $self->qga_fs_thaw($vmid);
 725         }
 726
 727         die $qmperr if $qmperr;
 728         die $qmpclient->{errors}->{$vmid} if $qmpclient->{errors}->{$vmid};
 729
 730         if ($cpid) {
 731             POSIX::close($outfileno) == 0 ||
 732                 die "close output file handle failed\n";
 733         }
 734
 735         die "got no uuid for backup task\n" if !defined($backup_job_uuid);
 736
 737         $self->loginfo("started backup task '$backup_job_uuid'");
 738
 739         $self->resume_vm_after_job_start($task, $vmid);
 740
 741         $query_backup_status_loop->($self, $vmid, $backup_job_uuid);
 742     };
 743     my $err = $@;
 744     if ($err) {
 745         $self->logerr($err);
 746         $self->mon_backup_cancel($vmid) if defined($backup_job_uuid);
 747     }
 748
 749     $self->restore_vm_power_state($vmid);
 750
 751     if ($err) {
 752         if ($cpid) {
 753             kill(9, $cpid);
 754             waitpid($cpid, 0);
 755         }
 756         die $err;
 757     }
 758
 759     if ($cpid && (waitpid($cpid, 0) > 0)) {
 760         my $stat = $?;
 761         my $ec = $stat >> 8;
 762         my $signal = $stat & 127;
 763         if ($ec || $signal) {
 764             die "$comp failed - wrong exit status $ec" .
 765                 ($signal ? " (signal $signal)\n" : "\n");
 766         }
 767     }
 768 }
 769
 770 sub _get_task_devlist {
 771     my ($task) = @_;
 772
 773     my $devlist = '';
 774     foreach my $di (@{$task->{disks}}) {
 775         if ($di->{type} eq 'block' || $di->{type} eq 'file') {
 776             $devlist .= ',' if $devlist;
 777             $devlist .= $di->{qmdevice};
 778         } else {
 779             die "implement me (type '$di->{type}')";
 780         }
 781     }
 782     return $devlist;
 783 }
 784
 785 sub qga_fs_freeze {
 786     my ($self, $task, $vmid) = @_;
 787     return if !$self->{vmlist}->{$vmid}->{agent} || $task->{mode} eq 'stop' || !$self->{vm_was_running};
 788
 789     if (!PVE::QemuServer::qga_check_running($vmid, 1)) {
 790         $self->loginfo("skipping guest-agent 'fs-freeze', agent configured but not running?");
 791         return;
 792     }
 793
 794     $self->loginfo("issuing guest-agent 'fs-freeze' command");
 795     eval { mon_cmd($vmid, "guest-fsfreeze-freeze") };
 796     $self->logerr($@) if $@;
 797
 798     return 1; # even on mon command error, ensure we always thaw again
 799 }
 800
 801 # only call if fs_freeze return 1
 802 sub qga_fs_thaw {
 803     my ($self, $vmid) = @_;
 804
 805     $self->loginfo("issuing guest-agent 'fs-thaw' command");
 806     eval { mon_cmd($vmid, "guest-fsfreeze-thaw") };
 807     $self->logerr($@) if $@;
 808 }
 809
 810 # we need a running QEMU/KVM process for backup, starts a paused (prelaunch)
 811 # one if VM isn't already running
 812 sub enforce_vm_running_for_backup {
 813     my ($self, $vmid) = @_;
 814
 815     if (PVE::QemuServer::check_running($vmid)) {
 816         $self->{vm_was_running} = 1;
 817         return;
 818     }
 819
 820     eval {
 821         $self->loginfo("starting kvm to execute backup task");
 822         # start with skiplock
 823         my $params = {
 824             skiplock => 1,
 825             skiptemplate => 1,
 826             paused => 1,
 827         };
 828         PVE::QemuServer::vm_start($self->{storecfg}, $vmid, $params);
 829     };
 830     die $@ if $@;
 831 }
 832
 833 # resume VM againe once we got in a clear state (stop mode backup of running VM)
 834 sub resume_vm_after_job_start {
 835     my ($self, $task, $vmid) = @_;
 836
 837     return if !$self->{vm_was_running};
 838
 839     if (my $stoptime = $task->{vmstoptime}) {
 840         my $delay = time() - $task->{vmstoptime};
 841         $task->{vmstoptime} = undef; # avoid printing 'online after ..' twice
 842         $self->loginfo("resuming VM again after $delay seconds");
 843     } else {
 844         $self->loginfo("resuming VM again");
 845     }
 846     mon_cmd($vmid, 'cont');
 847 }
 848
 849 # stop again if VM was not running before
 850 sub restore_vm_power_state {
 851     my ($self, $vmid) = @_;
 852
 853     # we always let VMs keep running
 854     return if $self->{vm_was_running};
 855
 856     eval {
 857         my $resp = mon_cmd($vmid, 'query-status');
 858         my $status = $resp && $resp->{status} ?  $resp->{status} : 'unknown';
 859         if ($status eq 'prelaunch') {
 860             $self->loginfo("stopping kvm after backup task");
 861             PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1);
 862         } else {
 863             $self->loginfo("kvm status changed after backup ('$status') - keep VM running");
 864         }
 865     };
 866     warn $@ if $@;
 867 }
 868
 869 sub mon_backup_cancel {
 870     my ($self, $vmid) = @_;
 871
 872     $self->loginfo("aborting backup job");
 873     eval { mon_cmd($vmid, 'backup-cancel') };
 874     $self->logerr($@) if $@;
 875 }
 876
 877 sub snapshot {
 878     my ($self, $task, $vmid) = @_;
 879
 880     # nothing to do
 881 }
 882
 883 sub cleanup {
 884     my ($self, $task, $vmid) = @_;
 885
 886     # nothing to do ?
 887 }
 888
 889 1;