PVE/VZDump/QemuServer.pm

   1 package PVE::VZDump::QemuServer;
   2
   3 use strict;
   4 use warnings;
   5
   6 use File::Basename;
   7 use File::Path;
   8 use IO::File;
   9 use IPC::Open3;
  10 use JSON;
  11 use POSIX qw(EINTR EAGAIN);
  12
  13 use PVE::Cluster qw(cfs_read_file);
  14 use PVE::INotify;
  15 use PVE::IPCC;
  16 use PVE::JSONSchema;
  17 use PVE::PBSClient;
  18 use PVE::QMPClient;
  19 use PVE::Storage::Plugin;
  20 use PVE::Storage::PBSPlugin;
  21 use PVE::Storage;
  22 use PVE::Tools;
  23 use PVE::VZDump;
  24 use PVE::Format qw(render_duration render_bytes);
  25
  26 use PVE::QemuConfig;
  27 use PVE::QemuServer;
  28 use PVE::QemuServer::Machine;
  29 use PVE::QemuServer::Monitor qw(mon_cmd);
  30
  31 use base qw (PVE::VZDump::Plugin);
  32
  33 sub new {
  34     my ($class, $vzdump) = @_;
  35
  36     PVE::VZDump::check_bin('qm');
  37
  38     my $self = bless { vzdump => $vzdump }, $class;
  39
  40     $self->{vmlist} = PVE::QemuServer::vzlist();
  41     $self->{storecfg} = PVE::Storage::config();
  42
  43     return $self;
  44 };
  45
  46 sub type {
  47     return 'qemu';
  48 }
  49
  50 sub vmlist {
  51     my ($self) = @_;
  52     return [ keys %{$self->{vmlist}} ];
  53 }
  54
  55 sub prepare {
  56     my ($self, $task, $vmid, $mode) = @_;
  57
  58     $task->{disks} = [];
  59
  60     my $conf = $self->{vmlist}->{$vmid} = PVE::QemuConfig->load_config($vmid);
  61
  62     $self->loginfo("VM Name: $conf->{name}")
  63         if defined($conf->{name});
  64
  65     $self->{vm_was_running} = 1;
  66     $self->{vm_was_paused} = 0;
  67     if (!PVE::QemuServer::check_running($vmid)) {
  68         $self->{vm_was_running} = 0;
  69     } elsif (PVE::QemuServer::vm_is_paused($vmid)) {
  70         $self->{vm_was_paused} = 1;
  71     }
  72
  73     $task->{hostname} = $conf->{name};
  74
  75     my $hostname = PVE::INotify::nodename();
  76
  77     my $vollist = [];
  78     my $drivehash = {};
  79     my $backup_volumes = PVE::QemuConfig->get_backup_volumes($conf);
  80
  81     foreach my $volume (@{$backup_volumes}) {
  82         my $name = $volume->{key};
  83         my $volume_config = $volume->{volume_config};
  84         my $volid = $volume_config->{file};
  85
  86         if (!$volume->{included}) {
  87             $self->loginfo("exclude disk '$name' '$volid' ($volume->{reason})");
  88             next;
  89         } elsif ($self->{vm_was_running} && $volume_config->{iothread}) {
  90             if (!PVE::QemuServer::Machine::runs_at_least_qemu_version($vmid, 4, 0, 1)) {
  91                 die "disk '$name' '$volid' (iothread=on) can't use backup feature with running QEMU " .
  92                     "version < 4.0.1! Either set backup=no for this drive or upgrade QEMU and restart VM\n";
  93             }
  94         } else {
  95             my $log = "include disk '$name' '$volid'";
  96             if (defined(my $size = $volume_config->{size})) {
  97                 my $readable_size = PVE::JSONSchema::format_size($size);
  98                 $log .= " $readable_size";
  99             }
 100             $self->loginfo($log);
 101         }
 102
 103         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 104         push @$vollist, $volid if $storeid;
 105         $drivehash->{$name} = $volume->{volume_config};
 106     }
 107
 108     PVE::Storage::activate_volumes($self->{storecfg}, $vollist);
 109
 110     foreach my $ds (sort keys %$drivehash) {
 111         my $drive = $drivehash->{$ds};
 112
 113         my $volid = $drive->{file};
 114         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 115
 116         my $path = $volid;
 117         if ($storeid) {
 118             $path = PVE::Storage::path($self->{storecfg}, $volid);
 119         }
 120         next if !$path;
 121
 122         my ($size, $format) = eval { PVE::Storage::volume_size_info($self->{storecfg}, $volid, 5) };
 123         die "no such volume '$volid'\n" if $@;
 124
 125         my $diskinfo = {
 126             path => $path,
 127             volid => $volid,
 128             storeid => $storeid,
 129             format => $format,
 130             virtdev => $ds,
 131             qmdevice => "drive-$ds",
 132         };
 133
 134         if (-b $path) {
 135             $diskinfo->{type} = 'block';
 136         } else {
 137             $diskinfo->{type} = 'file';
 138         }
 139
 140         push @{$task->{disks}}, $diskinfo;
 141     }
 142 }
 143
 144 sub vm_status {
 145     my ($self, $vmid) = @_;
 146
 147     my $running = PVE::QemuServer::check_running($vmid) ? 1 : 0;
 148
 149     return wantarray ? ($running, $running ? 'running' : 'stopped') : $running;
 150 }
 151
 152 sub lock_vm {
 153     my ($self, $vmid) = @_;
 154
 155     PVE::QemuConfig->set_lock($vmid, 'backup');
 156 }
 157
 158 sub unlock_vm {
 159     my ($self, $vmid) = @_;
 160
 161     PVE::QemuConfig->remove_lock($vmid, 'backup');
 162 }
 163
 164 sub stop_vm {
 165     my ($self, $task, $vmid) = @_;
 166
 167     my $opts = $self->{vzdump}->{opts};
 168
 169     my $wait = $opts->{stopwait} * 60;
 170     # send shutdown and wait
 171     $self->cmd ("qm shutdown $vmid --skiplock --keepActive --timeout $wait");
 172 }
 173
 174 sub start_vm {
 175     my ($self, $task, $vmid) = @_;
 176
 177     $self->cmd ("qm start $vmid --skiplock");
 178 }
 179
 180 sub suspend_vm {
 181     my ($self, $task, $vmid) = @_;
 182
 183     return if $self->{vm_was_paused};
 184
 185     $self->cmd ("qm suspend $vmid --skiplock");
 186 }
 187
 188 sub resume_vm {
 189     my ($self, $task, $vmid) = @_;
 190
 191     return if $self->{vm_was_paused};
 192
 193     $self->cmd ("qm resume $vmid --skiplock");
 194 }
 195
 196 sub assemble {
 197     my ($self, $task, $vmid) = @_;
 198
 199     my $conffile = PVE::QemuConfig->config_file($vmid);
 200
 201     my $outfile = "$task->{tmpdir}/qemu-server.conf";
 202     my $firewall_src = "/etc/pve/firewall/$vmid.fw";
 203     my $firewall_dest = "$task->{tmpdir}/qemu-server.fw";
 204
 205     my $outfd = IO::File->new (">$outfile") ||
 206         die "unable to open '$outfile'";
 207     my $conffd = IO::File->new ($conffile, 'r') ||
 208         die "unable open '$conffile'";
 209
 210     my $found_snapshot;
 211     my $found_pending;
 212     while (defined (my $line = <$conffd>)) {
 213         next if $line =~ m/^\#vzdump\#/; # just to be sure
 214         next if $line =~ m/^\#qmdump\#/; # just to be sure
 215         if ($line =~ m/^\[(.*)\]\s*$/) {
 216             if ($1 =~ m/PENDING/i) {
 217                 $found_pending = 1;
 218             } else {
 219                 $found_snapshot = 1;
 220             }
 221         }
 222         next if $found_snapshot || $found_pending; # skip all snapshots and pending changes config data
 223
 224         if ($line =~ m/^unused\d+:\s*(\S+)\s*/) {
 225             $self->loginfo("skip unused drive '$1' (not included into backup)");
 226             next;
 227         }
 228         next if $line =~ m/^lock:/ || $line =~ m/^parent:/;
 229
 230         print $outfd $line;
 231     }
 232
 233     foreach my $di (@{$task->{disks}}) {
 234         if ($di->{type} eq 'block' || $di->{type} eq 'file') {
 235             my $storeid = $di->{storeid} || '';
 236             my $format = $di->{format} || '';
 237             print $outfd "#qmdump#map:$di->{virtdev}:$di->{qmdevice}:$storeid:$format:\n";
 238         } else {
 239             die "internal error";
 240         }
 241     }
 242
 243     if ($found_snapshot) {
 244         $self->loginfo("snapshots found (not included into backup)");
 245     }
 246     if ($found_pending) {
 247         $self->loginfo("pending configuration changes found (not included into backup)");
 248     }
 249
 250     PVE::Tools::file_copy($firewall_src, $firewall_dest) if -f $firewall_src;
 251 }
 252
 253 sub archive {
 254     my ($self, $task, $vmid, $filename, $comp) = @_;
 255
 256     my $opts = $self->{vzdump}->{opts};
 257     my $scfg = $opts->{scfg};
 258
 259     if ($self->{vzdump}->{opts}->{pbs}) {
 260         $self->archive_pbs($task, $vmid);
 261     } else {
 262         $self->archive_vma($task, $vmid, $filename, $comp);
 263     }
 264 }
 265
 266 my $bitmap_action_to_human = sub {
 267     my ($self, $info) = @_;
 268
 269     my $action = $info->{action};
 270
 271     if ($action eq "not-used") {
 272         return "disabled (no support)";
 273     } elsif ($action eq "not-used-removed") {
 274         return "disabled (old bitmap cleared)";
 275     } elsif ($action eq "new") {
 276         return "created new";
 277     } elsif ($action eq "used") {
 278         if ($info->{dirty} == 0) {
 279             return "OK (drive clean)";
 280         } else {
 281             my $size = render_bytes($info->{size}, 1);
 282             my $dirty = render_bytes($info->{dirty}, 1);
 283             return "OK ($dirty of $size dirty)";
 284         }
 285     } elsif ($action eq "invalid") {
 286         return "existing bitmap was invalid and has been cleared";
 287     } else {
 288         return "unknown";
 289     }
 290 };
 291
 292 my $query_backup_status_loop = sub {
 293     my ($self, $vmid, $job_uuid, $qemu_support) = @_;
 294
 295     my $starttime = time ();
 296     my $last_time = $starttime;
 297     my ($last_percent, $last_total, $last_target, $last_zero, $last_transferred) = (-1, 0, 0, 0, 0);
 298     my ($transferred, $reused);
 299
 300     my $get_mbps = sub {
 301         my ($mb, $delta) = @_;
 302         return "0 B/s" if $mb <= 0;
 303         my $bw = int(($mb / $delta));
 304         return render_bytes($bw, 1) . "/s";
 305     };
 306
 307     my $target = 0;
 308     my $last_reused = 0;
 309     my $has_query_bitmap = $qemu_support && $qemu_support->{'query-bitmap-info'};
 310     my $is_template = PVE::QemuConfig->is_template($self->{vmlist}->{$vmid});
 311     if ($has_query_bitmap) {
 312         my $total = 0;
 313         my $bitmap_info = mon_cmd($vmid, 'query-pbs-bitmap-info');
 314         for my $info (sort { $a->{drive} cmp $b->{drive} } @$bitmap_info) {
 315             if (!$is_template) {
 316                 my $text = $bitmap_action_to_human->($self, $info);
 317                 my $drive = $info->{drive};
 318                 $drive =~ s/^drive-//; # for consistency
 319                 $self->loginfo("$drive: dirty-bitmap status: $text");
 320             }
 321             $target += $info->{dirty};
 322             $total += $info->{size};
 323             $last_reused += $info->{size} - $info->{dirty};
 324         }
 325         if ($target < $total) {
 326             my $total_h = render_bytes($total, 1);
 327             my $target_h = render_bytes($target, 1);
 328             $self->loginfo("using fast incremental mode (dirty-bitmap), $target_h dirty of $total_h total");
 329         }
 330     }
 331
 332     my $last_finishing = 0;
 333     while(1) {
 334         my $status = mon_cmd($vmid, 'query-backup');
 335
 336         my $total = $status->{total} || 0;
 337         my $dirty = $status->{dirty};
 338         $target = (defined($dirty) && $dirty < $total) ? $dirty : $total if !$has_query_bitmap;
 339         $transferred = $status->{transferred} || 0;
 340         $reused = $status->{reused};
 341         my $percent = $target ? int(($transferred * 100)/$target) : 100;
 342         my $zero = $status->{'zero-bytes'} || 0;
 343
 344         die "got unexpected uuid\n" if !$status->{uuid} || ($status->{uuid} ne $job_uuid);
 345
 346         my $ctime = time();
 347         my $duration = $ctime - $starttime;
 348
 349         my $rbytes = $transferred - $last_transferred;
 350         my $wbytes;
 351         if ($reused) {
 352             # reused includes zero bytes for PBS
 353             $wbytes = $rbytes - ($reused - $last_reused);
 354         } else {
 355             $wbytes = $rbytes - ($zero - $last_zero);
 356         }
 357
 358         my $timediff = ($ctime - $last_time) || 1; # fixme
 359         my $mbps_read = $get_mbps->($rbytes, $timediff);
 360         my $mbps_write = $get_mbps->($wbytes, $timediff);
 361         my $target_h = render_bytes($target, 1);
 362         my $transferred_h = render_bytes($transferred, 1);
 363
 364         my $statusline = sprintf("%3d%% ($transferred_h of $target_h) in %s"
 365             .", read: $mbps_read, write: $mbps_write", $percent, render_duration($duration));
 366
 367         my $res = $status->{status} || 'unknown';
 368         if ($res ne 'active') {
 369             if ($last_percent < 100) {
 370                 $self->loginfo($statusline);
 371             }
 372             if ($res ne 'done') {
 373                 die (($status->{errmsg} || "unknown error") . "\n") if $res eq 'error';
 374                 die "got unexpected status '$res'\n";
 375             }
 376             $last_target = $target if $target;
 377             $last_total = $total if $total;
 378             $last_zero = $zero if $zero;
 379             $last_transferred = $transferred if $transferred;
 380             last;
 381         }
 382         if ($percent != $last_percent && ($timediff > 2)) {
 383             $self->loginfo($statusline);
 384             $last_percent = $percent;
 385             $last_target = $target if $target;
 386             $last_total = $total if $total;
 387             $last_zero = $zero if $zero;
 388             $last_transferred = $transferred if $transferred;
 389             $last_time = $ctime;
 390             $last_reused = $reused;
 391
 392             if (!$last_finishing && $status->{finishing}) {
 393                 $self->loginfo("Waiting for server to finish backup validation...");
 394             }
 395             $last_finishing = $status->{finishing};
 396         }
 397         sleep(1);
 398     }
 399
 400     my $duration = time() - $starttime;
 401
 402     if ($last_zero) {
 403         my $zero_per = $last_target ? int(($last_zero * 100)/$last_target) : 0;
 404         my $zero_h = render_bytes($last_zero);
 405         $self->loginfo("backup is sparse: $zero_h (${zero_per}%) total zero data");
 406     }
 407     if ($reused) {
 408         my $reused_h = render_bytes($reused);
 409         my $reuse_per = int($reused * 100 / $last_total);
 410         $self->loginfo("backup was done incrementally, reused $reused_h (${reuse_per}%)");
 411     }
 412     if ($transferred) {
 413         my $transferred_h = render_bytes($transferred);
 414         if ($duration) {
 415             my $mbps = $get_mbps->($transferred, $duration);
 416             $self->loginfo("transferred $transferred_h in $duration seconds ($mbps)");
 417         } else {
 418             $self->loginfo("transferred $transferred_h in <1 seconds");
 419         }
 420     }
 421
 422     return {
 423         total => $last_total,
 424         reused => $reused,
 425     };
 426 };
 427
 428 sub archive_pbs {
 429     my ($self, $task, $vmid) = @_;
 430
 431     my $conffile = "$task->{tmpdir}/qemu-server.conf";
 432     my $firewall = "$task->{tmpdir}/qemu-server.fw";
 433
 434     my $opts = $self->{vzdump}->{opts};
 435     my $scfg = $opts->{scfg};
 436
 437     my $starttime = time();
 438
 439     my $fingerprint = $scfg->{fingerprint};
 440     my $repo = PVE::PBSClient::get_repository($scfg);
 441     my $password = PVE::Storage::PBSPlugin::pbs_get_password($scfg, $opts->{storage});
 442     my $keyfile = PVE::Storage::PBSPlugin::pbs_encryption_key_file_name($scfg, $opts->{storage});
 443     my $master_keyfile = PVE::Storage::PBSPlugin::pbs_master_pubkey_file_name($scfg, $opts->{storage});
 444
 445     my $diskcount = scalar(@{$task->{disks}});
 446     # proxmox-backup-client can only handle raw files and block devs
 447     # only use it (directly) for disk-less VMs
 448     if (!$diskcount) {
 449         my @pathlist;
 450         $self->loginfo("backup contains no disks");
 451
 452         local $ENV{PBS_PASSWORD} = $password;
 453         local $ENV{PBS_FINGERPRINT} = $fingerprint if defined($fingerprint);
 454         my $cmd = [
 455             '/usr/bin/proxmox-backup-client',
 456             'backup',
 457             '--repository', $repo,
 458             '--backup-type', 'vm',
 459             '--backup-id', "$vmid",
 460             '--backup-time', $task->{backup_time},
 461         ];
 462
 463         push @$cmd, "qemu-server.conf:$conffile";
 464         push @$cmd, "fw.conf:$firewall" if -e $firewall;
 465
 466         $self->loginfo("starting template backup");
 467         $self->loginfo(join(' ', @$cmd));
 468
 469         $self->cmd($cmd);
 470
 471         return;
 472     }
 473
 474     # get list early so we die on unkown drive types before doing anything
 475     my $devlist = _get_task_devlist($task);
 476
 477     $self->enforce_vm_running_for_backup($vmid);
 478     $self->{qmeventd_fh} = PVE::QemuServer::register_qmeventd_handle($vmid);
 479
 480     my $backup_job_uuid;
 481     eval {
 482         $SIG{INT} = $SIG{TERM} = $SIG{QUIT} = $SIG{HUP} = $SIG{PIPE} = sub {
 483             die "interrupted by signal\n";
 484         };
 485
 486         my $qemu_support = eval { mon_cmd($vmid, "query-proxmox-support") };
 487         my $err = $@;
 488         if (!$qemu_support || $err) {
 489             die "query-proxmox-support returned empty value\n" if !$err;
 490             if ($err =~ m/The command query-proxmox-support has not been found/) {
 491                 die "PBS backups are not supported by the running QEMU version. Please make "
 492                   . "sure you've installed the latest version and the VM has been restarted.\n";
 493             } else {
 494                 die "QMP command query-proxmox-support failed - $err\n";
 495             }
 496         }
 497
 498         if (!defined($qemu_support->{"pbs-masterkey"}) && -e $master_keyfile) {
 499             $self->loginfo("WARNING: backup target is configured with master key, but running QEMU version does not support master keys.");
 500             $self->loginfo("Please make sure you've installed the latest version and the VM has been restarted to use master key feature.");
 501             $master_keyfile = undef; # skip rest of master key handling below
 502         }
 503
 504         my $fs_frozen = $self->qga_fs_freeze($task, $vmid);
 505
 506         my $params = {
 507             format => "pbs",
 508             'backup-file' => $repo,
 509             'backup-id' => "$vmid",
 510             'backup-time' => $task->{backup_time},
 511             password => $password,
 512             devlist => $devlist,
 513             'config-file' => $conffile,
 514         };
 515         $params->{speed} = $opts->{bwlimit}*1024 if $opts->{bwlimit};
 516         $params->{fingerprint} = $fingerprint if defined($fingerprint);
 517         $params->{'firewall-file'} = $firewall if -e $firewall;
 518         if (-e $keyfile) {
 519             $self->loginfo("enabling encryption");
 520             $params->{keyfile} = $keyfile;
 521             $params->{encrypt} = JSON::true;
 522             if (defined($master_keyfile) && -e $master_keyfile) {
 523                 $self->loginfo("enabling master key feature");
 524                 $params->{"master-keyfile"} = $master_keyfile;
 525             }
 526         } else {
 527             $self->loginfo("WARNING: backup target is configured with master key, but this backup is not encrypted - master key settings will be ignored!")
 528                 if defined($master_keyfile) && -e $master_keyfile;
 529             $params->{encrypt} = JSON::false;
 530         }
 531
 532         my $is_template = PVE::QemuConfig->is_template($self->{vmlist}->{$vmid});
 533         $params->{'use-dirty-bitmap'} = JSON::true
 534             if $qemu_support->{'pbs-dirty-bitmap'} && !$is_template;
 535
 536         $params->{timeout} = 125; # give some time to connect to the backup server
 537
 538         my $res = eval { mon_cmd($vmid, "backup", %$params) };
 539         my $qmperr = $@;
 540         $backup_job_uuid = $res->{UUID} if $res;
 541
 542         if ($fs_frozen) {
 543             $self->qga_fs_thaw($vmid);
 544         }
 545
 546         die $qmperr if $qmperr;
 547         die "got no uuid for backup task\n" if !defined($backup_job_uuid);
 548
 549         $self->loginfo("started backup task '$backup_job_uuid'");
 550
 551         $self->resume_vm_after_job_start($task, $vmid);
 552
 553         my $stat = $query_backup_status_loop->($self, $vmid, $backup_job_uuid, $qemu_support);
 554         $task->{size} = $stat->{total};
 555     };
 556     my $err = $@;
 557     if ($err) {
 558         $self->logerr($err);
 559         $self->mon_backup_cancel($vmid);
 560         $self->resume_vm_after_job_start($task, $vmid);
 561     }
 562     $self->restore_vm_power_state($vmid);
 563
 564     die $err if $err;
 565 }
 566
 567 my $fork_compressor_pipe = sub {
 568     my ($self, $comp, $outfileno) = @_;
 569
 570     my @pipefd = POSIX::pipe();
 571     my $cpid = fork();
 572     die "unable to fork worker - $!" if !defined($cpid) || $cpid < 0;
 573     if ($cpid == 0) {
 574         eval {
 575             POSIX::close($pipefd[1]);
 576             # redirect STDIN
 577             my $fd = fileno(STDIN);
 578             close STDIN;
 579             POSIX::close(0) if $fd != 0;
 580             die "unable to redirect STDIN - $!"
 581                 if !open(STDIN, "<&", $pipefd[0]);
 582
 583             # redirect STDOUT
 584             $fd = fileno(STDOUT);
 585             close STDOUT;
 586             POSIX::close (1) if $fd != 1;
 587
 588             die "unable to redirect STDOUT - $!"
 589                 if !open(STDOUT, ">&", $outfileno);
 590
 591             exec($comp);
 592             die "fork compressor '$comp' failed\n";
 593         };
 594         if (my $err = $@) {
 595             $self->logerr($err);
 596             POSIX::_exit(1);
 597         }
 598         POSIX::_exit(0);
 599         kill(-9, $$);
 600     } else {
 601         POSIX::close($pipefd[0]);
 602         $outfileno = $pipefd[1];
 603     }
 604
 605     return ($cpid, $outfileno);
 606 };
 607
 608 sub archive_vma {
 609     my ($self, $task, $vmid, $filename, $comp) = @_;
 610
 611     my $conffile = "$task->{tmpdir}/qemu-server.conf";
 612     my $firewall = "$task->{tmpdir}/qemu-server.fw";
 613
 614     my $opts = $self->{vzdump}->{opts};
 615
 616     my $starttime = time();
 617
 618     my $speed = 0;
 619     if ($opts->{bwlimit}) {
 620         $speed = $opts->{bwlimit}*1024;
 621     }
 622
 623     my $diskcount = scalar(@{$task->{disks}});
 624     if (PVE::QemuConfig->is_template($self->{vmlist}->{$vmid}) || !$diskcount) {
 625         my @pathlist;
 626         foreach my $di (@{$task->{disks}}) {
 627             if ($di->{type} eq 'block' || $di->{type} eq 'file') {
 628                 push @pathlist, "$di->{qmdevice}=$di->{path}";
 629             } else {
 630                 die "implement me";
 631             }
 632         }
 633
 634         if (!$diskcount) {
 635             $self->loginfo("backup contains no disks");
 636         }
 637
 638         my $outcmd;
 639         if ($comp) {
 640             $outcmd = "exec:$comp";
 641         } else {
 642             $outcmd = "exec:cat";
 643         }
 644
 645         $outcmd .= " > $filename" if !$opts->{stdout};
 646
 647         my $cmd = ['/usr/bin/vma', 'create', '-v', '-c', $conffile];
 648         push @$cmd, '-c', $firewall if -e $firewall;
 649         push @$cmd, $outcmd, @pathlist;
 650
 651         $self->loginfo("starting template backup");
 652         $self->loginfo(join(' ', @$cmd));
 653
 654         if ($opts->{stdout}) {
 655             $self->cmd($cmd, output => ">&" . fileno($opts->{stdout}));
 656         } else {
 657             $self->cmd($cmd);
 658         }
 659
 660         return;
 661     }
 662
 663     my $devlist = _get_task_devlist($task);
 664
 665     $self->enforce_vm_running_for_backup($vmid);
 666     $self->{qmeventd_fh} = PVE::QemuServer::register_qmeventd_handle($vmid);
 667
 668     my $cpid;
 669     my $backup_job_uuid;
 670
 671     eval {
 672         $SIG{INT} = $SIG{TERM} = $SIG{QUIT} = $SIG{HUP} = $SIG{PIPE} = sub {
 673             die "interrupted by signal\n";
 674         };
 675
 676         my $outfh;
 677         if ($opts->{stdout}) {
 678             $outfh = $opts->{stdout};
 679         } else {
 680             $outfh = IO::File->new($filename, "w") ||
 681                 die "unable to open file '$filename' - $!\n";
 682         }
 683         my $outfileno = fileno($outfh);
 684
 685         if ($comp) {
 686             ($cpid, $outfileno) = $fork_compressor_pipe->($self, $comp, $outfileno);
 687         }
 688
 689         my $qmpclient = PVE::QMPClient->new();
 690         my $backup_cb = sub {
 691             my ($vmid, $resp) = @_;
 692             $backup_job_uuid = $resp->{return}->{UUID};
 693         };
 694         my $add_fd_cb = sub {
 695             my ($vmid, $resp) = @_;
 696
 697             my $params = {
 698                 'backup-file' => "/dev/fdname/backup",
 699                 speed => $speed,
 700                 'config-file' => $conffile,
 701                 devlist => $devlist
 702             };
 703             $params->{'firewall-file'} = $firewall if -e $firewall;
 704
 705             $qmpclient->queue_cmd($vmid, $backup_cb, 'backup', %$params);
 706         };
 707
 708         $qmpclient->queue_cmd($vmid, $add_fd_cb, 'getfd', fd => $outfileno, fdname => "backup");
 709
 710         my $fs_frozen = $self->qga_fs_freeze($task, $vmid);
 711
 712         eval { $qmpclient->queue_execute(30) };
 713         my $qmperr = $@;
 714
 715         if ($fs_frozen) {
 716             $self->qga_fs_thaw($vmid);
 717         }
 718
 719         die $qmperr if $qmperr;
 720         die $qmpclient->{errors}->{$vmid} if $qmpclient->{errors}->{$vmid};
 721
 722         if ($cpid) {
 723             POSIX::close($outfileno) == 0 ||
 724                 die "close output file handle failed\n";
 725         }
 726
 727         die "got no uuid for backup task\n" if !defined($backup_job_uuid);
 728
 729         $self->loginfo("started backup task '$backup_job_uuid'");
 730
 731         $self->resume_vm_after_job_start($task, $vmid);
 732
 733         $query_backup_status_loop->($self, $vmid, $backup_job_uuid);
 734     };
 735     my $err = $@;
 736     if ($err) {
 737         $self->logerr($err);
 738         $self->mon_backup_cancel($vmid);
 739         $self->resume_vm_after_job_start($task, $vmid);
 740     }
 741
 742     $self->restore_vm_power_state($vmid);
 743
 744     if ($err) {
 745         if ($cpid) {
 746             kill(9, $cpid);
 747             waitpid($cpid, 0);
 748         }
 749         die $err;
 750     }
 751
 752     if ($cpid && (waitpid($cpid, 0) > 0)) {
 753         my $stat = $?;
 754         my $ec = $stat >> 8;
 755         my $signal = $stat & 127;
 756         if ($ec || $signal) {
 757             die "$comp failed - wrong exit status $ec" .
 758                 ($signal ? " (signal $signal)\n" : "\n");
 759         }
 760     }
 761 }
 762
 763 sub _get_task_devlist {
 764     my ($task) = @_;
 765
 766     my $devlist = '';
 767     foreach my $di (@{$task->{disks}}) {
 768         if ($di->{type} eq 'block' || $di->{type} eq 'file') {
 769             $devlist .= ',' if $devlist;
 770             $devlist .= $di->{qmdevice};
 771         } else {
 772             die "implement me (type '$di->{type}')";
 773         }
 774     }
 775     return $devlist;
 776 }
 777
 778 sub qga_fs_freeze {
 779     my ($self, $task, $vmid) = @_;
 780     return if !$self->{vmlist}->{$vmid}->{agent} || $task->{mode} eq 'stop' || !$self->{vm_was_running} || $self->{vm_was_paused};
 781
 782     if (!PVE::QemuServer::qga_check_running($vmid, 1)) {
 783         $self->loginfo("skipping guest-agent 'fs-freeze', agent configured but not running?");
 784         return;
 785     }
 786
 787     $self->loginfo("issuing guest-agent 'fs-freeze' command");
 788     eval { mon_cmd($vmid, "guest-fsfreeze-freeze") };
 789     $self->logerr($@) if $@;
 790
 791     return 1; # even on mon command error, ensure we always thaw again
 792 }
 793
 794 # only call if fs_freeze return 1
 795 sub qga_fs_thaw {
 796     my ($self, $vmid) = @_;
 797
 798     $self->loginfo("issuing guest-agent 'fs-thaw' command");
 799     eval { mon_cmd($vmid, "guest-fsfreeze-thaw") };
 800     $self->logerr($@) if $@;
 801 }
 802
 803 # we need a running QEMU/KVM process for backup, starts a paused (prelaunch)
 804 # one if VM isn't already running
 805 sub enforce_vm_running_for_backup {
 806     my ($self, $vmid) = @_;
 807
 808     if (PVE::QemuServer::check_running($vmid)) {
 809         $self->{vm_was_running} = 1;
 810         return;
 811     }
 812
 813     eval {
 814         $self->loginfo("starting kvm to execute backup task");
 815         # start with skiplock
 816         my $params = {
 817             skiplock => 1,
 818             skiptemplate => 1,
 819             paused => 1,
 820         };
 821         PVE::QemuServer::vm_start($self->{storecfg}, $vmid, $params);
 822     };
 823     die $@ if $@;
 824 }
 825
 826 # resume VM again once in a clear state (stop mode backup of running VM)
 827 sub resume_vm_after_job_start {
 828     my ($self, $task, $vmid) = @_;
 829
 830     return if !$self->{vm_was_running} || $self->{vm_was_paused};
 831
 832     if (my $stoptime = $task->{vmstoptime}) {
 833         my $delay = time() - $task->{vmstoptime};
 834         $task->{vmstoptime} = undef; # avoid printing 'online after ..' twice
 835         $self->loginfo("resuming VM again after $delay seconds");
 836     } else {
 837         $self->loginfo("resuming VM again");
 838     }
 839     mon_cmd($vmid, 'cont');
 840 }
 841
 842 # stop again if VM was not running before
 843 sub restore_vm_power_state {
 844     my ($self, $vmid) = @_;
 845
 846     # we always let VMs keep running
 847     return if $self->{vm_was_running};
 848
 849     eval {
 850         my $resp = mon_cmd($vmid, 'query-status');
 851         my $status = $resp && $resp->{status} ?  $resp->{status} : 'unknown';
 852         if ($status eq 'prelaunch') {
 853             $self->loginfo("stopping kvm after backup task");
 854             PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1);
 855         } else {
 856             $self->loginfo("kvm status changed after backup ('$status') - keep VM running");
 857         }
 858     };
 859     warn $@ if $@;
 860 }
 861
 862 sub mon_backup_cancel {
 863     my ($self, $vmid) = @_;
 864
 865     $self->loginfo("aborting backup job");
 866     eval { mon_cmd($vmid, 'backup-cancel') };
 867     $self->logerr($@) if $@;
 868 }
 869
 870 sub snapshot {
 871     my ($self, $task, $vmid) = @_;
 872
 873     # nothing to do
 874 }
 875
 876 sub cleanup {
 877     my ($self, $task, $vmid) = @_;
 878
 879     if ($self->{qmeventd_fh}) {
 880         close($self->{qmeventd_fh});
 881     }
 882 }
 883
 884 1;