test/run_config2command_tests.pl

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use lib qw(..);
   7
   8 use Test::More;
   9 use Test::MockModule;
  10 use Socket qw(AF_INET AF_INET6);
  11
  12 use PVE::Tools qw(file_get_contents file_set_contents run_command);
  13 use PVE::INotify;
  14 use PVE::SysFSTools;
  15
  16 use PVE::QemuConfig;
  17 use PVE::QemuServer;
  18 use PVE::QemuServer::Monitor;
  19 use PVE::QemuServer::Machine;
  20 use PVE::QemuServer::CPUConfig;
  21
  22 my $base_env = {
  23     storage_config => {
  24         ids => {
  25             local => {
  26                 content => {
  27                     images => 1,
  28                 },
  29                 path => '/var/lib/vz',
  30                 type => 'dir',
  31                 shared => 0,
  32             },
  33             'cifs-store' => {
  34                 shared => 1,
  35                 path => '/mnt/pve/cifs-store',
  36                 username => 'guest',
  37                 server => '127.0.0.42',
  38                 type => 'cifs',
  39                 share => 'CIFShare',
  40                 content => {
  41                     images => 1
  42                 },
  43             },
  44             'rbd-store' => {
  45                 monhost => '127.0.0.42,127.0.0.21,::1',
  46                 content => {
  47                     images => 1
  48                 },
  49                 type => 'rbd',
  50                 pool => 'cpool',
  51                 username => 'admin',
  52                 shared => 1
  53             },
  54             'local-lvm' => {
  55                 vgname => 'pve',
  56                 bwlimit => 'restore=1024',
  57                 type => 'lvmthin',
  58                 thinpool => 'data',
  59                 content => {
  60                     images => 1,
  61                 }
  62             }
  63         }
  64     },
  65     vmid => 8006,
  66     real_qemu_version => PVE::QemuServer::kvm_user_version(), # not yet mocked
  67 };
  68
  69 my $pci_devs = [
  70     "0000:00:43.1",
  71     "0000:00:f4.0",
  72     "0000:00:ff.1",
  73     "0000:0f:f2.0",
  74     "0000:d0:13.0",
  75     "0000:d0:15.1",
  76     "0000:d0:17.0",
  77     "0000:f0:42.0",
  78     "0000:f0:43.0",
  79     "0000:f0:43.1",
  80     "1234:f0:43.1",
  81 ];
  82
  83 my $current_test; # = {
  84 #   description => 'Test description', # if available
  85 #   qemu_version => '2.12',
  86 #   host_arch => 'HOST_ARCH',
  87 #   config => { config hash },
  88 #   expected => [ expected outcome cmd line array ],
  89 # };
  90
  91 # use the config description to allow changing environment, fields are:
  92 #   TEST: A single line describing the test, gets outputted
  93 #   QEMU_VERSION: \d+\.\d+(\.\d+)? (defaults to current version)
  94 #   HOST_ARCH: x86_64 | aarch64 (default to x86_64, to make tests stable)
  95 # all fields are optional
  96 sub parse_test($) {
  97     my ($config_fn) = @_;
  98
  99     $current_test = {}; # reset
 100
 101     my $fake_config_fn ="$config_fn/qemu-server/8006.conf";
 102     my $config_raw = file_get_contents($config_fn);
 103     my $config = PVE::QemuServer::parse_vm_config($fake_config_fn, $config_raw);
 104
 105     $current_test->{config} = $config;
 106
 107     my $description = $config->{description} // '';
 108
 109     while ($description =~ /^\h*(.*?)\h*$/gm) {
 110         my $line = $1;
 111         next if !$line || $line =~ /^#/;
 112         $line =~ s/^\s+//;
 113         $line =~ s/\s+$//;
 114
 115         if ($line =~ /^TEST:\s*(.*)\s*$/) {
 116             $current_test->{description} = "$1";
 117         } elsif ($line =~ /^QEMU_VERSION:\s*(.*)\s*$/) {
 118             $current_test->{qemu_version} = "$1";
 119         } elsif ($line =~ /^HOST_ARCH:\s*(.*)\s*$/) {
 120             $current_test->{host_arch} = "$1";
 121         } elsif ($line =~ /^EXPECT_ERROR:\s*(.*)\s*$/) {
 122             $current_test->{expect_error} = "$1";
 123         }
 124     }
 125 }
 126
 127 sub get_test_qemu_version {
 128     $current_test->{qemu_version} // $base_env->{real_qemu_version} // '2.12';
 129 }
 130
 131 my $qemu_server_module;
 132 $qemu_server_module = Test::MockModule->new('PVE::QemuServer');
 133 $qemu_server_module->mock(
 134     kvm_user_version => sub {
 135         return get_test_qemu_version();
 136     },
 137     kvm_version => sub {
 138         return get_test_qemu_version();
 139     },
 140     kernel_has_vhost_net => sub {
 141         return 1; # TODO: make this per-test configurable?
 142     },
 143     get_host_arch => sub() {
 144         return $current_test->{host_arch} // 'x86_64';
 145     },
 146     get_initiator_name => sub {
 147         return 'iqn.1993-08.org.debian:01:aabbccddeeff';
 148     }
 149 );
 150
 151 my $qemu_server_config;
 152 $qemu_server_config = Test::MockModule->new('PVE::QemuConfig');
 153 $qemu_server_config->mock(
 154     load_config => sub {
 155         my ($class, $vmid, $node) = @_;
 156
 157         return $current_test->{config};
 158     },
 159 );
 160
 161 my $pve_common_tools;
 162 $pve_common_tools = Test::MockModule->new('PVE::Tools');
 163 $pve_common_tools->mock(
 164     next_vnc_port => sub {
 165         my ($family, $address) = @_;
 166
 167         return '5900';
 168     },
 169     next_spice_port => sub {
 170         my ($family, $address) = @_;
 171
 172         return '61000';
 173     },
 174     getaddrinfo_all => sub {
 175         my ($hostname, @opts) = @_;
 176         die "need stable hostname" if $hostname ne 'localhost';
 177         return (
 178             {
 179                 addr => Socket::pack_sockaddr_in(0, Socket::INADDR_LOOPBACK),
 180                 family => AF_INET, # IPv4
 181                 protocol => 6,
 182                 socktype => 1,
 183             },
 184         );
 185     },
 186 );
 187
 188 my $pve_cpuconfig;
 189 $pve_cpuconfig = Test::MockModule->new('PVE::QemuServer::CPUConfig');
 190 $pve_cpuconfig->mock(
 191     load_custom_model_conf => sub {
 192         # mock custom CPU model config
 193         return PVE::QemuServer::CPUConfig->parse_config("cpu-models.conf",
 194 <<EOF
 195
 196 # "qemu64" is also a default CPU, used here to test that this doesn't matter
 197 cpu-model: qemu64
 198     reported-model athlon
 199     flags +aes;+avx;-kvm_pv_unhalt
 200     hv-vendor-id testvend
 201     phys-bits 40
 202
 203 cpu-model: alldefault
 204
 205 EOF
 206         )
 207     },
 208 );
 209
 210 my $pve_common_network;
 211 $pve_common_network = Test::MockModule->new('PVE::Network');
 212 $pve_common_network->mock(
 213     read_bridge_mtu => sub {
 214         return 1500;
 215     },
 216 );
 217
 218
 219 my $pve_common_inotify;
 220 $pve_common_inotify = Test::MockModule->new('PVE::INotify');
 221 $pve_common_inotify->mock(
 222     nodename => sub {
 223         return 'localhost';
 224     },
 225 );
 226
 227 my $pve_common_sysfstools;
 228 $pve_common_sysfstools = Test::MockModule->new('PVE::SysFSTools');
 229 $pve_common_sysfstools->mock(
 230     lspci => sub {
 231         my ($filter, $verbose) = @_;
 232
 233         return [
 234             map { { id => $_ } }
 235             grep {
 236                 !defined($filter)
 237                 || (!ref($filter) && $_ =~ m/^(0000:)?\Q$filter\E/)
 238                 || (ref($filter) eq 'CODE' && $filter->({ id => $_ }))
 239             } sort @$pci_devs
 240         ];
 241     },
 242 );
 243
 244 my $qemu_monitor_module;
 245 $qemu_monitor_module = Test::MockModule->new('PVE::QemuServer::Monitor');
 246 $qemu_monitor_module->mock(
 247     mon_cmd => sub {
 248         my ($vmid, $cmd) = @_;
 249
 250         die "invalid vmid: $vmid (expected: $base_env->{vmid})"
 251             if $vmid != $base_env->{vmid};
 252
 253         if ($cmd eq 'query-version') {
 254             my $ver = get_test_qemu_version();
 255             $ver =~ m/(\d+)\.(\d+)(?:\.(\d+))?/;
 256             return {
 257                 qemu => {
 258                     major => $1,
 259                     minor => $2,
 260                     micro => $3
 261                 }
 262             }
 263         }
 264
 265         die "unexpected QMP command: '$cmd'";
 266     },
 267 );
 268 $qemu_monitor_module->mock('qmp_cmd', \&qmp_cmd);
 269
 270 sub diff($$) {
 271     my ($a, $b) = @_;
 272     return if $a eq $b;
 273
 274     my ($ra, $wa) = POSIX::pipe();
 275     my ($rb, $wb) = POSIX::pipe();
 276     my $ha = IO::Handle->new_from_fd($wa, 'w');
 277     my $hb = IO::Handle->new_from_fd($wb, 'w');
 278
 279     open my $diffproc, '-|', 'diff', '-up', "/proc/self/fd/$ra", "/proc/self/fd/$rb"
 280         or die "failed to run program 'diff': $!";
 281     POSIX::close($ra);
 282     POSIX::close($rb);
 283
 284     open my $f1, '<', \$a;
 285     open my $f2, '<', \$b;
 286     my ($line1, $line2);
 287     do {
 288         $ha->print($line1) if defined($line1 = <$f1>);
 289         $hb->print($line2) if defined($line2 = <$f2>);
 290     } while (defined($line1 // $line2));
 291     close $f1;
 292     close $f2;
 293     close $ha;
 294     close $hb;
 295
 296     local $/ = undef;
 297     my $diff = <$diffproc>;
 298     close $diffproc;
 299     die "files differ:\n$diff";
 300 }
 301
 302 sub do_test($) {
 303     my ($config_fn) = @_;
 304
 305     die "no such input test config: $config_fn\n" if ! -f $config_fn;
 306
 307     parse_test $config_fn;
 308
 309     $config_fn =~ /([^\/]+)$/;
 310     my $testname = "$1";
 311     if (my $desc = $current_test->{description}) {
 312         $testname = "'$testname' - $desc";
 313     }
 314
 315     my ($vmid, $storecfg) = $base_env->@{qw(vmid storage_config)};
 316
 317     my $cmdline = eval { PVE::QemuServer::vm_commandline($storecfg, $vmid) };
 318     my $err = $@;
 319
 320     if (my $err_expect = $current_test->{expect_error}) {
 321         if (!$err) {
 322             fail("$testname");
 323             note("did NOT get any error, but expected error: $err_expect");
 324             return;
 325         }
 326         chomp $err;
 327         if ($err ne $err_expect) {
 328             fail("$testname");
 329             note("error does not match expected error: '$err' !~ '$err_expect'");
 330         } else {
 331             pass("$testname");
 332         }
 333         return;
 334     } elsif ($err) {
 335         fail("$testname");
 336         note("got unexpected error: $err");
 337         return;
 338     }
 339
 340     # check if QEMU version set correctly and test version_cmp
 341     (my $qemu_major = get_test_qemu_version()) =~ s/\..*$//;
 342     die "runs_at_least_qemu_version returned false, maybe error in version_cmp?"
 343         if !PVE::QemuServer::Machine::runs_at_least_qemu_version($vmid, $qemu_major);
 344
 345     $cmdline =~ s/ -/ \\\n  -/g; # same as qm showcmd --pretty
 346     $cmdline .= "\n";
 347
 348     my $cmd_fn = "$config_fn.cmd";
 349
 350     if (-f $cmd_fn) {
 351         my $cmdline_expected = file_get_contents($cmd_fn);
 352
 353         my $cmd_expected = [ split /\s*\\?\n\s*/, $cmdline_expected ];
 354         my $cmd = [ split /\s*\\?\n\s*/, $cmdline ];
 355
 356         # uncomment for easier debugging
 357         #file_set_contents("$cmd_fn.tmp", $cmdline);
 358
 359         my $exp = join("\n", @$cmd_expected);
 360         my $got = join("\n", @$cmd);
 361         eval { diff($exp, $got) };
 362         if (my $err = $@) {
 363             fail("$testname");
 364             note($err);
 365         } else {
 366             pass("$testname");
 367         }
 368     } else {
 369         file_set_contents($cmd_fn, $cmdline);
 370     }
 371 }
 372
 373 print "testing config to command stabillity\n";
 374
 375 # exec tests
 376 if (my $file = shift) {
 377     do_test $file;
 378 } else {
 379     foreach my $file (<cfg2cmd/*.conf>) {
 380         do_test $file;
 381     }
 382 }
 383
 384 done_testing();