PVE/QemuMigrate.pm

   1 package PVE::QemuMigrate;
   2
   3 use strict;
   4 use warnings;
   5
   6 use IO::File;
   7 use IPC::Open2;
   8 use POSIX qw( WNOHANG );
   9 use Time::HiRes qw( usleep );
  10
  11 use PVE::Cluster;
  12 use PVE::INotify;
  13 use PVE::RPCEnvironment;
  14 use PVE::Replication;
  15 use PVE::ReplicationConfig;
  16 use PVE::ReplicationState;
  17 use PVE::Storage;
  18 use PVE::Tools;
  19
  20 use PVE::QemuConfig;
  21 use PVE::QemuServer::CPUConfig;
  22 use PVE::QemuServer::Drive;
  23 use PVE::QemuServer::Helpers qw(min_version);
  24 use PVE::QemuServer::Machine;
  25 use PVE::QemuServer::Monitor qw(mon_cmd);
  26 use PVE::QemuServer;
  27
  28 use PVE::AbstractMigrate;
  29 use base qw(PVE::AbstractMigrate);
  30
  31 sub fork_command_pipe {
  32     my ($self, $cmd) = @_;
  33
  34     my $reader = IO::File->new();
  35     my $writer = IO::File->new();
  36
  37     my $orig_pid = $$;
  38
  39     my $cpid;
  40
  41     eval { $cpid = open2($reader, $writer, @$cmd); };
  42
  43     my $err = $@;
  44
  45     # catch exec errors
  46     if ($orig_pid != $$) {
  47         $self->log('err', "can't fork command pipe\n");
  48         POSIX::_exit(1);
  49         kill('KILL', $$);
  50     }
  51
  52     die $err if $err;
  53
  54     return { writer => $writer, reader => $reader, pid => $cpid };
  55 }
  56
  57 sub finish_command_pipe {
  58     my ($self, $cmdpipe, $timeout) = @_;
  59
  60     my $cpid = $cmdpipe->{pid};
  61     return if !defined($cpid);
  62
  63     my $writer = $cmdpipe->{writer};
  64     my $reader = $cmdpipe->{reader};
  65
  66     $writer->close();
  67     $reader->close();
  68
  69     my $collect_child_process = sub {
  70         my $res = waitpid($cpid, WNOHANG);
  71         if (defined($res) && ($res == $cpid)) {
  72             delete $cmdpipe->{cpid};
  73             return 1;
  74         } else {
  75             return 0;
  76         }
  77      };
  78
  79     if ($timeout) {
  80         for (my $i = 0; $i < $timeout; $i++) {
  81             return if &$collect_child_process();
  82             sleep(1);
  83         }
  84     }
  85
  86     $self->log('info', "ssh tunnel still running - terminating now with SIGTERM\n");
  87     kill(15, $cpid);
  88
  89     # wait again
  90     for (my $i = 0; $i < 10; $i++) {
  91         return if &$collect_child_process();
  92         sleep(1);
  93     }
  94
  95     $self->log('info', "ssh tunnel still running - terminating now with SIGKILL\n");
  96     kill 9, $cpid;
  97     sleep 1;
  98
  99     $self->log('err', "ssh tunnel child process (PID $cpid) couldn't be collected\n")
 100         if !&$collect_child_process();
 101 }
 102
 103 sub read_tunnel {
 104     my ($self, $tunnel, $timeout) = @_;
 105
 106     $timeout = 60 if !defined($timeout);
 107
 108     my $reader = $tunnel->{reader};
 109
 110     my $output;
 111     eval {
 112         PVE::Tools::run_with_timeout($timeout, sub { $output = <$reader>; });
 113     };
 114     die "reading from tunnel failed: $@\n" if $@;
 115
 116     chomp $output;
 117
 118     return $output;
 119 }
 120
 121 sub write_tunnel {
 122     my ($self, $tunnel, $timeout, $command) = @_;
 123
 124     $timeout = 60 if !defined($timeout);
 125
 126     my $writer = $tunnel->{writer};
 127
 128     eval {
 129         PVE::Tools::run_with_timeout($timeout, sub {
 130             print $writer "$command\n";
 131             $writer->flush();
 132         });
 133     };
 134     die "writing to tunnel failed: $@\n" if $@;
 135
 136     if ($tunnel->{version} && $tunnel->{version} >= 1) {
 137         my $res = eval { $self->read_tunnel($tunnel, 10); };
 138         die "no reply to command '$command': $@\n" if $@;
 139
 140         if ($res eq 'OK') {
 141             return;
 142         } else {
 143             die "tunnel replied '$res' to command '$command'\n";
 144         }
 145     }
 146 }
 147
 148 sub fork_tunnel {
 149     my ($self, $tunnel_addr) = @_;
 150
 151     my @localtunnelinfo = ();
 152     foreach my $addr (@$tunnel_addr) {
 153         push @localtunnelinfo, '-L', $addr;
 154     }
 155
 156     my $cmd = [@{$self->{rem_ssh}}, '-o ExitOnForwardFailure=yes', @localtunnelinfo, '/usr/sbin/qm', 'mtunnel' ];
 157
 158     my $tunnel = $self->fork_command_pipe($cmd);
 159
 160     eval {
 161         my $helo = $self->read_tunnel($tunnel, 60);
 162         die "no reply\n" if !$helo;
 163         die "no quorum on target node\n" if $helo =~ m/^no quorum$/;
 164         die "got strange reply from mtunnel ('$helo')\n"
 165             if $helo !~ m/^tunnel online$/;
 166     };
 167     my $err = $@;
 168
 169     eval {
 170         my $ver = $self->read_tunnel($tunnel, 10);
 171         if ($ver =~ /^ver (\d+)$/) {
 172             $tunnel->{version} = $1;
 173             $self->log('info', "ssh tunnel $ver\n");
 174         } else {
 175             $err = "received invalid tunnel version string '$ver'\n" if !$err;
 176         }
 177     };
 178
 179     if ($err) {
 180         $self->finish_command_pipe($tunnel);
 181         die "can't open migration tunnel - $err";
 182     }
 183     return $tunnel;
 184 }
 185
 186 sub finish_tunnel {
 187     my ($self, $tunnel) = @_;
 188
 189     eval { $self->write_tunnel($tunnel, 30, 'quit'); };
 190     my $err = $@;
 191
 192     $self->finish_command_pipe($tunnel, 30);
 193
 194     if ($tunnel->{sock_addr}) {
 195         # ssh does not clean up on local host
 196         my $cmd = ['rm', '-f', @{$tunnel->{sock_addr}}]; #
 197         PVE::Tools::run_command($cmd);
 198
 199         # .. and just to be sure check on remote side
 200         unshift @{$cmd}, @{$self->{rem_ssh}};
 201         PVE::Tools::run_command($cmd);
 202     }
 203
 204     die $err if $err;
 205 }
 206
 207 sub lock_vm {
 208     my ($self, $vmid, $code, @param) = @_;
 209
 210     return PVE::QemuConfig->lock_config($vmid, $code, @param);
 211 }
 212
 213 sub prepare {
 214     my ($self, $vmid) = @_;
 215
 216     my $online = $self->{opts}->{online};
 217
 218     $self->{storecfg} = PVE::Storage::config();
 219
 220     # test if VM exists
 221     my $conf = $self->{vmconf} = PVE::QemuConfig->load_config($vmid);
 222
 223     PVE::QemuConfig->check_lock($conf);
 224
 225     my $running = 0;
 226     if (my $pid = PVE::QemuServer::check_running($vmid)) {
 227         die "can't migrate running VM without --online\n" if !$online;
 228         $running = $pid;
 229
 230         $self->{forcemachine} = PVE::QemuServer::Machine::qemu_machine_pxe($vmid, $conf);
 231
 232         # To support custom CPU types, we keep QEMU's "-cpu" parameter intact.
 233         # Since the parameter itself contains no reference to a custom model,
 234         # this makes migration independent of changes to "cpu-models.conf".
 235         if ($conf->{cpu}) {
 236             my $cpuconf = PVE::QemuServer::CPUConfig::parse_cpu_conf_basic($conf->{cpu});
 237             if ($cpuconf && PVE::QemuServer::CPUConfig::is_custom_model($cpuconf->{cputype})) {
 238                 $self->{forcecpu} = PVE::QemuServer::CPUConfig::get_cpu_from_running_vm($pid);
 239             }
 240         }
 241     }
 242
 243     my $loc_res = PVE::QemuServer::check_local_resources($conf, 1);
 244     if (scalar @$loc_res) {
 245         if ($self->{running} || !$self->{opts}->{force}) {
 246             die "can't migrate VM which uses local devices: " . join(", ", @$loc_res) . "\n";
 247         } else {
 248             $self->log('info', "migrating VM which uses local devices");
 249         }
 250     }
 251
 252     my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 253
 254     my $need_activate = [];
 255     foreach my $volid (@$vollist) {
 256         my ($sid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 257
 258         # check if storage is available on both nodes
 259         my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $sid);
 260
 261         my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 262         PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 263
 264         if ($scfg->{shared}) {
 265             # PVE::Storage::activate_storage checks this for non-shared storages
 266             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 267             warn "Used shared storage '$sid' is not online on source node!\n"
 268                 if !$plugin->check_connection($sid, $scfg);
 269         } else {
 270             # only activate if not shared
 271             next if ($volid =~ m/vm-\d+-cloudinit/);
 272             push @$need_activate, $volid;
 273         }
 274     }
 275
 276     # activate volumes
 277     PVE::Storage::activate_volumes($self->{storecfg}, $need_activate);
 278
 279     # test ssh connection
 280     my $cmd = [ @{$self->{rem_ssh}}, '/bin/true' ];
 281     eval { $self->cmd_quiet($cmd); };
 282     die "Can't connect to destination address using public key\n" if $@;
 283
 284     return $running;
 285 }
 286
 287 sub sync_disks {
 288     my ($self, $vmid) = @_;
 289
 290     my $conf = $self->{vmconf};
 291
 292     # local volumes which have been copied
 293     # and their old_id => new_id pairs
 294     $self->{volumes} = [];
 295     $self->{volume_map} = {};
 296
 297     my $storecfg = $self->{storecfg};
 298     eval {
 299
 300         # found local volumes and their origin
 301         my $local_volumes = {};
 302         my $local_volumes_errors = {};
 303         my $other_errors = [];
 304         my $abort = 0;
 305
 306         my $log_error = sub {
 307             my ($msg, $volid) = @_;
 308
 309             if (defined($volid)) {
 310                 $local_volumes_errors->{$volid} = $msg;
 311             } else {
 312                 push @$other_errors, $msg;
 313             }
 314             $abort = 1;
 315         };
 316
 317         my @sids = PVE::Storage::storage_ids($storecfg);
 318         foreach my $storeid (@sids) {
 319             my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
 320             next if $scfg->{shared};
 321             next if !PVE::Storage::storage_check_enabled($storecfg, $storeid, undef, 1);
 322
 323             # get list from PVE::Storage (for unused volumes)
 324             my $dl = PVE::Storage::vdisk_list($storecfg, $storeid, $vmid);
 325
 326             next if @{$dl->{$storeid}} == 0;
 327
 328             my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $storeid);
 329             # check if storage is available on target node
 330             PVE::Storage::storage_check_node($storecfg, $targetsid, $self->{node});
 331
 332             # grandfather in existing mismatches
 333             if ($targetsid ne $storeid) {
 334                 my $target_scfg = PVE::Storage::storage_config($storecfg, $targetsid);
 335                 die "content type 'images' is not available on storage '$targetsid'\n"
 336                     if !$target_scfg->{content}->{images};
 337             }
 338
 339             PVE::Storage::foreach_volid($dl, sub {
 340                 my ($volid, $sid, $volinfo) = @_;
 341
 342                 $local_volumes->{$volid}->{ref} = 'storage';
 343
 344                 # If with_snapshots is not set for storage migrate, it tries to use
 345                 # a raw+size stream, but on-the-fly conversion from qcow2 to raw+size
 346                 # back to qcow2 is currently not possible.
 347                 $local_volumes->{$volid}->{snapshots} = ($volinfo->{format} =~ /^(?:qcow2|vmdk)$/);
 348                 $local_volumes->{$volid}->{format} = $volinfo->{format};
 349             });
 350         }
 351
 352         my $rep_cfg = PVE::ReplicationConfig->new();
 353         my $replication_jobcfg = $rep_cfg->find_local_replication_job($vmid, $self->{node});
 354         my $replicatable_volumes = !$replication_jobcfg ? {}
 355             : PVE::QemuConfig->get_replicatable_volumes($storecfg, $vmid, $conf, 0, 1);
 356
 357         my $test_volid = sub {
 358             my ($volid, $attr) = @_;
 359
 360             if ($volid =~ m|^/|) {
 361                 return if $attr->{shared};
 362                 $local_volumes->{$volid}->{ref} = 'config';
 363                 die "local file/device\n";
 364             }
 365
 366             my $snaprefs = $attr->{referenced_in_snapshot};
 367
 368             if ($attr->{cdrom}) {
 369                 if ($volid eq 'cdrom') {
 370                     my $msg = "can't migrate local cdrom drive";
 371                     if (defined($snaprefs) && !$attr->{referenced_in_config}) {
 372                         my $snapnames = join(', ', sort keys %$snaprefs);
 373                         $msg .= " (referenced in snapshot - $snapnames)";
 374                     }
 375                     &$log_error("$msg\n");
 376                     return;
 377                 }
 378                 return if $volid eq 'none';
 379             }
 380
 381             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 382
 383             my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $sid);
 384             # check if storage is available on both nodes
 385             my $scfg = PVE::Storage::storage_check_node($storecfg, $sid);
 386             PVE::Storage::storage_check_node($storecfg, $targetsid, $self->{node});
 387
 388             return if $scfg->{shared};
 389
 390             $local_volumes->{$volid}->{ref} = $attr->{referenced_in_config} ? 'config' : 'snapshot';
 391
 392             $local_volumes->{$volid}->{is_vmstate} = $attr->{is_vmstate} ? 1 : 0;
 393
 394             if ($attr->{cdrom}) {
 395                 if ($volid =~ /vm-\d+-cloudinit/) {
 396                     $local_volumes->{$volid}->{ref} = 'generated';
 397                     return;
 398                 }
 399                 die "local cdrom image\n";
 400             }
 401
 402             my ($path, $owner) = PVE::Storage::path($storecfg, $volid);
 403
 404             die "owned by other VM (owner = VM $owner)\n"
 405                 if !$owner || ($owner != $vmid);
 406
 407             if (defined($snaprefs)) {
 408                 $local_volumes->{$volid}->{snapshots} = 1;
 409
 410                 # we cannot migrate shapshots on local storage
 411                 # exceptions: 'zfspool' or 'qcow2' files (on directory storage)
 412
 413                 die "online storage migration not possible if snapshot exists\n" if $self->{running};
 414                 if (!($scfg->{type} eq 'zfspool' || $local_volumes->{$volid}->{format} eq 'qcow2')) {
 415                     die "non-migratable snapshot exists\n";
 416                 }
 417             }
 418
 419             die "referenced by linked clone(s)\n"
 420                 if PVE::Storage::volume_is_base_and_used($storecfg, $volid);
 421         };
 422
 423         PVE::QemuServer::foreach_volid($conf, sub {
 424             my ($volid, $attr) = @_;
 425             eval { $test_volid->($volid, $attr); };
 426             if (my $err = $@) {
 427                 &$log_error($err, $volid);
 428             }
 429         });
 430
 431         foreach my $vol (sort keys %$local_volumes) {
 432             my $type = $replicatable_volumes->{$vol} ? 'local, replicated' : 'local';
 433             my $ref = $local_volumes->{$vol}->{ref};
 434             if ($ref eq 'storage') {
 435                 $self->log('info', "found $type disk '$vol' (via storage)\n");
 436             } elsif ($ref eq 'config') {
 437                 &$log_error("can't live migrate attached local disks without with-local-disks option\n", $vol)
 438                     if $self->{running} && !$self->{opts}->{"with-local-disks"};
 439                 $self->log('info', "found $type disk '$vol' (in current VM config)\n");
 440             } elsif ($ref eq 'snapshot') {
 441                 $self->log('info', "found $type disk '$vol' (referenced by snapshot(s))\n");
 442             } elsif ($ref eq 'generated') {
 443                 $self->log('info', "found generated disk '$vol' (in current VM config)\n");
 444             } else {
 445                 $self->log('info', "found $type disk '$vol'\n");
 446             }
 447         }
 448
 449         foreach my $vol (sort keys %$local_volumes_errors) {
 450             $self->log('warn', "can't migrate local disk '$vol': $local_volumes_errors->{$vol}");
 451         }
 452         foreach my $err (@$other_errors) {
 453             $self->log('warn', "$err");
 454         }
 455
 456         if ($abort) {
 457             die "can't migrate VM - check log\n";
 458         }
 459
 460         # additional checks for local storage
 461         foreach my $volid (keys %$local_volumes) {
 462             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 463             my $scfg =  PVE::Storage::storage_config($storecfg, $sid);
 464
 465             my $migratable = $scfg->{type} =~ /^(?:dir|zfspool|lvmthin|lvm)$/;
 466
 467             die "can't migrate '$volid' - storage type '$scfg->{type}' not supported\n"
 468                 if !$migratable;
 469
 470             # image is a linked clone on local storage, se we can't migrate.
 471             if (my $basename = (PVE::Storage::parse_volname($storecfg, $volid))[3]) {
 472                 die "can't migrate '$volid' as it's a clone of '$basename'";
 473             }
 474         }
 475
 476         if ($replication_jobcfg) {
 477             if ($self->{running}) {
 478
 479                 my $version = PVE::QemuServer::kvm_user_version();
 480                 if (!min_version($version, 4, 2)) {
 481                     die "can't live migrate VM with replicated volumes, pve-qemu to old (< 4.2)!\n"
 482                 }
 483
 484                 my $live_replicatable_volumes = {};
 485                 PVE::QemuConfig->foreach_volume($conf, sub {
 486                     my ($ds, $drive) = @_;
 487
 488                     my $volid = $drive->{file};
 489                     $live_replicatable_volumes->{$ds} = $volid
 490                         if defined($replicatable_volumes->{$volid});
 491                 });
 492                 foreach my $drive (keys %$live_replicatable_volumes) {
 493                     my $volid = $live_replicatable_volumes->{$drive};
 494
 495                     my $bitmap = "repl_$drive";
 496
 497                     # start tracking before replication to get full delta + a few duplicates
 498                     $self->log('info', "$drive: start tracking writes using block-dirty-bitmap '$bitmap'");
 499                     mon_cmd($vmid, 'block-dirty-bitmap-add', node => "drive-$drive", name => $bitmap);
 500
 501                     # other info comes from target node in phase 2
 502                     $self->{target_drive}->{$drive}->{bitmap} = $bitmap;
 503                 }
 504             }
 505             $self->log('info', "replicating disk images");
 506
 507             my $start_time = time();
 508             my $logfunc = sub { $self->log('info', shift) };
 509             $self->{replicated_volumes} = PVE::Replication::run_replication(
 510                'PVE::QemuConfig', $replication_jobcfg, $start_time, $start_time, $logfunc);
 511         }
 512
 513         # sizes in config have to be accurate for remote node to correctly
 514         # allocate disks, rescan to be sure
 515         my $volid_hash = PVE::QemuServer::scan_volids($storecfg, $vmid);
 516         PVE::QemuConfig->foreach_volume($conf, sub {
 517             my ($key, $drive) = @_;
 518             my ($updated, $old_size, $new_size) = PVE::QemuServer::Drive::update_disksize($drive, $volid_hash);
 519             if (defined($updated)) {
 520                 $conf->{$key} = PVE::QemuServer::print_drive($updated);
 521                 $self->log('info', "size of disk '$updated->{file}' ($key) updated from $old_size to $new_size\n");
 522             }
 523         });
 524
 525         # we want to set the efidisk size in the config to the size of the
 526         # real OVMF_VARS.fd image, else we can create a too big image, which does not work
 527         if (defined($conf->{efidisk0})) {
 528             PVE::QemuServer::update_efidisk_size($conf);
 529         }
 530
 531         $self->log('info', "copying local disk images") if scalar(%$local_volumes);
 532
 533         foreach my $volid (keys %$local_volumes) {
 534             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 535             my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $sid);
 536             my $ref = $local_volumes->{$volid}->{ref};
 537             if ($self->{running} && $ref eq 'config') {
 538                 push @{$self->{online_local_volumes}}, $volid;
 539             } elsif ($ref eq 'generated') {
 540                 die "can't live migrate VM with local cloudinit disk. use a shared storage instead\n" if $self->{running};
 541                 # skip all generated volumes but queue them for deletion in phase3_cleanup
 542                 push @{$self->{volumes}}, $volid;
 543                 next;
 544             } else {
 545                 next if $self->{replicated_volumes}->{$volid};
 546                 push @{$self->{volumes}}, $volid;
 547                 my $opts = $self->{opts};
 548                 # use 'migrate' limit for transfer to other node
 549                 my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', [$targetsid, $sid], $opts->{bwlimit});
 550                 # JSONSchema and get_bandwidth_limit use kbps - storage_migrate bps
 551                 $bwlimit = $bwlimit * 1024 if defined($bwlimit);
 552
 553                 my $storage_migrate_opts = {
 554                     'bwlimit' => $bwlimit,
 555                     'insecure' => $opts->{migration_type} eq 'insecure',
 556                     'with_snapshots' => $local_volumes->{$volid}->{snapshots},
 557                     'allow_rename' => !$local_volumes->{$volid}->{is_vmstate},
 558                 };
 559
 560                 my $logfunc = sub { $self->log('info', $_[0]); };
 561                 my $new_volid = eval {
 562                     PVE::Storage::storage_migrate($storecfg, $volid, $self->{ssh_info},
 563                                                   $targetsid, $storage_migrate_opts, $logfunc);
 564                 };
 565                 if (my $err = $@) {
 566                     die "storage migration for '$volid' to storage '$targetsid' failed - $err\n";
 567                 }
 568
 569                 $self->{volume_map}->{$volid} = $new_volid;
 570                 $self->log('info', "volume '$volid' is '$new_volid' on the target\n");
 571             }
 572         }
 573     };
 574     die "Failed to sync data - $@" if $@;
 575 }
 576
 577 sub cleanup_remotedisks {
 578     my ($self) = @_;
 579
 580     foreach my $target_drive (keys %{$self->{target_drive}}) {
 581         my $drivestr = $self->{target_drive}->{$target_drive}->{drivestr};
 582         next if !defined($drivestr);
 583
 584         my $drive = PVE::QemuServer::parse_drive($target_drive, $drivestr);
 585
 586         # don't clean up replicated disks!
 587         next if defined($self->{replicated_volumes}->{$drive->{file}});
 588
 589         my ($storeid, $volname) = PVE::Storage::parse_volume_id($drive->{file});
 590
 591         my $cmd = [@{$self->{rem_ssh}}, 'pvesm', 'free', "$storeid:$volname"];
 592
 593         eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 594         if (my $err = $@) {
 595             $self->log('err', $err);
 596             $self->{errors} = 1;
 597         }
 598     }
 599 }
 600
 601 sub cleanup_bitmaps {
 602     my ($self) = @_;
 603     foreach my $drive (keys %{$self->{target_drive}}) {
 604         my $bitmap = $self->{target_drive}->{$drive}->{bitmap};
 605         next if !$bitmap;
 606         $self->log('info', "$drive: removing block-dirty-bitmap '$bitmap'");
 607         mon_cmd($self->{vmid}, 'block-dirty-bitmap-remove', node => "drive-$drive", name => $bitmap);
 608     }
 609 }
 610
 611 sub phase1 {
 612     my ($self, $vmid) = @_;
 613
 614     $self->log('info', "starting migration of VM $vmid to node '$self->{node}' ($self->{nodeip})");
 615
 616     my $conf = $self->{vmconf};
 617
 618     # set migrate lock in config file
 619     $conf->{lock} = 'migrate';
 620     PVE::QemuConfig->write_config($vmid, $conf);
 621
 622     sync_disks($self, $vmid);
 623
 624     # sync_disks fixes disk sizes to match their actual size, write changes so
 625     # target allocates correct volumes
 626     PVE::QemuConfig->write_config($vmid, $conf);
 627 };
 628
 629 sub phase1_cleanup {
 630     my ($self, $vmid, $err) = @_;
 631
 632     $self->log('info', "aborting phase 1 - cleanup resources");
 633
 634     my $conf = $self->{vmconf};
 635     delete $conf->{lock};
 636     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 637     if (my $err = $@) {
 638         $self->log('err', $err);
 639     }
 640
 641     if ($self->{volumes}) {
 642         foreach my $volid (@{$self->{volumes}}) {
 643             $self->log('err', "found stale volume copy '$volid' on node '$self->{node}'");
 644             # fixme: try to remove ?
 645         }
 646     }
 647
 648     eval { $self->cleanup_bitmaps() };
 649     if (my $err =$@) {
 650         $self->log('err', $err);
 651     }
 652
 653 }
 654
 655 sub phase2 {
 656     my ($self, $vmid) = @_;
 657
 658     my $conf = $self->{vmconf};
 659
 660     $self->log('info', "starting VM $vmid on remote node '$self->{node}'");
 661
 662     my $raddr;
 663     my $rport;
 664     my $ruri; # the whole migration dst. URI (protocol:address[:port])
 665     my $nodename = PVE::INotify::nodename();
 666
 667     ## start on remote node
 668     my $cmd = [@{$self->{rem_ssh}}];
 669
 670     my $spice_ticket;
 671     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 672         my $res = mon_cmd($vmid, 'query-spice');
 673         $spice_ticket = $res->{ticket};
 674     }
 675
 676     push @$cmd , 'qm', 'start', $vmid, '--skiplock', '--migratedfrom', $nodename;
 677
 678     my $migration_type = $self->{opts}->{migration_type};
 679
 680     push @$cmd, '--migration_type', $migration_type;
 681
 682     push @$cmd, '--migration_network', $self->{opts}->{migration_network}
 683       if $self->{opts}->{migration_network};
 684
 685     if ($migration_type eq 'insecure') {
 686         push @$cmd, '--stateuri', 'tcp';
 687     } else {
 688         push @$cmd, '--stateuri', 'unix';
 689     }
 690
 691     if ($self->{forcemachine}) {
 692         push @$cmd, '--machine', $self->{forcemachine};
 693     }
 694
 695     if ($self->{forcecpu}) {
 696         push @$cmd, '--force-cpu', $self->{forcecpu};
 697     }
 698
 699     if ($self->{online_local_volumes}) {
 700         push @$cmd, '--targetstorage', ($self->{opts}->{targetstorage} // '1');
 701     }
 702
 703     my $spice_port;
 704     my $tunnel_addr = [];
 705     my $sock_addr = [];
 706     # version > 0 for unix socket support
 707     my $nbd_protocol_version = 1;
 708     # TODO change to 'spice_ticket: <ticket>\n' in 7.0
 709     my $input = $spice_ticket ? "$spice_ticket\n" : "\n";
 710     $input .= "nbd_protocol_version: $nbd_protocol_version\n";
 711
 712     my $number_of_online_replicated_volumes = 0;
 713     foreach my $volid (@{$self->{online_local_volumes}}) {
 714         next if !$self->{replicated_volumes}->{$volid};
 715         $number_of_online_replicated_volumes++;
 716         $input .= "replicated_volume: $volid\n";
 717     }
 718
 719     my $target_replicated_volumes = {};
 720
 721     # Note: We try to keep $spice_ticket secret (do not pass via command line parameter)
 722     # instead we pipe it through STDIN
 723     my $exitcode = PVE::Tools::run_command($cmd, input => $input, outfunc => sub {
 724         my $line = shift;
 725
 726         if ($line =~ m/^migration listens on tcp:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+)$/) {
 727             $raddr = $1;
 728             $rport = int($2);
 729             $ruri = "tcp:$raddr:$rport";
 730         }
 731         elsif ($line =~ m!^migration listens on unix:(/run/qemu-server/(\d+)\.migrate)$!) {
 732             $raddr = $1;
 733             die "Destination UNIX sockets VMID does not match source VMID" if $vmid ne $2;
 734             $ruri = "unix:$raddr";
 735         }
 736         elsif ($line =~ m/^migration listens on port (\d+)$/) {
 737             $raddr = "localhost";
 738             $rport = int($1);
 739             $ruri = "tcp:$raddr:$rport";
 740         }
 741         elsif ($line =~ m/^spice listens on port (\d+)$/) {
 742             $spice_port = int($1);
 743         }
 744         elsif ($line =~ m/^storage migration listens on nbd:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+):exportname=(\S+) volume:(\S+)$/) {
 745             my $drivestr = $4;
 746             my $nbd_uri = "nbd:$1:$2:exportname=$3";
 747             my $targetdrive = $3;
 748             $targetdrive =~ s/drive-//g;
 749
 750             $self->{target_drive}->{$targetdrive}->{drivestr} = $drivestr;
 751             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 752         } elsif ($line =~ m!^storage migration listens on nbd:unix:(/run/qemu-server/(\d+)_nbd\.migrate):exportname=(\S+) volume:(\S+)$!) {
 753             my $drivestr = $4;
 754             die "Destination UNIX socket's VMID does not match source VMID" if $vmid ne $2;
 755             my $nbd_unix_addr = $1;
 756             my $nbd_uri = "nbd:unix:$nbd_unix_addr:exportname=$3";
 757             my $targetdrive = $3;
 758             $targetdrive =~ s/drive-//g;
 759
 760             $self->{target_drive}->{$targetdrive}->{drivestr} = $drivestr;
 761             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 762             push @$tunnel_addr, "$nbd_unix_addr:$nbd_unix_addr";
 763             push @$sock_addr, $nbd_unix_addr;
 764         } elsif ($line =~ m/^re-using replicated volume: (\S+) - (.*)$/) {
 765             my $drive = $1;
 766             my $volid = $2;
 767             $target_replicated_volumes->{$volid} = $drive;
 768         } elsif ($line =~ m/^QEMU: (.*)$/) {
 769             $self->log('info', "[$self->{node}] $1\n");
 770         }
 771     }, errfunc => sub {
 772         my $line = shift;
 773         $self->log('info', "[$self->{node}] $line");
 774     }, noerr => 1);
 775
 776     die "remote command failed with exit code $exitcode\n" if $exitcode;
 777
 778     die "unable to detect remote migration address\n" if !$raddr;
 779
 780     if (scalar(keys %$target_replicated_volumes) != $number_of_online_replicated_volumes) {
 781         die "number of replicated disks on source and target node do not match - target node too old?\n"
 782     }
 783
 784     $self->log('info', "start remote tunnel");
 785
 786     if ($migration_type eq 'secure') {
 787
 788         if ($ruri =~ /^unix:/) {
 789             unlink $raddr;
 790             push @$tunnel_addr, "$raddr:$raddr";
 791             $self->{tunnel} = $self->fork_tunnel($tunnel_addr);
 792             push @$sock_addr, $raddr;
 793
 794             my $unix_socket_try = 0; # wait for the socket to become ready
 795             while ($unix_socket_try <= 100) {
 796                 $unix_socket_try++;
 797                 my $available = 0;
 798                 foreach my $sock (@$sock_addr) {
 799                     if (-S $sock) {
 800                         $available++;
 801                     }
 802                 }
 803
 804                 if ($available == @$sock_addr) {
 805                     last;
 806                 }
 807
 808                 usleep(50000);
 809             }
 810             if ($unix_socket_try > 100) {
 811                 $self->{errors} = 1;
 812                 $self->finish_tunnel($self->{tunnel});
 813                 die "Timeout, migration socket $ruri did not get ready";
 814             }
 815
 816         } elsif ($ruri =~ /^tcp:/) {
 817             my $tunnel_addr;
 818             if ($raddr eq "localhost") {
 819                 # for backwards compatibility with older qemu-server versions
 820                 my $pfamily = PVE::Tools::get_host_address_family($nodename);
 821                 my $lport = PVE::Tools::next_migrate_port($pfamily);
 822                 $tunnel_addr = "$lport:localhost:$rport";
 823             }
 824
 825             $self->{tunnel} = $self->fork_tunnel($tunnel_addr);
 826
 827         } else {
 828             die "unsupported protocol in migration URI: $ruri\n";
 829         }
 830     } else {
 831         #fork tunnel for insecure migration, to send faster commands like resume
 832         $self->{tunnel} = $self->fork_tunnel();
 833     }
 834     $self->{tunnel}->{sock_addr} = $sock_addr if (@$sock_addr);
 835
 836     my $start = time();
 837
 838     my $opt_bwlimit = $self->{opts}->{bwlimit};
 839
 840     if (defined($self->{online_local_volumes})) {
 841         $self->{storage_migration} = 1;
 842         $self->{storage_migration_jobs} = {};
 843         $self->log('info', "starting storage migration");
 844
 845         die "The number of local disks does not match between the source and the destination.\n"
 846             if (scalar(keys %{$self->{target_drive}}) != scalar @{$self->{online_local_volumes}});
 847         foreach my $drive (keys %{$self->{target_drive}}){
 848             my $target = $self->{target_drive}->{$drive};
 849             my $nbd_uri = $target->{nbd_uri};
 850
 851             my $source_drive = PVE::QemuServer::parse_drive($drive, $conf->{$drive});
 852             my $target_drive = PVE::QemuServer::parse_drive($drive, $target->{drivestr});
 853
 854             my $source_volid = $source_drive->{file};
 855             my $target_volid = $target_drive->{file};
 856
 857             my $source_sid = PVE::Storage::Plugin::parse_volume_id($source_volid);
 858             my $target_sid = PVE::Storage::Plugin::parse_volume_id($target_volid);
 859
 860             my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', [$source_sid, $target_sid], $opt_bwlimit);
 861             my $bitmap = $target->{bitmap};
 862
 863             $self->log('info', "$drive: start migration to $nbd_uri");
 864             PVE::QemuServer::qemu_drive_mirror($vmid, $drive, $nbd_uri, $vmid, undef, $self->{storage_migration_jobs}, 'skip', undef, $bwlimit, $bitmap);
 865
 866             $self->{volume_map}->{$source_volid} = $target_volid;
 867             $self->log('info', "volume '$source_volid' is '$target_volid' on the target\n");
 868         }
 869     }
 870
 871     $self->log('info', "starting online/live migration on $ruri");
 872     $self->{livemigration} = 1;
 873
 874     # load_defaults
 875     my $defaults = PVE::QemuServer::load_defaults();
 876
 877     $self->log('info', "set migration_caps");
 878     eval {
 879         PVE::QemuServer::set_migration_caps($vmid);
 880     };
 881     warn $@ if $@;
 882
 883     my $qemu_migrate_params = {};
 884
 885     # migrate speed can be set via bwlimit (datacenter.cfg and API) and via the
 886     # migrate_speed parameter in qm.conf - take the lower of the two.
 887     my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', undef, $opt_bwlimit) // 0;
 888     my $migrate_speed = $conf->{migrate_speed} // $bwlimit;
 889     # migrate_speed is in MB/s, bwlimit in KB/s
 890     $migrate_speed *= 1024;
 891
 892     $migrate_speed = ($bwlimit < $migrate_speed) ? $bwlimit : $migrate_speed;
 893
 894     # always set migrate speed (overwrite kvm default of 32m) we set a very high
 895     # default of 8192m which is basically unlimited
 896     $migrate_speed ||= ($defaults->{migrate_speed} || 8192) * 1024;
 897
 898     # qmp takes migrate_speed in B/s.
 899     $migrate_speed *= 1024;
 900     $self->log('info', "migration speed limit: $migrate_speed B/s");
 901     $qemu_migrate_params->{'max-bandwidth'} = int($migrate_speed);
 902
 903     my $migrate_downtime = $defaults->{migrate_downtime};
 904     $migrate_downtime = $conf->{migrate_downtime} if defined($conf->{migrate_downtime});
 905     # migrate-set-parameters expects limit in ms
 906     $migrate_downtime *= 1000;
 907     $self->log('info', "migration downtime limit: $migrate_downtime ms");
 908     $qemu_migrate_params->{'downtime-limit'} = int($migrate_downtime);
 909
 910     # set cachesize to 10% of the total memory
 911     my $memory =  $conf->{memory} || $defaults->{memory};
 912     my $cachesize = int($memory * 1048576 / 10);
 913     $cachesize = round_powerof2($cachesize);
 914
 915     $self->log('info', "migration cachesize: $cachesize B");
 916     $qemu_migrate_params->{'xbzrle-cache-size'} = int($cachesize);
 917
 918     $self->log('info', "set migration parameters");
 919     eval {
 920         mon_cmd($vmid, "migrate-set-parameters", %{$qemu_migrate_params});
 921     };
 922     $self->log('info', "migrate-set-parameters error: $@") if $@;
 923
 924     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 925         my $rpcenv = PVE::RPCEnvironment::get();
 926         my $authuser = $rpcenv->get_user();
 927
 928         my (undef, $proxyticket) = PVE::AccessControl::assemble_spice_ticket($authuser, $vmid, $self->{node});
 929
 930         my $filename = "/etc/pve/nodes/$self->{node}/pve-ssl.pem";
 931         my $subject =  PVE::AccessControl::read_x509_subject_spice($filename);
 932
 933         $self->log('info', "spice client_migrate_info");
 934
 935         eval {
 936             mon_cmd($vmid, "client_migrate_info", protocol => 'spice',
 937                                                 hostname => $proxyticket, 'port' => 0, 'tls-port' => $spice_port,
 938                                                 'cert-subject' => $subject);
 939         };
 940         $self->log('info', "client_migrate_info error: $@") if $@;
 941
 942     }
 943
 944     $self->log('info', "start migrate command to $ruri");
 945     eval {
 946         mon_cmd($vmid, "migrate", uri => $ruri);
 947     };
 948     my $merr = $@;
 949     $self->log('info', "migrate uri => $ruri failed: $merr") if $merr;
 950
 951     my $lstat = 0;
 952     my $usleep = 1000000;
 953     my $i = 0;
 954     my $err_count = 0;
 955     my $lastrem = undef;
 956     my $downtimecounter = 0;
 957     while (1) {
 958         $i++;
 959         my $avglstat = $lstat/$i if $lstat;
 960
 961         usleep($usleep);
 962         my $stat;
 963         eval {
 964             $stat = mon_cmd($vmid, "query-migrate");
 965         };
 966         if (my $err = $@) {
 967             $err_count++;
 968             warn "query migrate failed: $err\n";
 969             $self->log('info', "query migrate failed: $err");
 970             if ($err_count <= 5) {
 971                 usleep(1000000);
 972                 next;
 973             }
 974             die "too many query migrate failures - aborting\n";
 975         }
 976
 977         if (defined($stat->{status}) && $stat->{status} =~ m/^(setup)$/im) {
 978             sleep(1);
 979             next;
 980         }
 981
 982         if (defined($stat->{status}) && $stat->{status} =~ m/^(active|completed|failed|cancelled)$/im) {
 983             $merr = undef;
 984             $err_count = 0;
 985             if ($stat->{status} eq 'completed') {
 986                 my $delay = time() - $start;
 987                 if ($delay > 0) {
 988                     my $mbps = sprintf "%.2f", $memory / $delay;
 989                     my $downtime = $stat->{downtime} || 0;
 990                     $self->log('info', "migration speed: $mbps MB/s - downtime $downtime ms");
 991                 }
 992             }
 993
 994             if ($stat->{status} eq 'failed' || $stat->{status} eq 'cancelled') {
 995                 $self->log('info', "migration status error: $stat->{status}");
 996                 die "aborting\n"
 997             }
 998
 999             if ($stat->{status} ne 'active') {
1000                 $self->log('info', "migration status: $stat->{status}");
1001                 last;
1002             }
1003
1004             if ($stat->{ram}->{transferred} ne $lstat) {
1005                 my $trans = $stat->{ram}->{transferred} || 0;
1006                 my $rem = $stat->{ram}->{remaining} || 0;
1007                 my $total = $stat->{ram}->{total} || 0;
1008                 my $xbzrlecachesize = $stat->{"xbzrle-cache"}->{"cache-size"} || 0;
1009                 my $xbzrlebytes = $stat->{"xbzrle-cache"}->{"bytes"} || 0;
1010                 my $xbzrlepages = $stat->{"xbzrle-cache"}->{"pages"} || 0;
1011                 my $xbzrlecachemiss = $stat->{"xbzrle-cache"}->{"cache-miss"} || 0;
1012                 my $xbzrleoverflow = $stat->{"xbzrle-cache"}->{"overflow"} || 0;
1013                 # reduce sleep if remainig memory is lower than the average transfer speed
1014                 $usleep = 100000 if $avglstat && $rem < $avglstat;
1015
1016                 $self->log('info', "migration status: $stat->{status} (transferred ${trans}, " .
1017                            "remaining ${rem}), total ${total})");
1018
1019                 if (${xbzrlecachesize}) {
1020                     $self->log('info', "migration xbzrle cachesize: ${xbzrlecachesize} transferred ${xbzrlebytes} pages ${xbzrlepages} cachemiss ${xbzrlecachemiss} overflow ${xbzrleoverflow}");
1021                 }
1022
1023                 if (($lastrem  && $rem > $lastrem ) || ($rem == 0)) {
1024                     $downtimecounter++;
1025                 }
1026                 $lastrem = $rem;
1027
1028                 if ($downtimecounter > 5) {
1029                     $downtimecounter = 0;
1030                     $migrate_downtime *= 2;
1031                     $self->log('info', "auto-increased downtime to continue migration: $migrate_downtime ms");
1032                     eval {
1033                         # migrate-set-parameters does not touch values not
1034                         # specified, so this only changes downtime-limit
1035                         mon_cmd($vmid, "migrate-set-parameters", 'downtime-limit' => int($migrate_downtime));
1036                     };
1037                     $self->log('info', "migrate-set-parameters error: $@") if $@;
1038                 }
1039
1040             }
1041
1042
1043             $lstat = $stat->{ram}->{transferred};
1044
1045         } else {
1046             die $merr if $merr;
1047             die "unable to parse migration status '$stat->{status}' - aborting\n";
1048         }
1049     }
1050 }
1051
1052 sub phase2_cleanup {
1053     my ($self, $vmid, $err) = @_;
1054
1055     return if !$self->{errors};
1056     $self->{phase2errors} = 1;
1057
1058     $self->log('info', "aborting phase 2 - cleanup resources");
1059
1060     $self->log('info', "migrate_cancel");
1061     eval {
1062         mon_cmd($vmid, "migrate_cancel");
1063     };
1064     $self->log('info', "migrate_cancel error: $@") if $@;
1065
1066     my $conf = $self->{vmconf};
1067     delete $conf->{lock};
1068     eval { PVE::QemuConfig->write_config($vmid, $conf) };
1069     if (my $err = $@) {
1070         $self->log('err', $err);
1071     }
1072
1073     # cleanup ressources on target host
1074     if ($self->{storage_migration}) {
1075         eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
1076         if (my $err = $@) {
1077             $self->log('err', $err);
1078         }
1079     }
1080
1081     eval { $self->cleanup_bitmaps() };
1082     if (my $err =$@) {
1083         $self->log('err', $err);
1084     }
1085
1086     my $nodename = PVE::INotify::nodename();
1087
1088     my $cmd = [@{$self->{rem_ssh}}, 'qm', 'stop', $vmid, '--skiplock', '--migratedfrom', $nodename];
1089     eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1090     if (my $err = $@) {
1091         $self->log('err', $err);
1092         $self->{errors} = 1;
1093     }
1094
1095     # cleanup after stopping, otherwise disks might be in-use by target VM!
1096     eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
1097     if (my $err = $@) {
1098         $self->log('err', $err);
1099     }
1100
1101
1102     if ($self->{tunnel}) {
1103         eval { finish_tunnel($self, $self->{tunnel});  };
1104         if (my $err = $@) {
1105             $self->log('err', $err);
1106             $self->{errors} = 1;
1107         }
1108     }
1109 }
1110
1111 sub phase3 {
1112     my ($self, $vmid) = @_;
1113
1114     my $volids = $self->{volumes};
1115     return if $self->{phase2errors};
1116
1117     # destroy local copies
1118     foreach my $volid (@$volids) {
1119         eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
1120         if (my $err = $@) {
1121             $self->log('err', "removing local copy of '$volid' failed - $err");
1122             $self->{errors} = 1;
1123             last if $err =~ /^interrupted by signal$/;
1124         }
1125     }
1126 }
1127
1128 sub phase3_cleanup {
1129     my ($self, $vmid, $err) = @_;
1130
1131     my $conf = $self->{vmconf};
1132     return if $self->{phase2errors};
1133
1134     my $tunnel = $self->{tunnel};
1135
1136     if ($self->{storage_migration}) {
1137         # finish block-job with block-job-cancel, to disconnect source VM from NBD
1138         # to avoid it trying to re-establish it. We are in blockjob ready state,
1139         # thus, this command changes to it to blockjob complete (see qapi docs)
1140         eval { PVE::QemuServer::qemu_drive_mirror_monitor($vmid, undef, $self->{storage_migration_jobs}, 'cancel'); };
1141
1142         if (my $err = $@) {
1143             eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
1144             eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
1145             die "Failed to complete storage migration: $err\n";
1146         }
1147     }
1148
1149     if ($self->{volume_map}) {
1150         my $target_drives = $self->{target_drive};
1151
1152         # FIXME: for NBD storage migration we now only update the volid, and
1153         # not the full drivestr from the target node. Workaround that until we
1154         # got some real rescan, to avoid things like wrong format in the drive
1155         delete $conf->{$_} for keys %$target_drives;
1156         PVE::QemuConfig->update_volume_ids($conf, $self->{volume_map});
1157
1158         for my $drive (keys %$target_drives) {
1159             $conf->{$drive} = $target_drives->{$drive}->{drivestr};
1160         }
1161         PVE::QemuConfig->write_config($vmid, $conf);
1162     }
1163
1164     # transfer replication state before move config
1165     $self->transfer_replication_state() if $self->{replicated_volumes};
1166
1167     # move config to remote node
1168     my $conffile = PVE::QemuConfig->config_file($vmid);
1169     my $newconffile = PVE::QemuConfig->config_file($vmid, $self->{node});
1170
1171     die "Failed to move config to node '$self->{node}' - rename failed: $!\n"
1172         if !rename($conffile, $newconffile);
1173
1174     $self->switch_replication_job_target() if $self->{replicated_volumes};
1175
1176     if ($self->{livemigration}) {
1177         if ($self->{storage_migration}) {
1178             # stop nbd server on remote vm - requirement for resume since 2.9
1179             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'nbdstop', $vmid];
1180
1181             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1182             if (my $err = $@) {
1183                 $self->log('err', $err);
1184                 $self->{errors} = 1;
1185             }
1186         }
1187
1188         # config moved and nbd server stopped - now we can resume vm on target
1189         if ($tunnel && $tunnel->{version} && $tunnel->{version} >= 1) {
1190             eval {
1191                 $self->write_tunnel($tunnel, 30, "resume $vmid");
1192             };
1193             if (my $err = $@) {
1194                 $self->log('err', $err);
1195                 $self->{errors} = 1;
1196             }
1197         } else {
1198             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'resume', $vmid, '--skiplock', '--nocheck'];
1199             my $logf = sub {
1200                 my $line = shift;
1201                 $self->log('err', $line);
1202             };
1203             eval { PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => $logf); };
1204             if (my $err = $@) {
1205                 $self->log('err', $err);
1206                 $self->{errors} = 1;
1207             }
1208         }
1209
1210         if ($self->{storage_migration} && PVE::QemuServer::parse_guest_agent($conf)->{fstrim_cloned_disks} && $self->{running}) {
1211             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'guest', 'cmd', $vmid, 'fstrim'];
1212             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1213         }
1214     }
1215
1216     # close tunnel on successful migration, on error phase2_cleanup closed it
1217     if ($tunnel) {
1218         eval { finish_tunnel($self, $tunnel);  };
1219         if (my $err = $@) {
1220             $self->log('err', $err);
1221             $self->{errors} = 1;
1222         }
1223     }
1224
1225     eval {
1226         my $timer = 0;
1227         if (PVE::QemuServer::vga_conf_has_spice($conf->{vga}) && $self->{running}) {
1228             $self->log('info', "Waiting for spice server migration");
1229             while (1) {
1230                 my $res = mon_cmd($vmid, 'query-spice');
1231                 last if int($res->{'migrated'}) == 1;
1232                 last if $timer > 50;
1233                 $timer ++;
1234                 usleep(200000);
1235             }
1236         }
1237     };
1238
1239     # always stop local VM
1240     eval { PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1, 1); };
1241     if (my $err = $@) {
1242         $self->log('err', "stopping vm failed - $err");
1243         $self->{errors} = 1;
1244     }
1245
1246     # always deactivate volumes - avoid lvm LVs to be active on several nodes
1247     eval {
1248         my $vollist = PVE::QemuServer::get_vm_volumes($conf);
1249         PVE::Storage::deactivate_volumes($self->{storecfg}, $vollist);
1250     };
1251     if (my $err = $@) {
1252         $self->log('err', $err);
1253         $self->{errors} = 1;
1254     }
1255
1256     if($self->{storage_migration}) {
1257         # destroy local copies
1258         my $volids = $self->{online_local_volumes};
1259
1260         foreach my $volid (@$volids) {
1261             # keep replicated volumes!
1262             next if $self->{replicated_volumes}->{$volid};
1263
1264             eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
1265             if (my $err = $@) {
1266                 $self->log('err', "removing local copy of '$volid' failed - $err");
1267                 $self->{errors} = 1;
1268                 last if $err =~ /^interrupted by signal$/;
1269             }
1270         }
1271
1272     }
1273
1274     # clear migrate lock
1275     my $cmd = [ @{$self->{rem_ssh}}, 'qm', 'unlock', $vmid ];
1276     $self->cmd_logerr($cmd, errmsg => "failed to clear migrate lock");
1277 }
1278
1279 sub final_cleanup {
1280     my ($self, $vmid) = @_;
1281
1282     # nothing to do
1283 }
1284
1285 sub round_powerof2 {
1286     return 1 if $_[0] < 2;
1287     return 2 << int(log($_[0]-1)/log(2));
1288 }
1289
1290 1;