test/run_config2command_tests.pl

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use lib qw(..);
   7
   8 use Test::More;
   9 use Test::MockModule;
  10
  11 use PVE::Tools qw(file_get_contents file_set_contents run_command);
  12 use PVE::QemuConfig;
  13 use PVE::QemuServer;
  14
  15 my $base_env = {
  16     storage_config => {
  17         ids => {
  18             local => {
  19                 content => {
  20                     images => 1,
  21                 },
  22                 path => '/var/lib/vz',
  23                 type => 'dir',
  24                 shared => 0,
  25             },
  26             'cifs-store' => {
  27                 shared => 1,
  28                 path => '/mnt/pve/cifs-store',
  29                 username => 'guest',
  30                 server => '127.0.0.42',
  31                 type => 'cifs',
  32                 share => 'CIFShare',
  33                 content => {
  34                     images => 1
  35                 },
  36             },
  37             'rbd-store' => {
  38                 monhost => '127.0.0.42,127.0.0.21,::1',
  39                 content => {
  40                     images => 1
  41                 },
  42                 type => 'rbd',
  43                 pool => 'cpool',
  44                 username => 'admin',
  45                 shared => 1
  46             },
  47             'local-lvm' => {
  48                 vgname => 'pve',
  49                 bwlimit => 'restore=1024',
  50                 type => 'lvmthin',
  51                 thinpool => 'data',
  52                 content => {
  53                     images => 1,
  54                 }
  55             }
  56         }
  57     },
  58     vmid => 8006,
  59     real_qemu_version => PVE::QemuServer::kvm_user_version(), # not yet mocked
  60 };
  61
  62 my $current_test; # = {
  63 #   description => 'Test description', # if available
  64 #   qemu_version => '2.12',
  65 #   host_arch => 'HOST_ARCH',
  66 #   config => { config hash },
  67 #   expected => [ expected outcome cmd line array ],
  68 # };
  69
  70 # use the config description to allow changing environment, fields are:
  71 #   TEST: A single line describing the test, gets outputted
  72 #   QEMU_VERSION: \d+\.\d+(\.\d+)? (defaults to current version)
  73 #   HOST_ARCH: x86_64 | aarch64 (default to x86_64, to make tests stable)
  74 # all fields are optional
  75 sub parse_test($) {
  76     my ($config_fn) = @_;
  77
  78     $current_test = {}; # reset
  79
  80     my $fake_config_fn ="$config_fn/qemu-server/8006.conf";
  81     my $config_raw = file_get_contents($config_fn);
  82     my $config = PVE::QemuServer::parse_vm_config($fake_config_fn, $config_raw);
  83
  84     $current_test->{config} = $config;
  85
  86     my $description = $config->{description} // '';
  87
  88     while ($description =~ /^\h*(.*?)\h*$/gm) {
  89         my $line = $1;
  90         next if !$line || $line =~ /^#/;
  91         $line =~ s/^\s+//;
  92         $line =~ s/\s+$//;
  93
  94         if ($line =~ /^TEST:\s*(.*)\s*$/) {
  95             $current_test->{description} = "$1";
  96         } elsif ($line =~ /^QEMU_VERSION:\s*(.*)\s*$/) {
  97             $current_test->{qemu_version} = "$1";
  98         } elsif ($line =~ /^HOST_ARCH:\s*(.*)\s*$/) {
  99             $current_test->{host_arch} = "$1";
 100         }
 101     }
 102 }
 103
 104 my $qemu_server_module;
 105 $qemu_server_module = Test::MockModule->new('PVE::QemuServer');
 106 $qemu_server_module->mock(
 107     kvm_user_version => sub {
 108         return $current_test->{qemu_version} // $base_env->{real_qemu_version};
 109     },
 110     kvm_version => sub {
 111         return $current_test->{qemu_version} // $base_env->{real_qemu_version};
 112     },
 113     get_host_arch => sub() {
 114         return $current_test->{host_arch} // 'x86_64';
 115     },
 116     get_initiator_name => sub {
 117         return 'iqn.1993-08.org.debian:01:aabbccddeeff';
 118     }
 119 );
 120
 121 my $qemu_server_config;
 122 $qemu_server_config = Test::MockModule->new('PVE::QemuConfig');
 123 $qemu_server_config->mock(
 124     load_config => sub {
 125         my ($class, $vmid, $node) = @_;
 126
 127         return $current_test->{config};
 128     },
 129 );
 130
 131 sub diff($$) {
 132     my ($a, $b) = @_;
 133     return if $a eq $b;
 134
 135     my ($ra, $wa) = POSIX::pipe();
 136     my ($rb, $wb) = POSIX::pipe();
 137     my $ha = IO::Handle->new_from_fd($wa, 'w');
 138     my $hb = IO::Handle->new_from_fd($wb, 'w');
 139
 140     open my $diffproc, '-|', 'diff', '-up', "/dev/fd/$ra", "/dev/fd/$rb"
 141         or die "failed to run program 'diff': $!";
 142     POSIX::close($ra);
 143     POSIX::close($rb);
 144
 145     open my $f1, '<', \$a;
 146     open my $f2, '<', \$b;
 147     my ($line1, $line2);
 148     do {
 149         $ha->print($line1) if defined($line1 = <$f1>);
 150         $hb->print($line2) if defined($line2 = <$f2>);
 151     } while (defined($line1 // $line2));
 152     close $f1;
 153     close $f2;
 154     close $ha;
 155     close $hb;
 156
 157     local $/ = undef;
 158     my $diff = <$diffproc>;
 159     close $diffproc;
 160     die "files differ:\n$diff";
 161 }
 162
 163 sub do_test($) {
 164     my ($config_fn) = @_;
 165
 166     die "no such input test config: $config_fn\n" if ! -f $config_fn;
 167
 168     parse_test $config_fn;
 169
 170     $config_fn =~ /([^\/]+)$/;
 171     my $testname = "$1";
 172     if (my $desc = $current_test->{description}) {
 173         $testname = "'$testname' - $desc";
 174     }
 175
 176     my ($vmid, $storecfg) = $base_env->@{qw(vmid storage_config)};
 177
 178     my $cmdline = PVE::QemuServer::vm_commandline($storecfg, $vmid);
 179
 180     $cmdline =~ s/ -/ \\\n  -/g; # same as qm showcmd --pretty
 181     $cmdline .= "\n";
 182
 183     my $cmd_fn = "$config_fn.cmd";
 184
 185     if (-f $cmd_fn) {
 186         my $cmdline_expected = file_get_contents($cmd_fn);
 187
 188         my $cmd_expected = [ sort split /\s*\\?\n\s*/, $cmdline_expected ];
 189         my $cmd = [ sort split /\s*\\?\n\s*/, $cmdline ];
 190
 191         # comment out for easier debugging
 192         #file_set_contents("$cmd_fn.tmp", $cmdline);
 193
 194         my $exp = join("\n", @$cmd_expected);
 195         my $got = join("\n", @$cmd);
 196         eval { diff($exp, $got) };
 197         if (my $err = $@) {
 198             fail("$testname");
 199             note($err);
 200         } else {
 201             pass("$testname");
 202         }
 203     } else {
 204         file_set_contents($cmd_fn, $cmdline);
 205     }
 206 }
 207
 208 print "testing config to command stabillity\n";
 209
 210 # exec tests
 211 if (my $file = shift) {
 212     do_test $file;
 213 } else {
 214     foreach my $file (<cfg2cmd/*.conf>) {
 215         do_test $file;
 216     }
 217 }
 218
 219 done_testing();