PVE/QemuServer/ImportDisk.pm

   1 package PVE::QemuServer::ImportDisk;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::Storage;
   7 use PVE::QemuServer;
   8 use PVE::Tools qw(run_command extract_param);
   9
  10 # imports an external disk image to an existing VM
  11 # and creates by default a drive entry unused[n] pointing to the created volume
  12 # $params->{drive_name} may be used to specify ide0, scsi1, etc ...
  13 # $params->{format} may be used to specify qcow2, raw, etc ...
  14 # $params->{skiplock} may be used to skip checking for a lock in the VM config
  15 # $params->{'skip-config-update'} may be used to import the disk without updating the VM config
  16 sub do_import {
  17     my ($src_path, $vmid, $storage_id, $params) = @_;
  18
  19     my $drive_name = extract_param($params, 'drive_name');
  20     my $format = extract_param($params, 'format');
  21     if ($drive_name && !(PVE::QemuServer::is_valid_drivename($drive_name))) {
  22         die "invalid drive name: $drive_name\n";
  23     }
  24
  25     # get the needed size from  source disk
  26     my $src_size = PVE::Storage::file_size_info($src_path);
  27
  28     # get target format, target image's path, and whether it's possible to sparseinit
  29     my $storecfg = PVE::Storage::config();
  30     my $dst_format = PVE::QemuServer::resolve_dst_disk_format($storecfg, $storage_id, undef, $format);
  31     warn "format '$format' is not supported by the target storage - using '$dst_format' instead\n"
  32         if $format && $format ne $dst_format;
  33
  34     my $dst_volid = PVE::Storage::vdisk_alloc($storecfg, $storage_id, $vmid, $dst_format, undef, $src_size / 1024);
  35
  36     my $zeroinit = PVE::Storage::volume_has_feature($storecfg, 'sparseinit', $dst_volid);
  37
  38     my $create_drive = sub {
  39         my $vm_conf = PVE::QemuConfig->load_config($vmid);
  40         if (!$params->{skiplock}) {
  41             PVE::QemuConfig->check_lock($vm_conf);
  42         }
  43
  44         if ($drive_name) {
  45             # should never happen as setting $drive_name is not exposed to public interface
  46             die "cowardly refusing to overwrite existing entry: $drive_name\n" if $vm_conf->{$drive_name};
  47
  48             my $modified = {}; # record what $option we modify
  49             $modified->{$drive_name} = 1;
  50             $vm_conf->{pending}->{$drive_name} = $dst_volid;
  51             PVE::QemuConfig->write_config($vmid, $vm_conf);
  52
  53             my $running = PVE::QemuServer::check_running($vmid);
  54             if ($running) {
  55                 my $errors = {};
  56                 PVE::QemuServer::vmconfig_hotplug_pending($vmid, $vm_conf, $storecfg, $modified, $errors);
  57                 warn "hotplugging imported disk '$_' failed: $errors->{$_}\n" for keys %$errors;
  58             } else {
  59                 PVE::QemuServer::vmconfig_apply_pending($vmid, $vm_conf, $storecfg);
  60             }
  61         } else {
  62             $drive_name = PVE::QemuConfig->add_unused_volume($vm_conf, $dst_volid);
  63             PVE::QemuConfig->write_config($vmid, $vm_conf);
  64         }
  65     };
  66
  67     eval {
  68         # trap interrupts so we have a chance to clean up
  69         local $SIG{INT} =
  70             local $SIG{TERM} =
  71             local $SIG{QUIT} =
  72             local $SIG{HUP} =
  73             local $SIG{PIPE} = sub { die "interrupted by signal $!\n"; };
  74
  75         PVE::Storage::activate_volumes($storecfg, [$dst_volid]);
  76         PVE::QemuServer::qemu_img_convert($src_path, $dst_volid, $src_size, undef, $zeroinit);
  77         PVE::Storage::deactivate_volumes($storecfg, [$dst_volid]);
  78         PVE::QemuConfig->lock_config($vmid, $create_drive) if !$params->{'skip-config-update'};
  79     };
  80     if (my $err = $@) {
  81         eval { PVE::Storage::vdisk_free($storecfg, $dst_volid) };
  82         warn "cleanup of $dst_volid failed: $@\n" if $@;
  83         die $err;
  84     }
  85
  86     return ($drive_name, $dst_volid);
  87 }
  88
  89 1;